[gentoo-commits] repo/gentoo:master commit in: dev-libs/qcoro/

[Andreas Sturmlechner]

commit:     75a3255317504d75be1b114e8c1c8bd06212a544
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 17 17:54:49 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Oct 17 17:59:26 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=75a32553

dev-libs/qcoro: add 0.11.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/qcoro/Manifest            |  1 +
 dev-libs/qcoro/qcoro-0.11.0.ebuild | 60 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/qcoro/Manifest b/dev-libs/qcoro/Manifest
index 8c665b3100eb..923b4a898db8 100644
--- a/dev-libs/qcoro/Manifest
+++ b/dev-libs/qcoro/Manifest
@@ -1 +1,2 @@
 DIST qcoro-0.10.0.tar.gz 150114 BLAKE2B 
8a552dc3a0e4a5963c7c9fd0638f336e6ad99491a54df3bb8ddaa6b0ee1fe8e4c6b7ffc26c25cef543e796c54bc4c625a0915755f4b538f489bc61fcd8310a6a
 SHA512 
de2e55256d3c9d35fec3ef6dc78128801b70a5e5b8ff0f3a6f235dac17f349ea44207a7c9f35375215dbeea04cb67c3412d505d0a8a95f2b926775f804a02649
+DIST qcoro-0.11.0.tar.gz 157896 BLAKE2B 
f857c90eceea0e21938c1605e53fde21098226087804d39abfab10eb2bd26984332ae1fa896290ecbc644e34e6417f46b7c4919c91383964610adde3adc435a8
 SHA512 
bde5c5cd9f3c038e6b5ec5a6adae5ae2218edd9df350e75fc5d8db31d9339484e92cc88fdc37fa0539e0cdf1f53731418ebfa73b94564e993d7b02168988771b

diff --git a/dev-libs/qcoro/qcoro-0.11.0.ebuild 
b/dev-libs/qcoro/qcoro-0.11.0.ebuild
new file mode 100644
index 000000000000..2d6c10b669a2
--- /dev/null
+++ b/dev-libs/qcoro/qcoro-0.11.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/danvratil/${PN}";
+else
+       
SRC_URI="https://github.com/danvratil/${PN}/archive/refs/tags/v${PV}.tar.gz -> 
${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="C++ Coroutine Library for Qt"
+HOMEPAGE="https://qcoro.dvratil.cz/ https://github.com/danvratil/qcoro";
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="dbus examples +network qml test websockets"
+
+REQUIRED_USE="examples? ( network )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       dev-qt/qtbase:6[dbus?,network?]
+       qml? (
+               dev-qt/qtbase:6[gui]
+               dev-qt/qtdeclarative:6=
+       )
+       websockets? ( dev-qt/qtwebsockets:6 )
+"
+DEPEND="${RDEPEND}
+       examples? ( dev-qt/qtbase:6[concurrent,network,widgets] )
+       test? ( dev-qt/qtbase:6[concurrent] )
+"
+
+src_configure() {
+       local mycmakeargs=(
+               -DUSE_QT_VERSION=6
+               -DQCORO_BUILD_EXAMPLES=$(usex examples)
+               -DQCORO_WITH_QTDBUS=$(usex dbus)
+               -DQCORO_WITH_QTNETWORK=$(usex network)
+               -DQCORO_WITH_QML=$(usex qml)
+               -DQCORO_WITH_QTQUICK=$(usex qml)
+               -DQCORO_WITH_QTTEST=ON
+               -DBUILD_TESTING=$(usex test)
+               -DQCORO_WITH_QTWEBSOCKETS=$(usex websockets)
+       )
+       cmake_src_configure
+}
+
+src_install() {
+       if use examples; then
+               docinto examples
+               dodoc -r examples/*
+       fi
+       cmake_src_install
+}