commit: 288175a46976e5e42d712ad2c272d07596241c77
Author: Davide Pesavento <pesa <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 18 14:41:59 2015 +0000
Commit: Davide Pesavento <pesa <AT> gentoo <DOT> org>
CommitDate: Wed Feb 18 14:41:59 2015 +0000
URL: http://sources.gentoo.org/gitweb/?p=proj/qt.git;a=commit;h=288175a4
[dev-qt/*] Live ebuilds for the 5.5 branch.
---
dev-qt/assistant/assistant-5.5.9999.ebuild | 42 ++++++
dev-qt/designer/designer-5.5.9999.ebuild | 45 ++++++
.../linguist-tools/linguist-tools-5.5.9999.ebuild | 40 ++++++
dev-qt/linguist/linguist-5.5.9999.ebuild | 33 +++++
dev-qt/pixeltool/pixeltool-5.5.9999.ebuild | 31 +++++
dev-qt/qdbus/qdbus-5.5.9999.ebuild | 30 ++++
dev-qt/qdbusviewer/qdbusviewer-5.5.9999.ebuild | 32 +++++
dev-qt/qdoc/qdoc-5.5.9999.ebuild | 29 ++++
dev-qt/qtconcurrent/qtconcurrent-5.5.9999.ebuild | 28 ++++
dev-qt/qtcore/qtcore-5.5.9999.ebuild | 45 ++++++
dev-qt/qtdbus/qtdbus-5.5.9999.ebuild | 44 ++++++
dev-qt/qtdeclarative/qtdeclarative-5.5.9999.ebuild | 49 +++++++
dev-qt/qtdiag/qtdiag-5.5.9999.ebuild | 30 ++++
.../qtgraphicaleffects-5.5.9999.ebuild | 31 +++++
dev-qt/qtgui/qtgui-5.5.9999.ebuild | 152 +++++++++++++++++++++
dev-qt/qthelp/qthelp-5.5.9999.ebuild | 36 +++++
.../qtimageformats/qtimageformats-5.5.9999.ebuild | 27 ++++
dev-qt/qtmultimedia/qtmultimedia-5.5.9999.ebuild | 63 +++++++++
dev-qt/qtnetwork/qtnetwork-5.5.9999.ebuild | 55 ++++++++
dev-qt/qtopengl/qtopengl-5.5.9999.ebuild | 39 ++++++
dev-qt/qtpaths/qtpaths-5.5.9999.ebuild | 28 ++++
dev-qt/qtpositioning/qtpositioning-5.5.9999.ebuild | 40 ++++++
.../qtprintsupport/qtprintsupport-5.5.9999.ebuild | 47 +++++++
dev-qt/qtquick1/qtquick1-5.5.9999.ebuild | 52 +++++++
.../qtquickcontrols-5.5.9999.ebuild | 36 +++++
dev-qt/qtscript/qtscript-5.5.9999.ebuild | 33 +++++
dev-qt/qtsensors/qtsensors-5.5.9999.ebuild | 30 ++++
dev-qt/qtserialport/qtserialport-5.5.9999.ebuild | 23 ++++
dev-qt/qtsql/qtsql-5.5.9999.ebuild | 58 ++++++++
dev-qt/qtsvg/qtsvg-5.5.9999.ebuild | 27 ++++
dev-qt/qttest/qttest-5.5.9999.ebuild | 34 +++++
.../qttranslations/qttranslations-5.5.9999.ebuild | 23 ++++
dev-qt/qtwayland/qtwayland-5.5.9999.ebuild | 41 ++++++
dev-qt/qtwebkit/qtwebkit-5.5.9999.ebuild | 90 ++++++++++++
dev-qt/qtwebsockets/qtwebsockets-5.5.9999.ebuild | 31 +++++
dev-qt/qtwidgets/qtwidgets-5.5.9999.ebuild | 57 ++++++++
dev-qt/qtx11extras/qtx11extras-5.5.9999.ebuild | 24 ++++
dev-qt/qtxml/qtxml-5.5.9999.ebuild | 30 ++++
dev-qt/qtxmlpatterns/qtxmlpatterns-5.5.9999.ebuild | 23 ++++
39 files changed, 1608 insertions(+)
diff --git a/dev-qt/assistant/assistant-5.5.9999.ebuild
b/dev-qt/assistant/assistant-5.5.9999.ebuild
new file mode 100644
index 0000000..2aa4941
--- /dev/null
+++ b/dev-qt/assistant/assistant-5.5.9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Tool for viewing on-line documentation in Qt help file format"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="webkit"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qthelp-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ >=dev-qt/qtprintsupport-${PV}:5[debug=]
+ >=dev-qt/qtsql-${PV}:5[debug=,sqlite]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ webkit? ( >=dev-qt/qtwebkit-${PV}:5[debug=] )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/assistant/assistant
+)
+
+src_prepare() {
+ qt_use_disable_mod webkit webkitwidgets \
+ src/assistant/assistant/assistant.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/designer/designer-5.5.9999.ebuild
b/dev-qt/designer/designer-5.5.9999.ebuild
new file mode 100644
index 0000000..040c234
--- /dev/null
+++ b/dev-qt/designer/designer-5.5.9999.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="WYSIWYG tool for designing and building Qt-based GUIs"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="declarative webkit"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ >=dev-qt/qtprintsupport-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ >=dev-qt/qtxml-${PV}:5[debug=]
+ declarative? ( >=dev-qt/qtdeclarative-${PV}:5[debug=,widgets] )
+ webkit? ( >=dev-qt/qtwebkit-${PV}:5[debug=] )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/designer
+)
+
+src_prepare() {
+ qt_use_disable_mod declarative quickwidgets \
+ src/designer/src/plugins/plugins.pro
+
+ qt_use_disable_mod webkit webkitwidgets \
+ src/designer/src/plugins/plugins.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/linguist-tools/linguist-tools-5.5.9999.ebuild
b/dev-qt/linguist-tools/linguist-tools-5.5.9999.ebuild
new file mode 100644
index 0000000..508d036
--- /dev/null
+++ b/dev-qt/linguist-tools/linguist-tools-5.5.9999.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Tools for working with Qt translation data files"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="qml"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtxml-${PV}:5[debug=]
+ qml? ( >=dev-qt/qtdeclarative-${PV}:5[debug=] )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/linguist
+)
+
+src_prepare() {
+ sed -i -e '/SUBDIRS += linguist/d' \
+ src/linguist/linguist.pro || die
+
+ qt_use_disable_mod qml qmldevtools-private \
+ src/linguist/lupdate/lupdate.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/linguist/linguist-5.5.9999.ebuild
b/dev-qt/linguist/linguist-5.5.9999.ebuild
new file mode 100644
index 0000000..b022445
--- /dev/null
+++ b/dev-qt/linguist/linguist-5.5.9999.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Graphical tool for translating Qt applications"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/designer-${PV}:5[debug=]
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtprintsupport-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ >=dev-qt/qtxml-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/linguist/linguist
+)
diff --git a/dev-qt/pixeltool/pixeltool-5.5.9999.ebuild
b/dev-qt/pixeltool/pixeltool-5.5.9999.ebuild
new file mode 100644
index 0000000..198a56d
--- /dev/null
+++ b/dev-qt/pixeltool/pixeltool-5.5.9999.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Qt screen magnifier"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/pixeltool
+)
diff --git a/dev-qt/qdbus/qdbus-5.5.9999.ebuild
b/dev-qt/qdbus/qdbus-5.5.9999.ebuild
new file mode 100644
index 0000000..523968c
--- /dev/null
+++ b/dev-qt/qdbus/qdbus-5.5.9999.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Interface to Qt applications communicating over D-Bus"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtdbus-${PV}:5[debug=]
+ >=dev-qt/qtxml-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/qdbus/qdbus
+)
diff --git a/dev-qt/qdbusviewer/qdbusviewer-5.5.9999.ebuild
b/dev-qt/qdbusviewer/qdbusviewer-5.5.9999.ebuild
new file mode 100644
index 0000000..e421e9c
--- /dev/null
+++ b/dev-qt/qdbusviewer/qdbusviewer-5.5.9999.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Graphical tool that lets you introspect D-Bus objects and
messages"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtdbus-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ >=dev-qt/qtxml-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/qdbus/qdbusviewer
+)
diff --git a/dev-qt/qdoc/qdoc-5.5.9999.ebuild b/dev-qt/qdoc/qdoc-5.5.9999.ebuild
new file mode 100644
index 0000000..688bc77
--- /dev/null
+++ b/dev-qt/qdoc/qdoc-5.5.9999.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="Qt documentation generator"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ ~dev-qt/qtxml-${PV}[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/tools/qdoc
+)
diff --git a/dev-qt/qtconcurrent/qtconcurrent-5.5.9999.ebuild
b/dev-qt/qtconcurrent/qtconcurrent-5.5.9999.ebuild
new file mode 100644
index 0000000..a04ebc8
--- /dev/null
+++ b/dev-qt/qtconcurrent/qtconcurrent-5.5.9999.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="Multi-threading concurrence support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/concurrent
+)
diff --git a/dev-qt/qtcore/qtcore-5.5.9999.ebuild
b/dev-qt/qtcore/qtcore-5.5.9999.ebuild
new file mode 100644
index 0000000..cc36a68
--- /dev/null
+++ b/dev-qt/qtcore/qtcore-5.5.9999.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="Cross-platform application development framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="icu systemd"
+
+DEPEND="
+ dev-libs/glib:2
+ >=dev-libs/libpcre-8.30[pcre16]
+ sys-libs/zlib
+ virtual/libiconv
+ icu? ( dev-libs/icu:= )
+ systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/tools/bootstrap
+ src/tools/moc
+ src/tools/rcc
+ src/corelib
+ src/tools/qlalr
+)
+
+src_configure() {
+ local myconf=(
+ $(qt_use icu)
+ $(qt_use systemd journald)
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtdbus/qtdbus-5.5.9999.ebuild
b/dev-qt/qtdbus/qtdbus-5.5.9999.ebuild
new file mode 100644
index 0000000..9cb7993
--- /dev/null
+++ b/dev-qt/qtdbus/qtdbus-5.5.9999.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="The D-Bus module for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ >=sys-apps/dbus-1.4.20
+ sys-libs/zlib
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/dbus
+ src/tools/qdbusxml2cpp
+ src/tools/qdbuscpp2xml
+)
+
+QT5_GENTOO_CONFIG=(
+ :dbus
+ :dbus-linked:
+)
+
+src_configure() {
+ local myconf=(
+ -dbus-linked
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.5.9999.ebuild
b/dev-qt/qtdeclarative/qtdeclarative-5.5.9999.ebuild
new file mode 100644
index 0000000..574cc92
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.5.9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="gles2 localstorage +widgets xml"
+
+# qtgui[gles2=] is needed because of bug 504322
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=,gles2=,opengl]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ >=dev-qt/qttest-${PV}:5[debug=]
+ localstorage? ( >=dev-qt/qtsql-${PV}:5[debug=] )
+ widgets? ( >=dev-qt/qtwidgets-${PV}:5[debug=] )
+ xml? ( >=dev-qt/qtxmlpatterns-${PV}:5[debug=] )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ use localstorage || sed -i -e '/localstorage/d' \
+ src/imports/imports.pro || die
+
+ use widgets || sed -i -e 's/contains(QT_CONFIG, no-widgets)/true/' \
+ src/qmltest/qmltest.pro || die
+
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ tools/tools.pro \
+ tools/qmlscene/qmlscene.pro \
+ tools/qml/qml.pro
+
+ qt_use_disable_mod xml xmlpatterns \
+ src/imports/imports.pro \
+ tests/auto/quick/quick.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtdiag/qtdiag-5.5.9999.ebuild
b/dev-qt/qtdiag/qtdiag-5.5.9999.ebuild
new file mode 100644
index 0000000..ee14921
--- /dev/null
+++ b/dev-qt/qtdiag/qtdiag-5.5.9999.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Tool for reporting diagnostic information about Qt and its
environment"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="+opengl +ssl"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=,opengl=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=,ssl=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/qtdiag
+)
diff --git a/dev-qt/qtgraphicaleffects/qtgraphicaleffects-5.5.9999.ebuild
b/dev-qt/qtgraphicaleffects/qtgraphicaleffects-5.5.9999.ebuild
new file mode 100644
index 0000000..9b41e58
--- /dev/null
+++ b/dev-qt/qtgraphicaleffects/qtgraphicaleffects-5.5.9999.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build virtualx
+
+DESCRIPTION="Set of QML types for adding visual effects to user interfaces"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtdeclarative-${PV}:5[debug=]
+ >=dev-qt/qtxmlpatterns-${PV}:5[debug=]
+"
+DEPEND="${RDEPEND}
+ test? ( >=dev-qt/qtgui-${PV}:5[debug=] )
+"
+
+src_test() {
+ local VIRTUALX_COMMAND="qt5-build_src_test"
+ virtualmake
+}
diff --git a/dev-qt/qtgui/qtgui-5.5.9999.ebuild
b/dev-qt/qtgui/qtgui-5.5.9999.ebuild
new file mode 100644
index 0000000..2f62794
--- /dev/null
+++ b/dev-qt/qtgui/qtgui-5.5.9999.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="The GUI module and platform plugins for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+# TODO: directfb, linuxfb, offscreen (auto-depends on X11)
+
+IUSE="accessibility egl eglfs evdev +gif gles2 +harfbuzz ibus jpeg kms +opengl
+png udev +xcb"
+REQUIRED_USE="
+ egl? ( evdev opengl )
+ eglfs? ( egl )
+ gles2? ( opengl )
+ kms? ( egl gles2 )
+"
+
+RDEPEND="
+ dev-libs/glib:2
+ ~dev-qt/qtcore-${PV}[debug=]
+ media-libs/fontconfig
+ media-libs/freetype:2
+ sys-libs/zlib
+ egl? ( media-libs/mesa[egl] )
+ evdev? ( sys-libs/mtdev )
+ gles2? ( media-libs/mesa[gles2] )
+ harfbuzz? ( >=media-libs/harfbuzz-0.9.32:= )
+ ibus? ( ~dev-qt/qtdbus-${PV}[debug=] )
+ jpeg? ( virtual/jpeg:0 )
+ kms? (
+ media-libs/mesa[gbm]
+ virtual/libudev:=
+ x11-libs/libdrm
+ )
+ opengl? ( virtual/opengl )
+ png? ( media-libs/libpng:0= )
+ udev? ( virtual/libudev:= )
+ xcb? (
+ x11-libs/libICE
+ x11-libs/libSM
+ >=x11-libs/libX11-1.5
+ >=x11-libs/libXi-1.6
+ x11-libs/libXrender
+ >=x11-libs/libxcb-1.10:=[xkb]
+ >=x11-libs/libxkbcommon-0.4.1[X]
+ x11-libs/xcb-util-image
+ x11-libs/xcb-util-keysyms
+ x11-libs/xcb-util-renderutil
+ x11-libs/xcb-util-wm
+ accessibility? ( ~dev-qt/qtdbus-${PV}[debug=] )
+ )
+"
+DEPEND="${RDEPEND}
+ evdev? ( sys-kernel/linux-headers )
+ test? ( ~dev-qt/qtnetwork-${PV}[debug=] )
+"
+PDEPEND="
+ ibus? ( app-i18n/ibus )
+"
+
+QT5_TARGET_SUBDIRS=(
+ src/gui
+ src/platformheaders
+ src/platformsupport
+ src/plugins/generic
+ src/plugins/imageformats
+ src/plugins/platforms
+)
+
+QT5_GENTOO_CONFIG=(
+ accessibility:accessibility-atspi-bridge
+ egl
+ eglfs
+ evdev
+ evdev:mtdev:
+ :fontconfig
+ :system-freetype:FREETYPE
+ !:no-freetype:
+ !gif:no-gif:
+ gles2::OPENGL_ES
+ gles2:opengles2:OPENGL_ES_2
+ !:no-gui:
+ harfbuzz:system-harfbuzz:HARFBUZZ
+ !harfbuzz:no-harfbuzz:
+ jpeg:system-jpeg:IMAGEFORMAT_JPEG
+ !jpeg:no-jpeg:
+ kms:kms:
+ opengl
+ png:png:
+ png:system-png:IMAGEFORMAT_PNG
+ !png:no-png:
+ udev:libudev:
+ xcb:xcb:
+ xcb:xcb-glx:
+ xcb:xcb-plugin:
+ xcb:xcb-render:
+ xcb:xcb-sm:
+ xcb:xcb-xlib:
+ xcb:xinput2:
+ xcb::XKB
+)
+
+pkg_setup() {
+ use opengl && QT5_TARGET_SUBDIRS+=(src/openglextensions)
+ use ibus &&
QT5_TARGET_SUBDIRS+=(src/plugins/platforminputcontexts/ibus)
+ use xcb &&
QT5_TARGET_SUBDIRS+=(src/plugins/platforminputcontexts/compose)
+
+ # egl_x11 is activated when both egl and xcb are enabled
+ use egl && QT5_GENTOO_CONFIG+=(xcb:egl_x11) ||
QT5_GENTOO_CONFIG+=(egl:egl_x11)
+}
+
+src_configure() {
+ local gl="-no-opengl"
+ if use gles2; then
+ gl="-opengl es2"
+ elif use opengl; then
+ gl="-opengl desktop"
+ fi
+
+ local myconf=(
+ $(use accessibility && use xcb && echo -dbus-linked)
+ $(use ibus && echo -dbus-linked)
+ $(qt_use egl)
+ $(qt_use eglfs)
+ $(qt_use evdev)
+ $(qt_use evdev mtdev)
+ -fontconfig
+ -system-freetype
+ $(use gif || echo -no-gif)
+ ${gl}
+ $(qt_use harfbuzz harfbuzz system)
+ $(qt_use jpeg libjpeg system)
+ $(qt_use kms)
+ $(qt_use png libpng system)
+ $(qt_use udev libudev)
+ $(qt_use xcb xcb system)
+ $(qt_use xcb xkbcommon system)
+ $(use xcb && echo -xcb-xlib -xinput2 -xkb -xrender)
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qthelp/qthelp-5.5.9999.ebuild
b/dev-qt/qthelp/qthelp-5.5.9999.ebuild
new file mode 100644
index 0000000..ef86f1d
--- /dev/null
+++ b/dev-qt/qthelp/qthelp-5.5.9999.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="The Help module for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ >=dev-qt/qtsql-${PV}:5[debug=,sqlite]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/assistant/clucene
+ src/assistant/help
+ src/assistant/qcollectiongenerator
+ src/assistant/qhelpconverter
+ src/assistant/qhelpgenerator
+)
diff --git a/dev-qt/qtimageformats/qtimageformats-5.5.9999.ebuild
b/dev-qt/qtimageformats/qtimageformats-5.5.9999.ebuild
new file mode 100644
index 0000000..ce21e36
--- /dev/null
+++ b/dev-qt/qtimageformats/qtimageformats-5.5.9999.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Additional format plugins for the Qt image I/O system"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ media-libs/jasper
+ media-libs/libmng:=
+ media-libs/libwebp:=
+ media-libs/tiff:0
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.5.9999.ebuild
b/dev-qt/qtmultimedia/qtmultimedia-5.5.9999.ebuild
new file mode 100644
index 0000000..b0a67fa
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-5.5.9999.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="The Multimedia module for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="alsa +gstreamer openal +opengl pulseaudio qml widgets"
+
+# "widgets? ( qtgui[opengl=] )" because of bug 518542 comment 2
+RDEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ alsa? ( media-libs/alsa-lib )
+ gstreamer? (
+ media-libs/gstreamer:0.10
+ media-libs/gst-plugins-bad:0.10
+ media-libs/gst-plugins-base:0.10
+ )
+ pulseaudio? ( media-sound/pulseaudio )
+ qml? (
+ >=dev-qt/qtdeclarative-${PV}:5[debug=]
+ openal? ( media-libs/openal )
+ )
+ widgets? (
+ >=dev-qt/qtgui-${PV}:5[debug=,opengl=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=,opengl=]
+ opengl? ( >=dev-qt/qtopengl-${PV}:5[debug=] )
+ )
+"
+DEPEND="${RDEPEND}
+ x11-proto/videoproto
+"
+
+src_prepare() {
+ qt_use_compile_test alsa
+ qt_use_compile_test gstreamer
+ qt_use_compile_test openal
+ qt_use_compile_test pulseaudio
+
+ qt_use_disable_mod opengl opengl \
+ src/multimediawidgets/multimediawidgets.pro
+
+ qt_use_disable_mod qml quick \
+ src/src.pro
+
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ src/gsttools/gsttools.pro \
+ src/plugins/gstreamer/common.pri
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtnetwork/qtnetwork-5.5.9999.ebuild
b/dev-qt/qtnetwork/qtnetwork-5.5.9999.ebuild
new file mode 100644
index 0000000..0cd874a
--- /dev/null
+++ b/dev-qt/qtnetwork/qtnetwork-5.5.9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="Network abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="connman networkmanager +ssl"
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ sys-libs/zlib
+ connman? ( ~dev-qt/qtdbus-${PV}[debug=] )
+ networkmanager? ( ~dev-qt/qtdbus-${PV}[debug=] )
+ ssl? ( dev-libs/openssl:0[-bindist] )
+"
+RDEPEND="${DEPEND}
+ connman? ( net-misc/connman )
+ networkmanager? ( net-misc/networkmanager )
+"
+
+QT5_TARGET_SUBDIRS=(
+ src/network
+ src/plugins/bearer/generic
+)
+
+QT5_GENTOO_CONFIG=(
+ ssl::SSL
+ ssl::OPENSSL
+ ssl:openssl-linked:LINKED_OPENSSL
+)
+
+pkg_setup() {
+ use connman && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/connman)
+ use networkmanager &&
QT5_TARGET_SUBDIRS+=(src/plugins/bearer/networkmanager)
+}
+
+src_configure() {
+ local myconf=(
+ $(use connman || use networkmanager && echo -dbus-linked)
+ $(use ssl && echo -openssl-linked)
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtopengl/qtopengl-5.5.9999.ebuild
b/dev-qt/qtopengl/qtopengl-5.5.9999.ebuild
new file mode 100644
index 0000000..1f74ecb
--- /dev/null
+++ b/dev-qt/qtopengl/qtopengl-5.5.9999.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+
+inherit qt5-build
+
+DESCRIPTION="OpenGL support library for the Qt5 framework (deprecated)"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="gles2"
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ ~dev-qt/qtgui-${PV}[debug=,gles2=,opengl]
+ ~dev-qt/qtwidgets-${PV}[debug=,gles2=,opengl]
+ virtual/opengl
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/opengl
+)
+
+src_configure() {
+ local myconf=(
+ -opengl $(usex gles2 es2 desktop)
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtpaths/qtpaths-5.5.9999.ebuild
b/dev-qt/qtpaths/qtpaths-5.5.9999.ebuild
new file mode 100644
index 0000000..78de013
--- /dev/null
+++ b/dev-qt/qtpaths/qtpaths-5.5.9999.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qttools"
+
+inherit qt5-build
+
+DESCRIPTION="Tool to query Qt path information"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/qtpaths
+)
diff --git a/dev-qt/qtpositioning/qtpositioning-5.5.9999.ebuild
b/dev-qt/qtpositioning/qtpositioning-5.5.9999.ebuild
new file mode 100644
index 0000000..448257b
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-5.5.9999.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtlocation"
+
+inherit qt5-build
+
+DESCRIPTION="Physical position determination library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+# TODO: src/plugins/position/gypsy
+IUSE="geoclue qml"
+
+RDEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ geoclue? (
+ app-misc/geoclue:0
+ dev-libs/glib:2
+ )
+ qml? ( >=dev-qt/qtdeclarative-${PV}:5[debug=] )
+"
+DEPEND="${RDEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/positioning
+ src/plugins/position/positionpoll
+)
+
+pkg_setup() {
+ use geoclue && QT5_TARGET_SUBDIRS+=(src/plugins/position/geoclue)
+ use qml && QT5_TARGET_SUBDIRS+=(src/imports/positioning)
+}
diff --git a/dev-qt/qtprintsupport/qtprintsupport-5.5.9999.ebuild
b/dev-qt/qtprintsupport/qtprintsupport-5.5.9999.ebuild
new file mode 100644
index 0000000..aad2972
--- /dev/null
+++ b/dev-qt/qtprintsupport/qtprintsupport-5.5.9999.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+
+inherit qt5-build
+
+DESCRIPTION="Printing support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="cups +opengl"
+
+RDEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ ~dev-qt/qtgui-${PV}[debug=,opengl=]
+ ~dev-qt/qtwidgets-${PV}[debug=,opengl=]
+ cups? ( >=net-print/cups-1.4 )
+"
+DEPEND="${RDEPEND}
+ test? ( ~dev-qt/qtnetwork-${PV}[debug=] )
+"
+
+QT5_TARGET_SUBDIRS=(
+ src/printsupport
+ src/plugins/printsupport
+)
+
+QT5_GENTOO_CONFIG=(
+ cups
+)
+
+src_configure() {
+ local myconf=(
+ $(qt_use cups)
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtquick1/qtquick1-5.5.9999.ebuild
b/dev-qt/qtquick1/qtquick1-5.5.9999.ebuild
new file mode 100644
index 0000000..72a3958
--- /dev/null
+++ b/dev-qt/qtquick1/qtquick1-5.5.9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Legacy declarative framework for Qt4 compatibility for building
dynamic user interfaces"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="designer +opengl webkit xml"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ >=dev-qt/qtscript-${PV}:5[debug=]
+ >=dev-qt/qtsql-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ designer? (
+ >=dev-qt/designer-${PV}:5[debug=]
+ >=dev-qt/qtdeclarative-${PV}:5[debug=]
+ )
+ opengl? ( >=dev-qt/qtopengl-${PV}:5[debug=] )
+ webkit? ( >=dev-qt/qtwebkit-${PV}:5[debug=] )
+ xml? ( >=dev-qt/qtxmlpatterns-${PV}:5[debug=] )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ qt_use_disable_mod designer designer \
+ src/plugins/plugins.pro
+
+ qt_use_disable_mod opengl opengl \
+ src/imports/imports.pro \
+ tools/qml/qml.pri
+
+ qt_use_disable_mod webkit webkitwidgets \
+ src/imports/imports.pro
+
+ qt_use_disable_mod xml xmlpatterns \
+ src/declarative/declarative.pro \
+ src/declarative/util/util.pri
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtquickcontrols/qtquickcontrols-5.5.9999.ebuild
b/dev-qt/qtquickcontrols/qtquickcontrols-5.5.9999.ebuild
new file mode 100644
index 0000000..60e838c
--- /dev/null
+++ b/dev-qt/qtquickcontrols/qtquickcontrols-5.5.9999.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Set of controls used in conjunction with Qt Quick to build
complete interfaces"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="widgets"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtdeclarative-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ widgets? ( >=dev-qt/qtwidgets-${PV}:5[debug=] )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ src/controls/Private/private.pri \
+ tests/auto/activeFocusOnTab/activeFocusOnTab.pro \
+ tests/auto/controls/controls.pro \
+ tests/auto/testplugin/testplugin.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtscript/qtscript-5.5.9999.ebuild
b/dev-qt/qtscript/qtscript-5.5.9999.ebuild
new file mode 100644
index 0000000..d8f09c2
--- /dev/null
+++ b/dev-qt/qtscript/qtscript-5.5.9999.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Application scripting library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="scripttools"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ scripttools? (
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ qt_use_disable_mod scripttools widgets \
+ src/src.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtsensors/qtsensors-5.5.9999.ebuild
b/dev-qt/qtsensors/qtsensors-5.5.9999.ebuild
new file mode 100644
index 0000000..e2258dc
--- /dev/null
+++ b/dev-qt/qtsensors/qtsensors-5.5.9999.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Hardware sensor access library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="qml"
+
+RDEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ qml? ( >=dev-qt/qtdeclarative-${PV}:5[debug=] )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+ qt_use_disable_mod qml quick \
+ src/src.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtserialport/qtserialport-5.5.9999.ebuild
b/dev-qt/qtserialport/qtserialport-5.5.9999.ebuild
new file mode 100644
index 0000000..ab5cecf
--- /dev/null
+++ b/dev-qt/qtserialport/qtserialport-5.5.9999.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Serial port abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ virtual/udev
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtsql/qtsql-5.5.9999.ebuild
b/dev-qt/qtsql/qtsql-5.5.9999.ebuild
new file mode 100644
index 0000000..b5801b1
--- /dev/null
+++ b/dev-qt/qtsql/qtsql-5.5.9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit multilib qt5-build
+
+DESCRIPTION="SQL abstraction library for the Qt5 tooolkit"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="freetds mysql oci8 odbc postgres +sqlite"
+
+REQUIRED_USE="
+ || ( freetds mysql oci8 odbc postgres sqlite )
+"
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ freetds? ( dev-db/freetds )
+ mysql? ( virtual/mysql:= )
+ oci8? ( dev-db/oracle-instantclient-basic )
+ odbc? ( || ( dev-db/unixODBC dev-db/libiodbc ) )
+ postgres? ( dev-db/postgresql:* )
+ sqlite? ( dev-db/sqlite:3 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/sql
+ src/plugins/sqldrivers
+)
+
+src_configure() {
+ local myconf=(
+ $(qt_use freetds sql-tds plugin)
+ $(qt_use mysql sql-mysql plugin)
+ $(qt_use oci8 sql-oci plugin)
+ $(qt_use odbc sql-odbc plugin)
+ $(qt_use postgres sql-psql plugin)
+ $(qt_use sqlite sql-sqlite plugin)
+ $(use sqlite && echo -system-sqlite)
+ )
+
+ use mysql && myconf+=("-I${EPREFIX}/usr/include/mysql"
"-L${EPREFIX}/usr/$(get_libdir)/mysql")
+ use oci8 && myconf+=("-I${ORACLE_HOME}/include"
"-L${ORACLE_HOME}/$(get_libdir)")
+ use odbc && myconf+=("-I${EPREFIX}/usr/include/iodbc")
+ use postgres && myconf+=("-I${EPREFIX}/usr/include/postgresql/pgsql")
+
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtsvg/qtsvg-5.5.9999.ebuild
b/dev-qt/qtsvg/qtsvg-5.5.9999.ebuild
new file mode 100644
index 0000000..a5e02d0
--- /dev/null
+++ b/dev-qt/qtsvg/qtsvg-5.5.9999.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="SVG rendering library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+ test? ( >=dev-qt/qtxml-${PV}:5[debug=] )
+"
diff --git a/dev-qt/qttest/qttest-5.5.9999.ebuild
b/dev-qt/qttest/qttest-5.5.9999.ebuild
new file mode 100644
index 0000000..c7fbbbd
--- /dev/null
+++ b/dev-qt/qttest/qttest-5.5.9999.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+
+inherit qt5-build
+
+DESCRIPTION="Unit testing library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+"
+DEPEND="${RDEPEND}
+ test? (
+ ~dev-qt/qtgui-${PV}[debug=]
+ ~dev-qt/qtxml-${PV}[debug=]
+ )
+"
+
+QT5_TARGET_SUBDIRS=(
+ src/testlib
+)
diff --git a/dev-qt/qttranslations/qttranslations-5.5.9999.ebuild
b/dev-qt/qttranslations/qttranslations-5.5.9999.ebuild
new file mode 100644
index 0000000..88628f9
--- /dev/null
+++ b/dev-qt/qttranslations/qttranslations-5.5.9999.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Translation files for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/linguist-tools-${PV}:5
+ >=dev-qt/qtcore-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtwayland/qtwayland-5.5.9999.ebuild
b/dev-qt/qtwayland/qtwayland-5.5.9999.ebuild
new file mode 100644
index 0000000..538050d
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-5.5.9999.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="egl qml wayland-compositor xcomposite"
+
+DEPEND="
+ >=dev-libs/wayland-1.3.0
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtgui-${PV}:5[debug=,egl=,opengl]
+ media-libs/mesa[egl?]
+ >=x11-libs/libxkbcommon-0.2.0
+ qml? ( >=dev-qt/qtdeclarative-${PV}:5[debug=] )
+ xcomposite? (
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+ if use wayland-compositor; then
+ echo "CONFIG += wayland-compositor" >>
"${QT5_BUILD_DIR}"/.qmake.cache
+ fi
+
+ qt_use_compile_test xcomposite
+
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtwebkit/qtwebkit-5.5.9999.ebuild
b/dev-qt/qtwebkit/qtwebkit-5.5.9999.ebuild
new file mode 100644
index 0000000..af9e2f8
--- /dev/null
+++ b/dev-qt/qtwebkit/qtwebkit-5.5.9999.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="WebKit rendering library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+# TODO: qttestlib, geolocation, orientation/sensors
+
+IUSE="gstreamer gstreamer010 multimedia opengl printsupport qml udev webp"
+REQUIRED_USE="?? ( gstreamer gstreamer010 multimedia )"
+
+RDEPEND="
+ dev-db/sqlite:3
+ dev-libs/icu:=
+ dev-libs/libxml2:2
+ dev-libs/libxslt
+ >=dev-qt/qtcore-${PV}:5[debug=,icu]
+ >=dev-qt/qtgui-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ >=dev-qt/qtsql-${PV}:5[debug=]
+ >=dev-qt/qtwidgets-${PV}:5[debug=]
+ media-libs/fontconfig:1.0
+ media-libs/libpng:0=
+ sys-libs/zlib
+ virtual/jpeg:0
+ virtual/opengl
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXrender
+ gstreamer? (
+ dev-libs/glib:2
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-base:1.0
+ )
+ gstreamer010? (
+ dev-libs/glib:2
+ media-libs/gstreamer:0.10
+ media-libs/gst-plugins-base:0.10
+ )
+ multimedia? ( >=dev-qt/qtmultimedia-${PV}:5[debug=,widgets] )
+ opengl? ( >=dev-qt/qtopengl-${PV}:5[debug=] )
+ printsupport? ( >=dev-qt/qtprintsupport-${PV}:5[debug=] )
+ qml? ( >=dev-qt/qtdeclarative-${PV}:5[debug=] )
+ udev? ( virtual/udev )
+ webp? ( media-libs/libwebp:0= )
+"
+DEPEND="${RDEPEND}
+ ${PYTHON_DEPS}
+ dev-lang/ruby
+ dev-util/gperf
+ sys-devel/bison
+ sys-devel/flex
+"
+
+src_prepare() {
+ if use gstreamer010; then
+ epatch "${FILESDIR}/${PN}-5.3.2-use-gstreamer010.patch"
+ elif ! use gstreamer; then
+ epatch "${FILESDIR}/${PN}-5.2.1-disable-gstreamer.patch"
+ fi
+ use multimedia || sed -i -e '/WEBKIT_CONFIG += video
use_qt_multimedia/d' \
+ Tools/qmake/mkspecs/features/features.prf || die
+ use opengl || sed -i -e '/contains(QT_CONFIG, opengl):
WEBKIT_CONFIG += use_3d_graphics/d' \
+ Tools/qmake/mkspecs/features/features.prf || die
+ use printsupport || sed -i -e '/WEBKIT_CONFIG += have_qtprintsupport/d'
\
+ Tools/qmake/mkspecs/features/features.prf || die
+ use qml || sed -i -e '/have?(QTQUICK): SUBDIRS +=
declarative/d' \
+ Source/QtWebKit.pro || die
+ use udev || sed -i -e '/linux: WEBKIT_CONFIG += gamepad/d' \
+ Tools/qmake/mkspecs/features/features.prf || die
+ use webp || sed -i -e '/config_libwebp: WEBKIT_CONFIG +=
use_webp/d' \
+ Tools/qmake/mkspecs/features/features.prf || die
+
+ # bug 458222
+ sed -i -e '/SUBDIRS += examples/d' Source/QtWebKit.pro || die
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtwebsockets/qtwebsockets-5.5.9999.ebuild
b/dev-qt/qtwebsockets/qtwebsockets-5.5.9999.ebuild
new file mode 100644
index 0000000..e518ebc
--- /dev/null
+++ b/dev-qt/qtwebsockets/qtwebsockets-5.5.9999.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Implementation of the WebSocket protocol for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="qml"
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+ qml? ( >=dev-qt/qtdeclarative-${PV}:5[debug=] )
+
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ qt_use_disable_mod qml quick src/src.pro
+
+ qt5-build_src_prepare
+}
diff --git a/dev-qt/qtwidgets/qtwidgets-5.5.9999.ebuild
b/dev-qt/qtwidgets/qtwidgets-5.5.9999.ebuild
new file mode 100644
index 0000000..3046d62
--- /dev/null
+++ b/dev-qt/qtwidgets/qtwidgets-5.5.9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="Set of UI elements for creating classic desktop-style user
interfaces for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="gles2 +opengl +png +xcb"
+REQUIRED_USE="
+ gles2? ( opengl )
+"
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ ~dev-qt/qtgui-${PV}[debug=,gles2=,opengl=,png=,xcb?]
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/tools/uic
+ src/widgets
+)
+
+QT5_GENTOO_CONFIG=(
+ !:no-widgets:
+)
+
+src_configure() {
+ local gl="-no-opengl"
+ if use gles2; then
+ gl="-opengl es2"
+ elif use opengl; then
+ gl="-opengl desktop"
+ fi
+
+ local myconf=(
+ # copied from qtgui
+ ${gl}
+ $(qt_use png libpng system)
+ $(qt_use xcb xcb system)
+ $(qt_use xcb xkbcommon system)
+ $(use xcb && echo -xcb-xlib -xinput2 -xkb -xrender)
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtx11extras/qtx11extras-5.5.9999.ebuild
b/dev-qt/qtx11extras/qtx11extras-5.5.9999.ebuild
new file mode 100644
index 0000000..31f133b
--- /dev/null
+++ b/dev-qt/qtx11extras/qtx11extras-5.5.9999.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="Linux/X11-specific support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+ ~dev-qt/qtgui-${PV}[debug=,xcb]
+ ~dev-qt/qtwidgets-${PV}[debug=]
+"
+DEPEND="${RDEPEND}"
diff --git a/dev-qt/qtxml/qtxml-5.5.9999.ebuild
b/dev-qt/qtxml/qtxml-5.5.9999.ebuild
new file mode 100644
index 0000000..32c00c3
--- /dev/null
+++ b/dev-qt/qtxml/qtxml-5.5.9999.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+QT5_MODULE="qtbase"
+
+inherit qt5-build
+
+DESCRIPTION="SAX and DOM implementation library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+ ~dev-qt/qtcore-${PV}[debug=]
+"
+DEPEND="${RDEPEND}
+ test? ( ~dev-qt/qtnetwork-${PV}[debug=] )
+"
+
+QT5_TARGET_SUBDIRS=(
+ src/xml
+)
diff --git a/dev-qt/qtxmlpatterns/qtxmlpatterns-5.5.9999.ebuild
b/dev-qt/qtxmlpatterns/qtxmlpatterns-5.5.9999.ebuild
new file mode 100644
index 0000000..085dd07
--- /dev/null
+++ b/dev-qt/qtxmlpatterns/qtxmlpatterns-5.5.9999.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit qt5-build
+
+DESCRIPTION="XPath, XQuery, and XSLT support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == live ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtcore-${PV}:5[debug=]
+ >=dev-qt/qtnetwork-${PV}:5[debug=]
+"
+RDEPEND="${DEPEND}"
