[gentoo-commits] repo/gentoo:master commit in: dev-util/lttng-tools/

[Florian Schmaus]

commit:     44062b8f9b854c2d49509834a8c7b150deff48d4
Author:     Florian Schmaus <flow <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 27 09:00:40 2024 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Tue Aug 27 12:03:02 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=44062b8f

dev-util/lttng-tools: add 2.13.13

Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 dev-util/lttng-tools/Manifest                   |  1 +
 dev-util/lttng-tools/lttng-tools-2.13.13.ebuild | 50 +++++++++++++++++++++++++
 2 files changed, 51 insertions(+)

diff --git a/dev-util/lttng-tools/Manifest b/dev-util/lttng-tools/Manifest
index ab07ce3f261c..62cbc590db47 100644
--- a/dev-util/lttng-tools/Manifest
+++ b/dev-util/lttng-tools/Manifest
@@ -1 +1,2 @@
+DIST lttng-tools-2.13.13.tar.bz2 1950855 BLAKE2B 
1861284385a97af33b43b2e699850656cc92aa965263db39a2599d6fcd48668c6d062f11e931c91a1fcc62f32bd4614d3090c112b461b0fb423e9e9df0cc7013
 SHA512 
a128f1560357a65dc0e9b6244303f880768e423999b479e10984af030c479298cf64de7c2580e2959282ca83e7c8c2487988fb4a4512eaafd5fc09b79cbd6542
 DIST lttng-tools-2.13.9.tar.bz2 1892293 BLAKE2B 
51c4824435164196a77c8b6b3072810df83caf488c5fb692f9990b8d743ced2b07bffffa1e5a671149c75f3d96267f9c92f042c6c13503e03894f4c352c1733b
 SHA512 
ff7a395d9af3fc44561be24163a84ce27ddd1338f7df2805037645b98c4ad17496553f17b8f0ede7bee967d630b53000c080a91ea8e1ced25ce86b010941b94e

diff --git a/dev-util/lttng-tools/lttng-tools-2.13.13.ebuild 
b/dev-util/lttng-tools/lttng-tools-2.13.13.ebuild
new file mode 100644
index 000000000000..5c8ab318c0d8
--- /dev/null
+++ b/dev-util/lttng-tools/lttng-tools-2.13.13.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+# Please bump the following packages together:
+# dev-util/lttng-modules
+# dev-util/lttng-tools
+# dev-util/lttng-ust
+
+MY_P="${P/_rc/-rc}"
+MY_SLOT="$(ver_cut 1-2)"
+
+DESCRIPTION="Linux Trace Toolkit - next generation"
+HOMEPAGE="https://lttng.org";
+SRC_URI="https://lttng.org/files/${PN}/${MY_P}.tar.bz2";
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0/${MY_SLOT}"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ust"
+
+DEPEND="
+       >=dev-libs/userspace-rcu-0.11.0:=
+       dev-libs/popt
+       >=dev-libs/libxml2-2.7.6
+       ust? ( >=dev-util/lttng-ust-${MY_SLOT}.0:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+       pthread_get_name_np # different from pthread_getname_*, not on linux
+       pthread_set_name_np # different from pthread_setname_*, not on linux
+)
+
+src_configure() {
+       # bug 906928
+       use elibc_musl && append-cppflags -D_LARGEFILE64_SOURCE
+
+       econf $(usex ust "" --without-lttng-ust)
+}
+
+src_install() {
+       default
+       find "${ED}" -type f -name '*.la' -delete || die
+}