commit: 7c7d3c0aad142bf96e7cd0237d8ab72c406a3b69
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 30 02:36:30 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct 30 03:25:40 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7c7d3c0a
dev-python/hypothesis: Bump to 6.115.6
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hypothesis/Manifest | 1 +
dev-python/hypothesis/hypothesis-6.115.6.ebuild | 103 ++++++++++++++++++++++++
2 files changed, 104 insertions(+)
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index e84694f93a63..81a570007b98 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,2 +1,3 @@
DIST hypothesis-6.114.1.gh.tar.gz 9477292 BLAKE2B
3dadb706f7d283febdc30c9e897fa5b648382edd9bba0ed0824abc2f2c1f6562f0ac77003df496d1def1e56092412c14674b5e768f9583607463f92b78770ad5
SHA512
14526a836c71cdec68a3fbd54391d4f6fe6911305fea9b349c77c59a3f352b7105531a44df05e26cd372d457ed07f7c8199967f444ede14b7d66151afe815727
DIST hypothesis-6.115.5.gh.tar.gz 9479622 BLAKE2B
44e21c25fbfb0da48102010a23522a636dd7dba0cbae3e1589710e816cb1f83abd33611750a76fd68c965dff5e0d1c234a5fb87da7cbf6ae0ebb4d3a8152ae9f
SHA512
e6528eb48710b61f6ef18cc1415f9977c0a4c10d86f4d92da51859f17dc1b24e16ea7cbce5be2438794edb1002b426fc9911e02bb1ce456d7f812262bcc3bd2f
+DIST hypothesis-6.115.6.gh.tar.gz 9479927 BLAKE2B
ddfeaebaa4e3687be1cab03fa8517353fcfc392dfe7a38100087534c6e71339e381a425c0e2b0d277d3d6344b69b9498e0b722efb18bbcbb90c3401e997afa96
SHA512
fb5df7b7bb45958e492d69d9375b3847de1ed39467bc119be69a237456e1cb1a2633cafbcd58c90113f0aa35880d5d30395ac9d43ccbc6c7368af46065094eb9
diff --git a/dev-python/hypothesis/hypothesis-6.115.6.ebuild
b/dev-python/hypothesis/hypothesis-6.115.6.ebuild
new file mode 100644
index 000000000000..f3d89f9d71ea
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.115.6.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+ https://github.com/HypothesisWorks/hypothesis/
+ https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+ https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ >=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+ ' 3.9 3.10)
+ cli? (
+ $(python_gen_cond_dep '
+ dev-python/black[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ ' "${CLI_COMPAT[@]}")
+ )
+"
+BDEPEND="
+ test? (
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ >=dev-python/pytest-8[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ !!<dev-python/requests-toolbelt-0.10.1
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+ # subtests are broken by warnings from random plugins
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+ local -x HYPOTHESIS_NO_PLUGINS=1
+
+ # NB: paths need to be relative to pytest.ini,
+ # i.e. start with hypothesis-python/
+ local EPYTEST_DESELECT=()
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+ # failing due to warnings from numpy/cython
+
hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+ )
+ ;;
+ esac
+
+ epytest -o filterwarnings= tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+ local HAD_CLI=
+
+ distutils-r1_src_install
+
+ if [[ ! ${HAD_CLI} ]]; then
+ rm -r "${ED}/usr/bin" || die
+ fi
+}
+
+python_install() {
+ distutils-r1_python_install
+ if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+ HAD_CLI=1
+ else
+ rm -r "${D}$(python_get_scriptdir)" || die
+ fi
+}
+
+pkg_postinst() {
+ optfeature "datetime support" dev-python/pytz
+ optfeature "dateutil support" dev-python/python-dateutil
+ optfeature "numpy support" dev-python/numpy
+ optfeature "django support" dev-python/django dev-python/pytz
+ optfeature "pandas support" dev-python/pandas
+ optfeature "pytest support" dev-python/pytest
+}
