commit: c7d4114383a3f9ac4c8a764853b1739ccdab7d1b
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 4 02:45:09 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct 4 03:12:20 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c7d41143
dev-python/statsmodels: Bump to 0.14.4
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/statsmodels/Manifest | 1 +
dev-python/statsmodels/statsmodels-0.14.4.ebuild | 80 ++++++++++++++++++++++++
2 files changed, 81 insertions(+)
diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
index 78610660bc56..384d60d1ddfc 100644
--- a/dev-python/statsmodels/Manifest
+++ b/dev-python/statsmodels/Manifest
@@ -1,2 +1,3 @@
DIST statsmodels-0.14.2.tar.gz 20352531 BLAKE2B
65053842ab979b6c2541baddc09f9ade4f55ca988451218b2e4fd2caf7af0e7891eaccf317e9715f35c3d002f8976ea637712173d58db1b5b7822658bdfc79dd
SHA512
0a38482bccac61081ff0c8de3b9fcf81689ec15437c53d79a8949df058e0ac8a4e93136a50a37a06577108dc29f1a51e0d00e041ee7e8f9dff93b6e8cf1f0f16
DIST statsmodels-0.14.3.tar.gz 20354488 BLAKE2B
113e90f7091197a5561e311bc033dfc3d9d28732fbcbae4fce13ec58f16db63ec1e25c54e411a8ff04d059f3f2df7c45dc484918235653df4d1f809cc40260af
SHA512
c7b8684be83b179edcdbed7703005d054a1f16b9731add69b5079a62e5e858bef87c34e00575580fd48ef80cc9108d405edec9e6a2cf3eb3e5e8f7fed53f8fca
+DIST statsmodels-0.14.4.tar.gz 20354802 BLAKE2B
c721c5b2e7b22ad1be10099627230f7344f966a335f37757dc6bb622fedcb1e84a7d708ee25bfdde64357394e059567e41dad19fc5b1daeb3d5ee29e52a3b2af
SHA512
db3bd19b8b47af453ad6fbd24449a621895e4237bbc8b7813810306748c32a3fbf005387a0e1e8db550c9c4a59666bdd50aeb49e24f0ecb86619bc90f166f5f9
diff --git a/dev-python/statsmodels/statsmodels-0.14.4.ebuild
b/dev-python/statsmodels/statsmodels-0.14.4.ebuild
new file mode 100644
index 000000000000..3b129f1595f7
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.14.4.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="
+ https://www.statsmodels.org/stable/index.html
+ https://github.com/statsmodels/statsmodels/
+ https://pypi.org/project/statsmodels/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~riscv ~amd64-linux"
+IUSE="examples"
+
+# NB: upstream requires building with numpy-2 but supports 1.x
+# at runtime
+DEPEND="
+ >=dev-python/numpy-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+RDEPEND="
+ >=dev-python/numpy-1.22.3[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+ >=dev-python/pandas-1.4[${PYTHON_USEDEP}]
+ >=dev-python/patsy-0.5.6[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ ${DEPEND}
+ >=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+ >=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+ 'dev-python/ipykernel' \
+ 'dev-python/jupyter-client' \
+ 'dev-python/matplotlib' \
+ 'dev-python/nbconvert' \
+ 'dev-python/numpydoc'
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ export VARTEXFONTS="${T}"/fonts
+ export MPLCONFIGDIR="${T}"
+ printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ local -x MKL_NUM_THREADS=1
+ local -x OMP_NUM_THREADS=1
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ epytest statsmodels
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x /usr/share/doc/${PF}/examples
+ dodoc -r examples
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Plotting functionality" "dev-python/matplotlib"
+}
