[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-backend/

[Michał Górny]

commit:     63fb78c602ff43eea3b85378ea7022b67dc7a7d4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 21 06:39:31 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Sep 21 07:40:57 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=63fb78c6

dev-python/pdm-backend: Bump to 2.4.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-backend/Manifest                 |  1 +
 dev-python/pdm-backend/pdm-backend-2.4.0.ebuild | 75 +++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index 7e22ae5f79da..1d54ae5e948f 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.3.3.gh.tar.gz 136942 BLAKE2B 
14f2584f22f1c4e08f687c77621269ae1e5acfe4babb1ab427c10d65ff07841b8175479f867870b9a5745db76444ca140a7da497a94c831ca6d0ea1e67b4e88f
 SHA512 
382ad95e2811f1142fee66065f96ede1a646c3e2b9fbfafc6afb17442d3aeccfbf1ff6260952986a025791d3d56a2c4b730decb3cb65e893c25a710e16cbcfc8
+DIST pdm-backend-2.4.0.gh.tar.gz 138766 BLAKE2B 
75295c6c72e34dd70d60a05949f4c0646cb5db45c2e9d952cd498395956dd3171bd293b0d5246dc782f5bb90ddfa7326fec75d4d4d8767de79e7c284cc1a9f08
 SHA512 
cd78cc2c9c8bd4964504aa495c9cd2ffa0d14da9e8e3aac6a3cc15045b0385e474214ae15c4ace57fd2ef87e0067a521355fd513610ef9aeadf276b2fe41d28d

diff --git a/dev-python/pdm-backend/pdm-backend-2.4.0.ebuild 
b/dev-python/pdm-backend/pdm-backend-2.4.0.ebuild
new file mode 100644
index 000000000000..178f44f54a53
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.4.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+       https://pypi.org/project/pdm-backend/
+       https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+       https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv 
~s390 ~sparc ~x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+       >=dev-python/editables-0.5[${PYTHON_USEDEP}]
+       >=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+       >=dev-python/pyproject-metadata-0.8.0[${PYTHON_USEDEP}]
+       >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+       $(python_gen_cond_dep '
+               >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+       ' 3.10)
+"
+BDEPEND="
+       ${RDEPEND}
+       test? (
+               dev-python/setuptools[${PYTHON_USEDEP}]
+               dev-vcs/git
+       )
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       rm -r src/pdm/backend/_vendor || die
+       find -name '*.py' -exec sed \
+               -e 's:from pdm\.backend\._vendor\.:from :' \
+               -e 's:from pdm\.backend\._vendor ::' \
+               -e 's:import pdm\.backend\._vendor\.:import :' \
+               -i {} + || die
+       distutils-r1_src_prepare
+}
+
+src_compile() {
+       # this must not be set during src_test()
+       local -x PDM_BUILD_SCM_VERSION=${PV}
+       distutils-r1_src_compile
+}
+
+src_test() {
+       git config --global user.email "t...@example.com" || die
+       git config --global user.name "Test User" || die
+       distutils-r1_src_test
+}
+
+python_test() {
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       epytest -k "not [hg"
+}