commit: 6d161b07bdbe7f4257af767e8e151e4dce7e69c5
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 21 15:09:47 2024 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Mon Oct 21 15:28:38 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6d161b07
net-wireless/iwd: add 3.0
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
net-wireless/iwd/Manifest | 1 +
net-wireless/iwd/iwd-3.0.ebuild | 167 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 168 insertions(+)
diff --git a/net-wireless/iwd/Manifest b/net-wireless/iwd/Manifest
index c4236c8f2f66..0d625cd551da 100644
--- a/net-wireless/iwd/Manifest
+++ b/net-wireless/iwd/Manifest
@@ -3,3 +3,4 @@ DIST iwd-2.19.tar.xz 1088892 BLAKE2B
0bd332b41b205ed8b396e672fb869c8d78a9b18d946
DIST iwd-2.20.tar.xz 1092832 BLAKE2B
34001bc34c07a40f34bb8a30258d9493a38957fd0d5ea83f5721d4441b78c5c061e2bb84380932422cdd695f37eac4b1c40d6535965b06d5f255fae64734d956
SHA512
ddfcc22539185be8847dedde4d3c8e86af0d71f3d1befd5bfaa57d5e75222676db3f49530f1082b531149164aee0411dcf76e4a78a41c3d878b2920197bfccea
DIST iwd-2.21.tar.xz 1095396 BLAKE2B
8681532e7125488750b68f5deb7b2c9fc16ed665a762cabeed5a002424cc474e8e47753e71b42ec22a2c004368b81f0087437e4689c11981df43a92b54eb3db5
SHA512
48c444e653486e86f443588ebc844781ff7aa9ba438f5fa50097c4021a822bb522a326a6e29b11ed2dc0de45230dff210906830746d0bc2fc4dd25479eb48773
DIST iwd-2.22.tar.xz 1095092 BLAKE2B
69db8bf4d0c5dae0d3b569f7f04f2361b3b3eef0ba5084d5c12684a9d18611611708ac077efe2df2085c7352273d28fe23c7e1145883c513cb4fdfed0f1f835e
SHA512
fca6f50b849e6b4fc18a8cf0163e0d532f09b71e593d37f21bdc1b4878bddd7c96b481a3bb45ee6d36f4b1fd2ad76e428f9d1dd1b64ba77545227d3740b1a210
+DIST iwd-3.0.tar.xz 1096812 BLAKE2B
a459a1d27a03631897a40c958dcf5ba451d09a1621207beaca20002e4056b0b72eade0b1cfbf26d3365346fbe204720841175f9f1e5370482375314c4a74b851
SHA512
d3c02fb034c471358817dc3f72eb0b96570004e042b704eee619a4ef44881486cfcfe9dfeedd0ff4ac9f70d07a5e68ce5626dc1f7f68fa190887d96f781bd0cd
diff --git a/net-wireless/iwd/iwd-3.0.ebuild b/net-wireless/iwd/iwd-3.0.ebuild
new file mode 100644
index 000000000000..95ad12b6ce87
--- /dev/null
+++ b/net-wireless/iwd/iwd-3.0.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit flag-o-matic linux-info systemd
+
+#Set this variable to the required external ell version
+ELL_REQ="0.69"
+
+if [[ ${PV} == *9999* ]]; then
+ inherit autotools git-r3
+
IWD_EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git";
+ ELL_EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git";
+else
+
SRC_URI="https://mirrors.edge.kernel.org/pub/linux/network/wireless/${P}.tar.xz";
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc
~x86"
+ MYRST2MAN="RST2MAN=:"
+fi
+
+DESCRIPTION="Wireless daemon for linux"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/wireless/iwd.git/";
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+client cpu_flags_x86_aes cpu_flags_x86_ssse3 +monitor ofono selinux
standalone systemd wired"
+
+DEPEND="
+ sys-apps/dbus
+ client? ( sys-libs/readline:0= )
+"
+
+[[ -z "${ELL_REQ}" ]] || DEPEND+=" ~dev-libs/ell-${ELL_REQ}"
+
+RDEPEND="
+ ${DEPEND}
+ acct-group/netdev
+ net-wireless/wireless-regdb
+ selinux? ( sec-policy/selinux-networkmanager )
+ standalone? (
+ systemd? ( sys-apps/systemd )
+ !systemd? ( virtual/resolvconf )
+ )
+"
+
+BDEPEND="
+ virtual/pkgconfig
+"
+
+[[ ${PV} == *9999* ]] && BDEPEND+=" dev-python/docutils"
+
+pkg_setup() {
+ CONFIG_CHECK="
+ ~ASYMMETRIC_KEY_TYPE
+ ~ASYMMETRIC_PUBLIC_KEY_SUBTYPE
+ ~CFG80211
+ ~CRYPTO_AES
+ ~CRYPTO_CBC
+ ~CRYPTO_CMAC
+ ~CRYPTO_DES
+ ~CRYPTO_ECB
+ ~CRYPTO_HMAC
+ ~CRYPTO_MD4
+ ~CRYPTO_MD5
+ ~CRYPTO_RSA
+ ~CRYPTO_SHA1
+ ~CRYPTO_SHA256
+ ~CRYPTO_SHA512
+ ~CRYPTO_USER_API_HASH
+ ~CRYPTO_USER_API_SKCIPHER
+ ~KEY_DH_OPERATIONS
+ ~PKCS7_MESSAGE_PARSER
+ ~RFKILL
+ ~X509_CERTIFICATE_PARSER
+ "
+
+ if use amd64;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_DES3_EDE_X86_64"
+ WARNING_CRYPTO_DES3_EDE_X86_64="CRYPTO_DES3_EDE_X86_64: enable
for increased performance"
+ fi
+
+ if use cpu_flags_x86_aes;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_NI_INTEL"
+ WARNING_CRYPTO_AES_NI_INTEL="CRYPTO_AES_NI_INTEL: enable for
increased performance"
+ fi
+
+ if use cpu_flags_x86_ssse3 && use amd64; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_SHA1_SSSE3
~CRYPTO_SHA256_SSSE3 ~CRYPTO_SHA512_SSSE3"
+ WARNING_CRYPTO_SHA1_SSSE3="CRYPTO_SHA1_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA256_SSSE3="CRYPTO_SHA256_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA512_SSSE3="CRYPTO_SHA512_SSSE3: enable for
increased performance"
+ fi
+
+ if use kernel_linux && kernel_is -ge 4 20; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~PKCS8_PRIVATE_KEY_PARSER"
+ fi
+
+ check_extra_config
+}
+
+src_unpack() {
+ if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI=${IWD_EGIT_REPO_URI} git-r3_src_unpack
+ EGIT_REPO_URI=${ELL_EGIT_REPO_URI}
EGIT_CHECKOUT_DIR=${WORKDIR}/ell git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == *9999* ]] ; then
+ eautoreconf
+ fi
+
+ sed -e "s:Exec=/bin/false:Exec=${EPREFIX}/usr/libexec/iwd:g" -i
src/net.connman.iwd.service || die
+}
+
+src_configure() {
+ append-cflags "-fsigned-char"
+ local myeconfargs=(
+ --sysconfdir="${EPREFIX}"/etc/iwd
--localstatedir="${EPREFIX}"/var
+ "$(use_enable client)"
+ "$(use_enable monitor)"
+ "$(use_enable ofono)"
+ "$(use_enable wired)"
+ --enable-systemd-service
+ --with-systemd-unitdir="$(systemd_get_systemunitdir)"
+ --with-systemd-modloaddir="${EPREFIX}/usr/lib/modules-load.d"
+ --with-systemd-networkdir="$(systemd_get_utildir)/network"
+ )
+ [[ ${PV} == *9999* ]] || myeconfargs+=(--enable-external-ell)
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake "${MYRST2MAN}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" "${MYRST2MAN}" install
+ keepdir "/var/lib/${PN}"
+
+ newinitd "${FILESDIR}/iwd.initd-r1" iwd
+
+ if use wired;then
+ newinitd "${FILESDIR}/ead.initd" ead
+ fi
+
+ if [[ ${PV} == *9999* ]] ; then
+ exeinto /usr/share/iwd/scripts/
+ doexe test/*
+ fi
+
+ if use standalone ; then
+ local iwdconf="${ED}/etc/iwd/main.conf"
+ dodir /etc/iwd
+ cat << EOF > "${iwdconf}"
+[General]
+EnableNetworkConfiguration=true
+
+[Network]
+NameResolvingService=$(usex systemd systemd resolvconf)
+EOF
+ dodir /etc/conf.d
+ echo "rc_provide=\"net\"" > "${ED}"/etc/conf.d/iwd
+ fi
+}
