commit: 05abf1d0c858443d82e954f0941671e75cccdb9f
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 20 15:34:51 2024 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Aug 21 21:16:30 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=05abf1d0
kde-frameworks/purpose: RDEPEND on purpose-kaccounts-services
Dropping IUSE kf6compat
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
kde-frameworks/purpose/purpose-5.116.0-r2.ebuild | 87 ++++++++++++++++++++++++
kde-frameworks/purpose/purpose-6.5.0-r1.ebuild | 80 ++++++++++++++++++++++
2 files changed, 167 insertions(+)
diff --git a/kde-frameworks/purpose/purpose-5.116.0-r2.ebuild
b/kde-frameworks/purpose/purpose-5.116.0-r2.ebuild
new file mode 100644
index 000000000000..e399592c8dd3
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.116.0-r2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org optfeature xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's
purposes fulfilled"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="bluetooth kaccounts"
+
+# requires running environment
+RESTRICT="test"
+
+DEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ =kde-frameworks/kconfig-${PVCUT}*:5
+ =kde-frameworks/kcoreaddons-${PVCUT}*:5
+ =kde-frameworks/ki18n-${PVCUT}*:5
+ =kde-frameworks/kio-${PVCUT}*:5
+ =kde-frameworks/kirigami-${PVCUT}*:5
+ =kde-frameworks/knotifications-${PVCUT}*:5
+ =kde-frameworks/kservice-${PVCUT}*:5
+ =kde-frameworks/prison-${PVCUT}*:5
+ kaccounts? (
+ || (
+ kde-apps/kaccounts-integration:6[qt5]
+ kde-apps/kaccounts-integration:5
+ )
+ >=net-libs/accounts-qt-1.16_p20220803[qt5(-)]
+ )
+"
+RDEPEND="${DEPEND}
+ >=dev-qt/qtquickcontrols-${QTMIN}:5
+ >=dev-qt/qtquickcontrols2-${QTMIN}:5
+ >=kde-frameworks/kdeclarative-${PVCUT}:5
+ bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
+ kaccounts? (
+ kde-frameworks/purpose-kaccounts-services
+ >=net-libs/accounts-qml-0.7_p20231028[qt5(-)]
+ )
+"
+BDEPEND="kaccounts? ( dev-util/intltool )"
+
+src_prepare() {
+ ecm_src_prepare
+
+ use bluetooth ||
+ cmake_run_in src/plugins cmake_comment_add_subdirectory
bluetooth
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package kaccounts KAccounts)
+ )
+ ecm_src_configure
+}
+
+src_install() {
+ # Shipped by kde-frameworks/purpose-kaccounts-services package for
shared use w/ SLOT 5
+ use kaccounts && ECM_REMOVE_FROM_INSTALL=(
+
/usr/share/accounts/services/kde/{google-youtube,nextcloud-upload}.service
+ )
+ ecm_src_install
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ optfeature "Send through KDE Connect" kde-misc/kdeconnect
+ fi
+ ecm_pkg_postinst
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}
diff --git a/kde-frameworks/purpose/purpose-6.5.0-r1.ebuild
b/kde-frameworks/purpose/purpose-6.5.0-r1.ebuild
new file mode 100644
index 000000000000..3addb28b15b1
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-6.5.0-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=6.6.2
+inherit ecm frameworks.kde.org optfeature xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's
purposes fulfilled"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="bluetooth webengine"
+
+# requires running environment
+RESTRICT="test"
+
+DEPEND="
+ >=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+ >=dev-qt/qtdeclarative-${QTMIN}:6
+ =kde-frameworks/kconfig-${PVCUT}*:6
+ =kde-frameworks/kcoreaddons-${PVCUT}*:6
+ =kde-frameworks/ki18n-${PVCUT}*:6
+ =kde-frameworks/kio-${PVCUT}*:6
+ =kde-frameworks/kirigami-${PVCUT}*:6
+ =kde-frameworks/knotifications-${PVCUT}*:6
+ =kde-frameworks/kservice-${PVCUT}*:6
+ =kde-frameworks/prison-${PVCUT}*:6
+ webengine? (
+ kde-apps/kaccounts-integration:6
+ >=net-libs/accounts-qt-1.16_p20220803[qt6]
+ )
+"
+RDEPEND="${DEPEND}
+ >=kde-frameworks/kdeclarative-${PVCUT}:6
+ bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:6 )
+ webengine? (
+ >=kde-frameworks/purpose-kaccounts-services-${PVCUT}
+ >=net-libs/accounts-qml-0.7_p20231028[qt6]
+ )
+"
+BDEPEND="webengine? ( dev-util/intltool )"
+
+src_prepare() {
+ ecm_src_prepare
+
+ use bluetooth ||
+ cmake_run_in src/plugins cmake_comment_add_subdirectory
bluetooth
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package webengine KAccounts6)
+ )
+
+ ecm_src_configure
+}
+
+src_install() {
+ # Shipped by kde-frameworks/purpose-kaccounts-services package for
shared use w/ SLOT 5
+ use webengine && ECM_REMOVE_FROM_INSTALL=(
+
/usr/share/accounts/services/kde/{google-youtube,nextcloud-upload}.service
+ )
+ ecm_src_install
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ optfeature "Send through KDE Connect" kde-misc/kdeconnect
+ fi
+ ecm_pkg_postinst
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}
