commit: 62a835a03744dd18ff8a4291b588c15069fe4110
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 8 11:48:48 2024 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Fri Nov 8 11:49:05 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=62a835a0
net-wireless/iwd: add 3.1
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
net-wireless/iwd/Manifest | 1 +
net-wireless/iwd/iwd-3.1.ebuild | 167 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 168 insertions(+)
diff --git a/net-wireless/iwd/Manifest b/net-wireless/iwd/Manifest
index c61c98113468..0469a53e6b94 100644
--- a/net-wireless/iwd/Manifest
+++ b/net-wireless/iwd/Manifest
@@ -1,2 +1,3 @@
DIST iwd-2.22.tar.xz 1095092 BLAKE2B
69db8bf4d0c5dae0d3b569f7f04f2361b3b3eef0ba5084d5c12684a9d18611611708ac077efe2df2085c7352273d28fe23c7e1145883c513cb4fdfed0f1f835e
SHA512
fca6f50b849e6b4fc18a8cf0163e0d532f09b71e593d37f21bdc1b4878bddd7c96b481a3bb45ee6d36f4b1fd2ad76e428f9d1dd1b64ba77545227d3740b1a210
DIST iwd-3.0.tar.xz 1096812 BLAKE2B
a459a1d27a03631897a40c958dcf5ba451d09a1621207beaca20002e4056b0b72eade0b1cfbf26d3365346fbe204720841175f9f1e5370482375314c4a74b851
SHA512
d3c02fb034c471358817dc3f72eb0b96570004e042b704eee619a4ef44881486cfcfe9dfeedd0ff4ac9f70d07a5e68ce5626dc1f7f68fa190887d96f781bd0cd
+DIST iwd-3.1.tar.xz 1097252 BLAKE2B
2529ab4bba1b831f2720349bf2324f4eb2d89ab288a7a7063ed20fcf31d40380fc7ef684eb8eeb1c60d37523a497c539174f9ffb873f416d431090ae9bc6f3e0
SHA512
e0b04cf6d0f21356c959455d79f76ec7fe0101c036e06ca7d31a8318b802f79e04eb7b6c1aba8ba7f85cbcdd25885a765f9c99c1a3229d62d3428c049386ed45
diff --git a/net-wireless/iwd/iwd-3.1.ebuild b/net-wireless/iwd/iwd-3.1.ebuild
new file mode 100644
index 000000000000..48f0d7987bd3
--- /dev/null
+++ b/net-wireless/iwd/iwd-3.1.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit flag-o-matic linux-info systemd
+
+#Set this variable to the required external ell version
+ELL_REQ="0.70"
+
+if [[ ${PV} == *9999* ]]; then
+ inherit autotools git-r3
+
IWD_EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git";
+ ELL_EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git";
+else
+
SRC_URI="https://mirrors.edge.kernel.org/pub/linux/network/wireless/${P}.tar.xz";
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc
~x86"
+ MYRST2MAN="RST2MAN=:"
+fi
+
+DESCRIPTION="Wireless daemon for linux"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/wireless/iwd.git/";
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+client cpu_flags_x86_aes cpu_flags_x86_ssse3 +monitor ofono selinux
standalone systemd wired"
+
+DEPEND="
+ sys-apps/dbus
+ client? ( sys-libs/readline:0= )
+"
+
+[[ -z "${ELL_REQ}" ]] || DEPEND+=" ~dev-libs/ell-${ELL_REQ}"
+
+RDEPEND="
+ ${DEPEND}
+ acct-group/netdev
+ net-wireless/wireless-regdb
+ selinux? ( sec-policy/selinux-networkmanager )
+ standalone? (
+ systemd? ( sys-apps/systemd )
+ !systemd? ( virtual/resolvconf )
+ )
+"
+
+BDEPEND="
+ virtual/pkgconfig
+"
+
+[[ ${PV} == *9999* ]] && BDEPEND+=" dev-python/docutils"
+
+pkg_setup() {
+ CONFIG_CHECK="
+ ~ASYMMETRIC_KEY_TYPE
+ ~ASYMMETRIC_PUBLIC_KEY_SUBTYPE
+ ~CFG80211
+ ~CRYPTO_AES
+ ~CRYPTO_CBC
+ ~CRYPTO_CMAC
+ ~CRYPTO_DES
+ ~CRYPTO_ECB
+ ~CRYPTO_HMAC
+ ~CRYPTO_MD4
+ ~CRYPTO_MD5
+ ~CRYPTO_RSA
+ ~CRYPTO_SHA1
+ ~CRYPTO_SHA256
+ ~CRYPTO_SHA512
+ ~CRYPTO_USER_API_HASH
+ ~CRYPTO_USER_API_SKCIPHER
+ ~KEY_DH_OPERATIONS
+ ~PKCS7_MESSAGE_PARSER
+ ~RFKILL
+ ~X509_CERTIFICATE_PARSER
+ "
+
+ if use amd64;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_DES3_EDE_X86_64"
+ WARNING_CRYPTO_DES3_EDE_X86_64="CRYPTO_DES3_EDE_X86_64: enable
for increased performance"
+ fi
+
+ if use cpu_flags_x86_aes;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_NI_INTEL"
+ WARNING_CRYPTO_AES_NI_INTEL="CRYPTO_AES_NI_INTEL: enable for
increased performance"
+ fi
+
+ if use cpu_flags_x86_ssse3 && use amd64; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_SHA1_SSSE3
~CRYPTO_SHA256_SSSE3 ~CRYPTO_SHA512_SSSE3"
+ WARNING_CRYPTO_SHA1_SSSE3="CRYPTO_SHA1_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA256_SSSE3="CRYPTO_SHA256_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA512_SSSE3="CRYPTO_SHA512_SSSE3: enable for
increased performance"
+ fi
+
+ if use kernel_linux && kernel_is -ge 4 20; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~PKCS8_PRIVATE_KEY_PARSER"
+ fi
+
+ check_extra_config
+}
+
+src_unpack() {
+ if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI=${IWD_EGIT_REPO_URI} git-r3_src_unpack
+ EGIT_REPO_URI=${ELL_EGIT_REPO_URI}
EGIT_CHECKOUT_DIR=${WORKDIR}/ell git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == *9999* ]] ; then
+ eautoreconf
+ fi
+
+ sed -e "s:Exec=/bin/false:Exec=${EPREFIX}/usr/libexec/iwd:g" -i
src/net.connman.iwd.service || die
+}
+
+src_configure() {
+ append-cflags "-fsigned-char"
+ local myeconfargs=(
+ --sysconfdir="${EPREFIX}"/etc/iwd
--localstatedir="${EPREFIX}"/var
+ "$(use_enable client)"
+ "$(use_enable monitor)"
+ "$(use_enable ofono)"
+ "$(use_enable wired)"
+ --enable-systemd-service
+ --with-systemd-unitdir="$(systemd_get_systemunitdir)"
+ --with-systemd-modloaddir="${EPREFIX}/usr/lib/modules-load.d"
+ --with-systemd-networkdir="$(systemd_get_utildir)/network"
+ )
+ [[ ${PV} == *9999* ]] || myeconfargs+=(--enable-external-ell)
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake "${MYRST2MAN}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" "${MYRST2MAN}" install
+ keepdir "/var/lib/${PN}"
+
+ newinitd "${FILESDIR}/iwd.initd-r1" iwd
+
+ if use wired;then
+ newinitd "${FILESDIR}/ead.initd" ead
+ fi
+
+ if [[ ${PV} == *9999* ]] ; then
+ exeinto /usr/share/iwd/scripts/
+ doexe test/*
+ fi
+
+ if use standalone ; then
+ local iwdconf="${ED}/etc/iwd/main.conf"
+ dodir /etc/iwd
+ cat << EOF > "${iwdconf}"
+[General]
+EnableNetworkConfiguration=true
+
+[Network]
+NameResolvingService=$(usex systemd systemd resolvconf)
+EOF
+ dodir /etc/conf.d
+ echo "rc_provide=\"net\"" > "${ED}"/etc/conf.d/iwd
+ fi
+}
