commit: 2285d5f71677f2d4a696bc2ee8f12eee1c1ab27a
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 20 04:43:36 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Sep 20 04:43:36 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2285d5f7
dev-python/kombu: Bump to 5.4.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/kombu/Manifest | 1 +
dev-python/kombu/kombu-5.4.2.ebuild | 84 +++++++++++++++++++++++++++++++++++++
2 files changed, 85 insertions(+)
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index a61b57bb3d8b..db802ed60263 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
DIST kombu-5.4.1.tar.gz 442786 BLAKE2B
b9772bd3a2ebabc4424b029ef72b7378dc2c4f4b0f6002732e5466910589d2c056317bc49ee7c9b3bc8dd02a820614eaf75dfcdebdade84d58fe919b5d11126a
SHA512
e0ccab1037e840f11bbdd1f7055df4b25e09c5a00716b1b6b1d754fe7e73b21cc1f85062cb544321eb87bf3eb294837373496e1dca6266c9bc27ed68f7e2c1d8
+DIST kombu-5.4.2.tar.gz 442858 BLAKE2B
a613f3a5656c87826345d7e96b4ccf15336afdcd79a77db04140628f8522cb6f348fa31d3ccba66b6d01c423971ae013f157a812e12662bf4639fd4f4dbfc750
SHA512
4224412b8d3ee867af03a1771326681f78d112f31ab7ecd7c0f648bd28e834b296c1b36b7720351ec8e0ba871153caaa6aa06961394c5a9e99cd68291ad20b9b
diff --git a/dev-python/kombu/kombu-5.4.2.ebuild
b/dev-python/kombu/kombu-5.4.2.ebuild
new file mode 100644
index 000000000000..7ff12e4b2201
--- /dev/null
+++ b/dev-python/kombu/kombu-5.4.2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+ https://github.com/celery/kombu/
+ https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+ <dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+ dev-python/tzdata[${PYTHON_USEDEP}]
+ dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ >=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+ dev-python/pycurl[${PYTHON_USEDEP}]
+ >=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+ dev-python/pytest-freezer[${PYTHON_USEDEP}]
+ dev-python/zstandard[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+ >=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+ dev-python/sphinx-celery
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+ )
+ local EPYTEST_IGNORE=(
+ # obsolete Pyro4
+ t/unit/transport/test_pyro.py
+ # unpackaged azure
+ t/unit/transport/test_azurestoragequeues.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+ optfeature "Etcd backend" dev-python/python-etcd
+ optfeature "MongoDB backend" dev-python/pymongo
+ optfeature "Redis backend" dev-python/redis
+ optfeature "sqlalchemy backend" dev-python/sqlalchemy
+ optfeature "yaml backend" dev-python/pyyaml
+ optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+ optfeature "brotli compression" "app-arch/brotli[python]"
+ optfeature "zstd compression" dev-python/zstandard
+}
