commit: e64a92899df27b01245cd7dbf87fa530739459de
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 10 02:29:59 2024 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Sep 10 02:31:40 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e64a9289
app-portage/gentoolkit: Version bump to 0.6.8
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
app-portage/gentoolkit/Manifest | 1 +
app-portage/gentoolkit/gentoolkit-0.6.8.ebuild | 127 +++++++++++++++++++++++++
2 files changed, 128 insertions(+)
diff --git a/app-portage/gentoolkit/Manifest b/app-portage/gentoolkit/Manifest
index 27d5cee1963f..30f127a1258a 100644
--- a/app-portage/gentoolkit/Manifest
+++ b/app-portage/gentoolkit/Manifest
@@ -2,3 +2,4 @@ DIST gentoolkit-0.6.3.tar.bz2 3186163 BLAKE2B
0f9befac53faa2b578b461a55c7113934a
DIST gentoolkit-0.6.5.tar.bz2 3186457 BLAKE2B
7f873385b183e51b03e1c4be0edbabc89556e1b3a1dce2be71584c9ea927dd09185ba1022e570de0ed2a46cbb764c67f6eaccf97dc5892f4f355244bac7c0545
SHA512
cff9e7b1b8122941b03f7e156f25b5b416c5e4bbf1b759ecf006c271758f2548323bf59ba94a14f3268eea43081ccbba3ab63e118123af870c0257aaecbb9554
DIST gentoolkit-0.6.6.tar.bz2 3187351 BLAKE2B
f8add246e9d968c57a8d0e5c842a40a7646e92cc165ca611df35988ba55bd0221a26eefb351680f53e81adcf608a20eab604d0a9b9e52f936ebc7c20575c597c
SHA512
73fc4b8d98dc118d3c505c49d94dd248c92d2bde883c130c65dcf814d200a165084e9c94713e93341e7c54b59b59db83279538440e0822902de688c135b8949d
DIST gentoolkit-0.6.7.tar.bz2 3187598 BLAKE2B
54c576fa7ded310fae24100171e069bfc79c0f908199384d33cac34d49f62e5cac4bda3e7f93db1866f8d4cf75afb465d82038eebb4df27070e14e73fba65feb
SHA512
a5fb73c9b43e74541ccbb0537f860b6623284b84feb8922c95b5b5dd1dbd3db5117cbc3f899483c1a99086fcd8ddf49f71b81475e29af9e8bcdd1255553501fe
+DIST gentoolkit-0.6.8.tar.bz2 3190065 BLAKE2B
2f792d174a25c03e0f1b895fe06282412d383561e5456d5b4d2d918f7648790846fa9390b3bb9c862618ffefe749d9ccc236682be9fecde12ef8fda17c79359d
SHA512
91ba97d8000d90350ea63c4d3be69dda919795b62ae84fe264ae8fee24ce6f6250599e03b086a334344df402781372ba9ced4cedb1c2fc66e2a4f6115ee57fc5
diff --git a/app-portage/gentoolkit/gentoolkit-0.6.8.ebuild
b/app-portage/gentoolkit/gentoolkit-0.6.8.ebuild
new file mode 100644
index 000000000000..a463fae5ad9d
--- /dev/null
+++ b/app-portage/gentoolkit/gentoolkit-0.6.8.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+PYTHON_REQ_USE="xml(+),threads(+)"
+
+inherit meson python-r1 tmpfiles
+
+if [[ ${PV} = 9999* ]]; then
+ EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/gentoolkit.git";
+ inherit git-r3
+else
+
SRC_URI="https://gitweb.gentoo.org/proj/gentoolkit.git/snapshot/${P}.tar.bz2";
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc
~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos
~x64-macos ~x64-solaris"
+fi
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage-Tools";
+
+LICENSE="GPL-2"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Need newer Portage for eclean-pkg API, bug #900224
+DEPEND="
+ >=sys-apps/portage-3.0.57[${PYTHON_USEDEP}]
+"
+RDEPEND="
+ ${DEPEND}
+ ${PYTHON_DEPS}
+ app-alternatives/awk
+ sys-apps/gentoo-functions
+"
+
+# setuptools is still needed as a workaround for Python 3.12+ for now.
+# https://github.com/mesonbuild/meson/issues/7702
+#
+# >=meson-1.2.1-r1 for bug #912051
+BDEPEND="
+ ${PYTHON_DEPS}
+ >=dev-build/meson-1.2.1-r1
+ $(python_gen_cond_dep '
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ ' python3_12)
+ test? (
+ dev-python/pytest[${PYTHON_USEDEP}]
+ )
+"
+
+src_prepare() {
+ default
+ if use prefix-guest ; then
+ # use correct repo name, bug #632223
+ sed -i \
+ -e
"/load_profile_data/s/repo='gentoo'/repo='gentoo_prefix'/" \
+ pym/gentoolkit/profile.py || die
+ fi
+}
+
+src_configure() {
+ local code_only=false
+ python_foreach_impl my_src_configure
+}
+
+my_src_configure() {
+ local emesonargs=(
+ -Dcode-only=${code_only}
+ $(meson_use test tests)
+ -Deprefix="${EPREFIX}"
+ -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+ )
+
+ meson_src_configure
+ code_only=true
+}
+
+src_compile() {
+ python_foreach_impl meson_src_compile
+}
+
+src_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ python_foreach_impl epytest
+}
+
+src_install() {
+ python_foreach_impl my_src_install
+ dotmpfiles data/tmpfiles.d/revdep-rebuild.conf
+
+ local scripts
+ mapfile -t scripts < <(awk '/^#!.*python/ {print FILENAME} {nextfile}'
"${ED}"/usr/bin/* || die)
+ python_replicate_script "${scripts[@]}"
+}
+
+my_src_install() {
+ local pydirs=(
+ "${D}$(python_get_sitedir)"
+ )
+
+ meson_src_install
+ python_optimize "${pydirs[@]}"
+}
+
+pkg_postinst() {
+ tmpfiles_process revdep-rebuild.conf
+
+ # Only show the elog information on a new install
+ if [[ ! ${REPLACING_VERSIONS} ]]; then
+ elog
+ elog "For further information on gentoolkit, please read the
gentoolkit"
+ elog "guide: https://wiki.gentoo.org/wiki/Gentoolkit";
+ elog
+ elog "Another alternative to equery is
app-portage/portage-utils"
+ elog
+ elog "Additional tools that may be of interest:"
+ elog
+ elog " app-admin/eclean-kernel"
+ elog " app-portage/diffmask"
+ elog " app-portage/flaggie"
+ elog " app-portage/portpeek"
+ elog " app-portage/smart-live-rebuild"
+ fi
+}
