commit: b7d1464ecac0876d1ce4c7c59673b055dd575004
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 25 03:52:02 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct 25 03:52:02 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b7d1464e
dev-python/sigstore: Bump to 3.5.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sigstore/Manifest | 1 +
dev-python/sigstore/sigstore-3.5.0.ebuild | 64 +++++++++++++++++++++++++++++++
2 files changed, 65 insertions(+)
diff --git a/dev-python/sigstore/Manifest b/dev-python/sigstore/Manifest
index 3000e848db2c..5d5d71ee3760 100644
--- a/dev-python/sigstore/Manifest
+++ b/dev-python/sigstore/Manifest
@@ -1,2 +1,3 @@
DIST sigstore-python-3.3.0.gh.tar.gz 194796 BLAKE2B
34773c7d4d1a2e5c57534ebfc2ea7e8d8769a1243d082bf0298c6e85e14fab289551f951646aaa482deea5101cbb447d8629a05c31937e7d618f45077507ed12
SHA512
7a5659d4c49ba2bea9974e6588d673d1a16b9618ff3d45c8da68d9f77c098a872b5f68cdf2ea402de50deb8141ea98091bd199243fbde217f9076f3b155c5226
DIST sigstore-python-3.4.0.gh.tar.gz 200807 BLAKE2B
ffb74589d6d740a5b16f4c7884966be8f34954bac9e746d5d210b2e9b23d06eb94b59f9e5f52358d7a934c23791c1a9616a449c320b87a17e3255c4351b0b556
SHA512
3624dd1611d1671988bec4518ffe6c135a3df3f7ce4171d8e93c7d848b2755688c1f349b77fb89643f7b2a9da530b1b1f52272abd2ddb3685d53fd6d5367a97c
+DIST sigstore-python-3.5.0.gh.tar.gz 201262 BLAKE2B
dfbdbacda8aa57783a36a6ea1e4b443913df553a1aefeb1e458f98e347518876567a2cc9dedea543750d7431475108fe453824b63469c5e33c2596c3d6979ba1
SHA512
f8c6c382d5f37b79cc6a1a354b549a1cfdb452d702fa4570ea25b4509df3374cc828e55973125496a6681c1f054681c9852a96ebd0fdae56fec227c9cd73a343
diff --git a/dev-python/sigstore/sigstore-3.5.0.ebuild
b/dev-python/sigstore/sigstore-3.5.0.ebuild
new file mode 100644
index 000000000000..849c52693e55
--- /dev/null
+++ b/dev-python/sigstore/sigstore-3.5.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+MY_P=sigstore-python-${PV}
+DESCRIPTION="A tool for signing Python package distributions"
+HOMEPAGE="
+ https://github.com/sigstore/sigstore-python/
+ https://pypi.org/project/sigstore/
+"
+# no tests in sdist, as of 3.3.0
+SRC_URI="
+ https://github.com/sigstore/sigstore-python/archive/v${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=dev-python/cryptography-42[${PYTHON_USEDEP}]
+ >=dev-python/id-1.1.0[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-4.2[${PYTHON_USEDEP}]
+ >=dev-python/pyopenssl-23.0.0[${PYTHON_USEDEP}]
+ >=dev-python/pyasn1-0.6[${PYTHON_USEDEP}]
+ >=dev-python/pydantic-2[${PYTHON_USEDEP}]
+ >=dev-python/pyjwt-2.1[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ >=dev-python/rfc8785-0.1.2[${PYTHON_USEDEP}]
+ >=dev-python/rich-13.0[${PYTHON_USEDEP}]
+ ~dev-python/sigstore-protobuf-specs-0.3.2[${PYTHON_USEDEP}]
+ ~dev-python/sigstore-rekor-types-0.0.13[${PYTHON_USEDEP}]
+ >=dev-python/tuf-5.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/importlib-resources-5.7[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ dev-python/pretend[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unpin deps
+ sed -i -e 's:~=:>=:' pyproject.toml || die
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest test/unit --skip-online
+}
