[gentoo-dev] Re: [gentoo-commits] gentoo-x86 commit in app-misc/linux-logo: linux-logo-5.11.ebuild ChangeLog

[Peter Volkov]

В Птн, 24/06/2011 в 06:20 +0000, Jeroen Roovers (jer) пишет:
> jer         11/06/24 06:20:28
> 
>   Modified:             ChangeLog
>   Added:                linux-logo-5.11.ebuild
>   Log:
>   Version bump.

> plain: 
> http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/linux-logo/linux-logo-5.11.ebuild?rev=1.1&content-type=text/plain
> 
> Index: linux-logo-5.11.ebuild
> ===================================================================
> # Copyright 1999-2011 Gentoo Foundation
> # Distributed under the terms of the GNU General Public License v2
> # $Header: 
> /var/cvsroot/gentoo-x86/app-misc/linux-logo/linux-logo-5.11.ebuild,v 1.1 
> 2011/06/24 06:20:27 jer Exp $
> 
> EAPI="4"
> 
> inherit eutils toolchain-funcs
> 
> MY_P=${PN/-/_}-${PV}
> S=${WORKDIR}/${MY_P}
> DESCRIPTION="A utility that displays an ANSI/ASCII logo and some system 
> information"
> HOMEPAGE="http://www.deater.net/weave/vmwprod/linux_logo/";
> SRC_URI="http://www.deater.net/weave/vmwprod/linux_logo/${MY_P}.tar.gz";
> 
> LICENSE="GPL-2"
> SLOT="0"
> KEYWORDS="~amd64 ~hppa ~ia64 ~mips ~ppc ~sparc ~x86"
> IUSE="nls"
> 
> RDEPEND="nls? ( virtual/libintl )"
> DEPEND="${RDEPEND}
>       nls? ( sys-devel/gettext )"
> 
> src_prepare() {
>       echo "./logos/gentoo.logo" >> logo_config
>       echo "./logos/gentoo2.logo" >> logo_config
>       echo "./logos/banner-simplified.logo" >> logo_config
>       echo "./logos/banner.logo" >> logo_config
>       echo "./logos/classic-no_periods.logo" >> logo_config
>       echo "./logos/classic-no_periods_or_chars.logo" >> logo_config
>       echo "./logos/classic.logo" >> logo_config

cat >> logo_config <<-EOF will look much better here.

>       cp "${FILESDIR}"/gentoo{,2}.logo "${S}"/logos/

|| die

>       echo "NAME gentoo" >> "${S}"/logos/gentoo.logo
> }
> 
> src_compile() {
>       ARCH="" ./configure --prefix="${D}"/usr || die

Why not src_configure()?
Also use econf or add # some comment here, please.

>       emake CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" CC="$(tc-getCC)"
> }
> 
> src_install() {
>       emake DESTDIR="${D}" install
> 
>       dodoc BUGS README README.CUSTOM_LOGOS TODO USAGE LINUX_LOGO.FAQ
> 
>       cp "${FILESDIR}"/${PN}.conf "${WORKDIR}"
>       sed -i -e 's/-L 4 -f -u/-f -u/' "${WORKDIR}"/${PN}.conf

|| die

With best regards,
--
Peter.