commit: 48ff1270205c1a56e1bc82c6096f658a637eb6f6
Author: Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 3 13:43:59 2024 +0000
Commit: Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Thu Oct 3 15:08:45 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=48ff1270
app-emacs/racket-mode: bump to 1_p20241001
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>
app-emacs/racket-mode/Manifest | 1 +
.../racket-mode/racket-mode-1_p20241001.ebuild | 78 ++++++++++++++++++++++
2 files changed, 79 insertions(+)
diff --git a/app-emacs/racket-mode/Manifest b/app-emacs/racket-mode/Manifest
index ce4b86bc2c0b..673ec2fb9952 100644
--- a/app-emacs/racket-mode/Manifest
+++ b/app-emacs/racket-mode/Manifest
@@ -1 +1,2 @@
DIST racket-mode-1_p20240718.tar.gz 382546 BLAKE2B
0d6b33a183751cb9601f9532645b45c01c7fdcc1d1902f316f7ed3446dec943cd65f9a0c0204051509d2e607e68647146b7c8719f75fb0d030a2dac299266195
SHA512
7e262a93378ddde154d16b3349f29faf57531e684b9aa26579dadc0746306917398ca37ee11a243b5ad3c33f1ba41b3650f68579354a260b76ed6cee0765a535
+DIST racket-mode-1_p20241001.tar.gz 387873 BLAKE2B
ad95eeed061a43b681919a6b14688d8755ad9c83b1ec14fe835ae92e692c1f7431bd986000bce95063094146604154bd38767c3db83b6a7756805269997829dc
SHA512
60672f1e8ed46bffc89686104971c48382ffd46ffdab0c2caa86f06349425ac8a2de9770608953249949caab6bd8b0d914b21dfd06f1cfda5fd87f76d92a259e
diff --git a/app-emacs/racket-mode/racket-mode-1_p20241001.ebuild
b/app-emacs/racket-mode/racket-mode-1_p20241001.ebuild
new file mode 100644
index 000000000000..db2875b6dee8
--- /dev/null
+++ b/app-emacs/racket-mode/racket-mode-1_p20241001.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+[[ "${PV}" == *p20241001 ]] &&
COMMIT="ec8b5142abaaef8335c23b98c18dee1f960b6e0b"
+
+inherit elisp
+
+DESCRIPTION="Emacs modes for Racket: edit, REPL, check-syntax, debug, profile,
and more"
+HOMEPAGE="https://www.racket-mode.com/
+ https://github.com/greghendershott/racket-mode/";
+
+if [[ "${PV}" == *9999* ]] ; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/greghendershott/${PN}.git";
+else
+
SRC_URI="https://github.com/greghendershott/${PN}/archive/${COMMIT}.tar.gz
+ -> ${P}.tar.gz"
+ S="${WORKDIR}/${PN}-${COMMIT}"
+
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-scheme/racket:=[-minimal]
+"
+BDEPEND="
+ ${RDEPEND}
+"
+
+ELISP_REMOVE="
+ test/racket/hash-lang-test.rkt
+"
+PATCHES=(
+ "${FILESDIR}/${PN}-rkt-source-dir.patch"
+)
+
+DOCS=( CONTRIBUTING.org README.org THANKS.org )
+ELISP_TEXINFO="doc/${PN}.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+ elisp_src_prepare
+
+ sed "s|@SITEETC@|${SITEETC}/${PN}|" -i "${S}/racket-util.el" || die
+}
+
+src_compile() {
+ elisp_src_compile
+
+ # Equivalent to compiling from Emacs with "racket-mode-start-faster",
+ # because this is installed globally we have to compile it now.
+ ebegin "Compiling Racket source files"
+ find "${S}/racket" -type f -name "*.rkt" -exec raco make -v {} +
+ eend $? "failed to compile Racket source files" || die
+}
+
+src_test() {
+ # Set "PLTUSERHOME" to a safe temp directory to prevent writing to "~".
+ local -x PLTUSERHOME="${T}/racket-mode/test-racket"
+
+ emake test-racket
+}
+
+src_install() {
+ elisp_src_install
+
+ # Install Racket files to "${SITEETC}".
+ insinto "${SITEETC}/${PN}"
+ doins -r racket
+}
