commit: 44941174a700a011ab1331504fade7c0fa2d9d30
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 18 14:27:41 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug 18 14:29:21 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=44941174
media-libs/glycin-loaders: New package, 1.1_beta
Required by media-gfx/fotema.
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
media-libs/glycin-loaders/Manifest | 1 +
.../glycin-loaders/glycin-loaders-1.1_beta.ebuild | 69 ++++++++++++++++++++++
media-libs/glycin-loaders/metadata.xml | 11 ++++
3 files changed, 81 insertions(+)
diff --git a/media-libs/glycin-loaders/Manifest
b/media-libs/glycin-loaders/Manifest
new file mode 100644
index 000000000000..ac1ae8dde59a
--- /dev/null
+++ b/media-libs/glycin-loaders/Manifest
@@ -0,0 +1 @@
+DIST glycin-1.1.beta.tar.xz 28597076 BLAKE2B
94e0172de27ce1a1cbbaba6ee5d3792b8a05a2f192598a03f61dc7cdacbdb2927ad3b19158ae30c63fe73916edab0c24a3d547ec4d8c7adbf63b7cce8cc81704
SHA512
a5534546f58508a033b00ad798536e0342c0d3f2108464f3c58bc0c7e23aeebf9687e6b2717c0edf35e3f88177c8bd281ab8f5e82377adec096396ce8c4e8eb2
diff --git a/media-libs/glycin-loaders/glycin-loaders-1.1_beta.ebuild
b/media-libs/glycin-loaders/glycin-loaders-1.1_beta.ebuild
new file mode 100644
index 000000000000..ed37a9ca5e08
--- /dev/null
+++ b/media-libs/glycin-loaders/glycin-loaders-1.1_beta.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cargo meson
+
+MY_P=glycin-${PV/_/.}
+DESCRIPTION="Loaders for glycin clients (glycin crate or libglycin)"
+HOMEPAGE="https://gitlab.gnome.org/sophie-h/glycin/";
+SRC_URI="
+ https://download.gnome.org/sources/glycin/$(ver_cut 1-2)/${MY_P}.tar.xz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( LGPL-2.1+ MPL-2.0 )"
+# Dependent crate licenses
+LICENSE+="
+ Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD GPL-3+ ISC MIT
+ Unicode-DFS-2016
+ || ( LGPL-2.1+ MPL-2.0 )
+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="heif jpegxl svg test"
+# TODO: figure out how to make tests work from inside the ebuild
+RESTRICT="test"
+
+RDEPEND="
+ >=dev-libs/glib-2.60:2
+ >=sys-libs/libseccomp-2.5.0
+ heif? ( >=media-libs/libheif-1.17.0:= )
+ jpegxl? ( >=media-libs/libjxl-0.10.0:= )
+ svg? (
+ >=gnome-base/librsvg-2.52.0
+ >=x11-libs/cairo-1.17.0
+ )
+"
+DEPEND="
+ ${RDEPEND}
+ test? (
+ >=gui-libs/gtk-4.12.0:4
+ >=media-libs/lcms-2.14:2
+ )
+"
+
+ECARGO_VENDOR=${S}/vendor
+
+QA_FLAGS_IGNORED="usr/libexec/glycin-loaders/.*"
+
+src_configure() {
+ local formats=(
+ $(usev heif glycin-heif)
+ $(usev jpegxl glycin-jxl)
+ $(usev svg glycin-svg)
+ glycin-image-rs
+ )
+ local formats_s=${formats[*]}
+ local emesonargs=(
+ -Dprofile=$(usex debug release dev)
+ -Dglycin-loaders=true
+ -Dloaders="${formats_s// /,}"
+ -Dtests=$(usex test true false)
+ -Dlibglycin=false
+ )
+
+ meson_src_configure
+ ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
+}
diff --git a/media-libs/glycin-loaders/metadata.xml
b/media-libs/glycin-loaders/metadata.xml
new file mode 100644
index 000000000000..52ff5d43ffe7
--- /dev/null
+++ b/media-libs/glycin-loaders/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
+<pkgmetadata>
+ <maintainer type="person">
+ <email>[email protected]</email>
+ <name>Michał Górny</name>
+ </maintainer>
+ <upstream>
+ <remote-id type="gnome-gitlab">sophie-h/glycin</remote-id>
+ </upstream>
+</pkgmetadata>
