commit: 56a37245e02b1f21364918f6dd9b900a473cdb84
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 6 01:40:26 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct 6 01:40:26 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=56a37245
dev-python/hypothesis: Bump to 6.112.3
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hypothesis/Manifest | 1 +
dev-python/hypothesis/hypothesis-6.112.3.ebuild | 103 ++++++++++++++++++++++++
2 files changed, 104 insertions(+)
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index be8f01928d75..4d1e93c177bc 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,2 +1,3 @@
DIST hypothesis-6.112.1.gh.tar.gz 9476397 BLAKE2B
adee46d6a4cf56bbbd8e5a91afc8236b9d311aa18efeaf6b367fc32d5ff3d679e08c5a8c500cedb50ff2cda2bab567a56f5ed564067972bc2f63bd6f5f0b88e1
SHA512
60b68f50a5d8d7ec23b2632a1a3c7d412ecedef6e58ec9e2f0450b07add9ddaa25963cd08cfa1d60741ff54cc47996da02dab1176ab25b8e7ecd3154f1b0446d
DIST hypothesis-6.112.2.gh.tar.gz 9476114 BLAKE2B
50b4dd0e7599732b78fea672738c20b3b20bd51ede08816c63e2adb841e1b441994be68b203bd4cf826d2f258f81b91510668b0b141658938ec31fc14bb464cb
SHA512
e4544feb0e12e4bfa380a3e31f33b3898e365fd6063586c1831ee39c21c0447e17d2f10066d59e1c576e6135ae6987ea2b49dfb09a1eeaa379893748b7caa4bd
+DIST hypothesis-6.112.3.gh.tar.gz 9476186 BLAKE2B
bd11e2b09c192943363a917b327c0d5d85dcb1e4161bbbaf63754353e784e4e909279084b6efd622144e97a88ad8ab64002264f2b512185f6af687303e5b19e5
SHA512
1a0a982dd3d006b6143479e7b6f4ee70c3a196eddd06ade54c53342f40cba5537d09f5da806604673096b17bf29515d93b325f306d8fbf4d7802b0fda1acd922
diff --git a/dev-python/hypothesis/hypothesis-6.112.3.ebuild
b/dev-python/hypothesis/hypothesis-6.112.3.ebuild
new file mode 100644
index 000000000000..f3d89f9d71ea
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.112.3.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+ https://github.com/HypothesisWorks/hypothesis/
+ https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+ https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ >=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+ ' 3.9 3.10)
+ cli? (
+ $(python_gen_cond_dep '
+ dev-python/black[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ ' "${CLI_COMPAT[@]}")
+ )
+"
+BDEPEND="
+ test? (
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ >=dev-python/pytest-8[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ !!<dev-python/requests-toolbelt-0.10.1
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+ # subtests are broken by warnings from random plugins
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+ local -x HYPOTHESIS_NO_PLUGINS=1
+
+ # NB: paths need to be relative to pytest.ini,
+ # i.e. start with hypothesis-python/
+ local EPYTEST_DESELECT=()
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+ # failing due to warnings from numpy/cython
+
hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+ )
+ ;;
+ esac
+
+ epytest -o filterwarnings= tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+ local HAD_CLI=
+
+ distutils-r1_src_install
+
+ if [[ ! ${HAD_CLI} ]]; then
+ rm -r "${ED}/usr/bin" || die
+ fi
+}
+
+python_install() {
+ distutils-r1_python_install
+ if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+ HAD_CLI=1
+ else
+ rm -r "${D}$(python_get_scriptdir)" || die
+ fi
+}
+
+pkg_postinst() {
+ optfeature "datetime support" dev-python/pytz
+ optfeature "dateutil support" dev-python/python-dateutil
+ optfeature "numpy support" dev-python/numpy
+ optfeature "django support" dev-python/django dev-python/pytz
+ optfeature "pandas support" dev-python/pandas
+ optfeature "pytest support" dev-python/pytest
+}
