commit: 53d21ab316ce71cdc7f5d9b228b559d71f3a3f0f
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 5 04:26:54 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Aug 5 11:48:26 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53d21ab3
dev-python/trio: Bump to 0.26.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/trio/Manifest | 1 +
dev-python/trio/trio-0.26.1.ebuild | 67 ++++++++++++++++++++++++++++++++++++++
2 files changed, 68 insertions(+)
diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index 46cefc543c8e..fd17fe90c3b1 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1 +1,2 @@
DIST trio-0.26.0.gh.tar.gz 609710 BLAKE2B
ec263e5db731760472111b8eb6a7d6ebdc476f8dc0976787692289caa5d5361a1a3db03d4713f14ee3198ad45dcec19c6c672af4af3860c3cd7ad5ff3e13bc8a
SHA512
9a51f4e71795083ffd4a606e989583b1a93e45dc32f93d2d03bccaf32ca62a82daaf964676636363711b7ea1675dddd3eac1acae1be73b0fc570baef3c37c748
+DIST trio-0.26.1.gh.tar.gz 610304 BLAKE2B
3bd9cd09cef7fe5484025ff2532c45a4a38f1c19b64ae833ecac5eda61463184a18020215dc569e40d1ec9950a860cf371ea461ac4d5b2dfc0f611d093c1ae7d
SHA512
415bb701183e1a38574770e94c30fe4893a5f0be80291decf4524fc27677c12455124b3f7a03c37be89d42cb67b75e3315322f0cbf23264947d51ae251b3204e
diff --git a/dev-python/trio/trio-0.26.1.ebuild
b/dev-python/trio/trio-0.26.1.ebuild
new file mode 100644
index 000000000000..01b349cf4ec8
--- /dev/null
+++ b/dev-python/trio/trio-0.26.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+ https://github.com/python-trio/trio/
+ https://pypi.org/project/trio/
+"
+SRC_URI="
+ https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/attrs-23.2.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.2.1[${PYTHON_USEDEP}]
+ ' 3.10)
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/outcome[${PYTHON_USEDEP}]
+ >=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
+ dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ >=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+ >=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+# Bug https://bugs.gentoo.org/916756
+# distutils_enable_sphinx docs/source \
+# dev-python/immutables \
+# dev-python/sphinxcontrib-trio \
+# dev-python/sphinx-rtd-theme \
+# dev-python/towncrier
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Times out on slower arches (ia64 in this case)
+ # https://github.com/python-trio/trio/issues/1753
+ tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+ # requires ruff
+ _tests/tools/test_gen_exports.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ rm -rf trio || die
+ epytest -p trio._tests.pytest_plugin \
+ -m "not redistributors_should_skip" \
+ --pyargs trio \
+ --skip-optional-imports
+}
