commit: 9db0ada89d4f1d58f22c108dbdf244fc540f2e2e
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 25 03:31:30 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Sep 25 04:38:53 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9db0ada8
dev-python/pylint: Bump to 3.3.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pylint/Manifest | 1 +
dev-python/pylint/pylint-3.3.1.ebuild | 92 +++++++++++++++++++++++++++++++++++
2 files changed, 93 insertions(+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 3990bc8b621c..6fcbb425fcfc 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1,2 +1,3 @@
DIST pylint-3.2.7.gh.tar.gz 1448329 BLAKE2B
4ec4a0e2a886e7acc4694582e7f7902b6806750a12286986533a4e57c68eeac96bec43bb4cef2de6ec0a7811cde5ec2cc03226b2213d1b2107aafe73db03c32d
SHA512
66dbf0f05aa7aac59f43cab6a1f23c29a3a37d9a19f2c54af0e0aa6f2630fc74d7602a6b6a250e1e02a24723d0513c54a7ee704026af16c8acc50b843708fd98
DIST pylint-3.3.0.gh.tar.gz 1453518 BLAKE2B
407ab1a3db4ae832c8ab7f26c3d3cd02c686305050f0dbd1168fe00e2e267aa169a99eb7e9a3a858a5ad58752a1e8a193692224c39971da93374da72a3d66ea7
SHA512
52bfc54691e5ea323032909c6e2bd8f265c70cc4941cb51ce4eb25e86ebfb22c54fdd9c92a8b5c518cbbcbb48894a9ae7bf2dcd6c2993533acb21ff3f9786f02
+DIST pylint-3.3.1.gh.tar.gz 1453572 BLAKE2B
e756d72c0757a8d90491fddaa5a60cccedde043b4dbaf9162ccabd920bbb864bf109f619483474748a606dedb4bf889a57edb447ef77a40c7ee35e2019caf277
SHA512
86cb0019f53477346de44a7cf22b6ee6ec791d2cfc23ec0c1ffcc749752d52f255aa5dcfaaf7b124706ce8a87013d5e592c0896c527e10b8df06c974f440d3c6
diff --git a/dev-python/pylint/pylint-3.3.1.ebuild
b/dev-python/pylint/pylint-3.3.1.ebuild
new file mode 100644
index 000000000000..78ddf6bce504
--- /dev/null
+++ b/dev-python/pylint/pylint-3.3.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+ https://pypi.org/project/pylint/
+ https://github.com/pylint-dev/pylint/
+"
+SRC_URI="
+ https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+ <dev-python/astroid-3.4[${PYTHON_USEDEP}]
+ >=dev-python/astroid-3.3.4[${PYTHON_USEDEP}]
+ >=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+ <dev-python/isort-6[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ $(python_gen_cond_dep '
+ >=dev-python/GitPython-3[${PYTHON_USEDEP}]
+ ' 'python*' )
+ >=dev-python/pytest-8.3[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-4.12[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
'tests/test_functional.py::test_functional[dataclass_with_field]'
+ 'tests/test_functional.py::test_functional[no_name_in_module]'
+ 'tests/test_functional.py::test_functional[shadowed_import]'
+ 'tests/test_functional.py::test_functional[use_yield_from]'
+ 'tests/test_functional.py::test_functional[wrong_import_order]'
+ )
+ local EPYTEST_IGNORE=(
+ # No need to run the benchmarks
+ tests/benchmark/test_baseline_benchmarks.py
+ )
+
+ if ! has_version "dev-python/GitPython[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/profile/test_profile_against_externals.py
+ tests/testutils/_primer/test_package_to_lint.py
+ tests/testutils/_primer/test_primer.py
+ )
+ fi
+
+ rm -rf pylint || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p timeout
+}
+
+python_install_all() {
+ if use examples ; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+
+ distutils-r1_python_install_all
+}
