commit: 5fab5742847fc7d26c3d7c874808a750c17ba9cb
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 17 16:35:03 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 17 17:03:08 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5fab5742
dev-python/tox: Bump to 4.23.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/tox/Manifest | 1 +
dev-python/tox/tox-4.23.0.ebuild | 98 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 99 insertions(+)
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 810abb55a630..b3f94a1c23b1 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,4 @@
DIST tox-4.20.0.tar.gz 181364 BLAKE2B
2651bb2a7eff09764b7288c0640d44031f2074f8c1c41aaf18989cdc3b8828d6b91f90b131a11b31ed01c4819524aedd4acedb56da2716eb5e3e607a8d5f1bf2
SHA512
c4b9a03a62c7d1993a8b027cd2f8f22fc033fa802176f20b0daeda84d528c5e8618ae9781f04c3d8820d9f49c5786d56b96dd596e95e489ac372631d61425616
DIST tox-4.21.2.tar.gz 188539 BLAKE2B
f729857e18a34a21b3963bc0089891a2e52c03411d79a20838322540f01efa17d6fa8ac0ebf5612ad425d3ce565975cc266ba2820d0f2d0d76017801c221de4c
SHA512
a2a363ecaa88ac459e147471c1dca7152e21f77f38253b484a15fa908ea8b0e758761e8c2c475bb6bd374a636cb10004c7c2fb6c61fe3718b2b1c09569d0f08d
DIST tox-4.22.0.tar.gz 189907 BLAKE2B
8a3ff89838a532b4cb42b4624d56d9d008319198b61edcf6ebcc609296b9d358b91ba17c262b17893321d5737c5ed51c23b495348d084e8712142e77b9c4af1a
SHA512
5bce8cbc826f2cfc54b2824e023fdef21120183a65688113a956691759b885c22135fcce551e3cf0430412d6f85ccd7ec568495e47e7645766049ed0a55fae97
+DIST tox-4.23.0.tar.gz 189943 BLAKE2B
5a2b0bce52626eb3faf5e0ab65419edae2aa0e436fc0f1e64cb07fcdd9d1c06c7b2a19898ff9c2c54137392d480d98e10c59c1be9e5318eaff276b85cfe82a06
SHA512
1c5f685334d0e885f8c17c94ffaa82502629aff1654efe9c544cc6e4d49a0d3a26eef4a05ab97246ebb31b63ee341776fb9240e5412cace68eb84f572283dbec
diff --git a/dev-python/tox/tox-4.23.0.ebuild b/dev-python/tox/tox-4.23.0.ebuild
new file mode 100644
index 000000000000..35198cd27b99
--- /dev/null
+++ b/dev-python/tox/tox-4.23.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+ https://tox.readthedocs.io/
+ https://github.com/tox-dev/tox/
+ https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86"
+
+RDEPEND="
+ dev-python/cachetools[${PYTHON_USEDEP}]
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/colorama[${PYTHON_USEDEP}]
+ dev-python/filelock[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ dev-python/platformdirs[${PYTHON_USEDEP}]
+ dev-python/pluggy[${PYTHON_USEDEP}]
+ dev-python/pyproject-api[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/tomli[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ ' 3.10)
+ dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/hatch-vcs[${PYTHON_USEDEP}]
+ test? (
+ dev-python/build[${PYTHON_USEDEP}]
+ dev-python/distlib[${PYTHON_USEDEP}]
+ dev-python/flaky[${PYTHON_USEDEP}]
+ dev-python/psutil[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ dev-python/re-assert[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/time-machine[${PYTHON_USEDEP}]
+ ' 'python*')
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ # upstream lower bounds are meaningless
+ sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ # devpi_process is not packaged, and has lots of dependencies
+ cat > "${T}"/devpi_process.py <<-EOF || die
+ def IndexServer(*args, **kwargs): raise NotImplementedError()
+ EOF
+
+ local -x PYTHONPATH=${T}:${PYTHONPATH}
+ local EPYTEST_DESELECT=(
+ # Internet
+
tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+
tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+ )
+ local EPYTEST_IGNORE=(
+ # requires devpi*
+ tests/test_provision.py
+ )
+
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+ )
+ ;;
+ python3.13)
+ EPYTEST_DESELECT+=(
+ # https://github.com/tox-dev/tox/issues/3290
+
'tests/config/loader/test_str_convert.py::test_str_convert_ok_py39[1,2-value1-Optional]'
+ )
+ ;;
+ esac
+
+ epytest
+}
