13.09.2015 05:41, Mark H Weaver пишет:
Andrei Borzenkov <arvidj...@gmail.com> writes:
ld: /tmp/conftest-efc530.o: compiled for a big endian system and target is
little endian
ld: /tmp/conftest-efc530.o: endianness incompatible with that of the selected
emulation
This is the same problem we had on powerpc. Your binutils are set to
use little-endian output by default; we need to explicitly enable
either big or little endian in this case as well. Could you try
attached patch to verify?
I'm glad to report that with your new patch, GRUB successfully builds on
GuixSD mips64el with TARGET_CC=clang. I haven't yet tried booting it
though.
Did you have chance to test whether compiled grub actually work?
Your patch works for me with gcc, although config.log shows this warning
when building the test program in your new code with the correct flags
for gcc (-mabi=32):
ld: warning: cannot find entry symbol __start; defaulting to
00000000004000d0
Well, I just reused existing checks in this case; we worry about it later.
Okay. I guess the name of the start symbol depends on the platform and
linker. E.g. boot/mips/loongson/fwstart.S has this:
--8<---------------cut here---------------start------------->8---
.global start,_start,__start
start:
_start:
__start:
--8<---------------cut here---------------end--------------->8---
Other platforms have only '_start', or both 'start' and '_start'.
I also worry that linking an O32 executable might be fragile on a pure
non-multilib N32 system such as GNU Guix, where we lack even the gcc
runtime library (libgcc_s) for O32. For now it seems to work, but I
wonder if it might be more robust to do the test compilation with -c and
-freestanding?
It is using -nostdlib; is it not enough?
The warning above makes me doubt the portability and future-proofness of
the link step of this test. This problem could be avoided entirely by
omitting the link step. The link step serves no purpose in this test,
and is a potential source of portability problems.
This step helped us to catch endianness mismatch; we want to ensure in
this case that full toolchain works to produce final binary.
Having said that, if you prefer to keep the link step, I guess it will
probably be okay in practice to define 'start', '_start', and '__start'
as above. Do as you think best.
Please test two attached patches. They separate o32 test from endianness
test. I compile-tested them using cross-binutils for mips and
powerpc64le to compile for mipsel and powerpc. The first patch also adds
additional _start and __start symbols to endianness tests to avoid
compiler warnings.
I am interested in both native and cross compilation - i.e. please test
for both --target=mipsel and --target=mips both with gcc and clang.
config.log from all runs would be interesting even for successful cases.
>From ca80d768a43685e3e67fe9092dc10d9c574ee596 Mon Sep 17 00:00:00 2001
From: Andrei Borzenkov <arvidj...@gmail.com>
Date: Sun, 13 Sep 2015 16:51:13 +0300
Subject: [PATCH 1/2] configure: try to find options to force endian on MIPS
---
configure.ac | 43 ++++++++++++++++++++++++++++++++++++++++---
1 file changed, 40 insertions(+), 3 deletions(-)
diff --git a/configure.ac b/configure.ac
index c864311..4760fe8 100644
--- a/configure.ac
+++ b/configure.ac
@@ -562,11 +562,11 @@ AC_COMPILE_IFELSE(
]])],
[grub_cv_cc_target_clang=no], [grub_cv_cc_target_clang=yes])])
-if test x$target_cpu = xpowerpc; then
+if test x$target_cpu = xpowerpc -o x$target_cpu = xmips; then
AC_CACHE_CHECK([for options to get big-endian compilation], grub_cv_target_cc_big_endian, [
grub_cv_target_cc_big_endian=no
- for cand in "-target powerpc -Wl,-EB" "-target powerpc" \
- "-target powerpc-linux-gnu -Wl,-EB" "-target powerpc-linux-gnu" \
+ for cand in "-target $target_cpu -Wl,-EB" "-target $target_cpu" \
+ "-target $target_cpu-linux-gnu -Wl,-EB" "-target $target_cpu-linux-gnu" \
"-mbig-endian"; do
if test x"$grub_cv_target_cc_big_endian" != xno ; then
break
@@ -577,6 +577,8 @@ if test x$target_cpu = xpowerpc; then
#error still little endian
#endif
asm (".globl start; start:");
+asm (".globl _start; _start:");
+asm (".globl __start; __start:");
void __main (void);
void __main (void) {}
int main (void);
@@ -595,6 +597,41 @@ int main (void);
TARGET_CPPFLAGS="$TARGET_CPPFLAGS $skip_linkflags"
TARGET_CCASFLAGS="$TARGET_CCASFLAGS $skip_linkflags"
TARGET_LDFLAGS="$TARGET_LDFLAGS $grub_cv_target_cc_big_endian"
+elif test x$target_cpu = xmipsel; then
+ AC_CACHE_CHECK([for options to get little-endian compilation], grub_cv_target_cc_little_endian, [
+ grub_cv_target_cc_little_endian=no
+ for cand in "-target $target_cpu -Wl,-EL" "-target $target_cpu" \
+ "-target $target_cpu-linux-gnu -Wl,-EL" "-target $target_cpu-linux-gnu" \
+ "-mlittle-endian"; do
+ if test x"$grub_cv_target_cc_little_endian" != xno ; then
+ break
+ fi
+ CFLAGS="$TARGET_CFLAGS $cand -Werror"
+ AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+#if defined(__BYTE_ORDER__) && defined(__ORDER_BIG_ENDIAN__) && (__ORDER_BIG_ENDIAN__ == __BYTE_ORDER__)
+#error still big endian
+#endif
+asm (".globl start; start:");
+asm (".globl _start; _start:");
+asm (".globl __start; __start:");
+void __main (void);
+void __main (void) {}
+int main (void);
+]], [[]])],
+ [grub_cv_target_cc_little_endian="$cand"], [])
+ done
+ ])
+
+ if test x"$grub_cv_target_cc_little_endian" = xno ; then
+ AC_MSG_ERROR([could not force little-endian])
+ fi
+
+ skip_linkflags="$(echo "$grub_cv_target_cc_little_endian"|sed 's@-Wl,-EL@@')"
+
+ TARGET_CFLAGS="$TARGET_CFLAGS $skip_linkflags"
+ TARGET_CPPFLAGS="$TARGET_CPPFLAGS $skip_linkflags"
+ TARGET_CCASFLAGS="$TARGET_CCASFLAGS $skip_linkflags"
+ TARGET_LDFLAGS="$TARGET_LDFLAGS $grub_cv_target_cc_little_endian"
fi
AC_CACHE_CHECK([for options to compile assembly], [grub_cv_cc_target_asm_compile], [
--
1.9.1
>From b69cb301dca85c60b25f0118e5532a2b12f7bae6 Mon Sep 17 00:00:00 2001
From: Andrei Borzenkov <arvidj...@gmail.com>
Date: Sun, 13 Sep 2015 16:51:13 +0300
Subject: [PATCH 2/2] configure: try to force o32 ABI on MIPS
GRUB expects o32 ABI, in particular used assembly is valid only in this mode.
Some systems (e.g. GNU Guix) default to using newer n64 or n32 ABI. Try to
find suitable options to force o32.
For GCC this is simply -mabi=32. While clang supports this option as well,
o32 ABI is valid for MIPS target and n32/64 ABI are valid for MIPS64 target
only, so use "-target mips/mipsel -mabi=32".
Reported-By: Mark H Weaver <m...@netris.org>
Also-By: Mark H Weaver <m...@netris.org>
---
configure.ac | 31 +++++++++++++++++++++++++++++++
1 file changed, 31 insertions(+)
diff --git a/configure.ac b/configure.ac
index 4760fe8..7b4e5bc 100644
--- a/configure.ac
+++ b/configure.ac
@@ -634,6 +634,37 @@ int main (void);
TARGET_LDFLAGS="$TARGET_LDFLAGS $grub_cv_target_cc_little_endian"
fi
+if test "x$target_cpu" = xmips || test "x$target_cpu" = xmipsel ; then
+ AC_CACHE_CHECK([for options to force MIPS o32 ABI], grub_cv_target_cc_mips_o32_abi, [
+ grub_cv_target_cc_mips_o32_abi=no
+ for arg in "" "-mabi=32" "-target $target_cpu -mabi=32" ; do
+ if test x"$grub_cv_target_cc_mips_o32_abi" != xno ; then
+ break
+ fi
+ CFLAGS="$TARGET_CFLAGS $arg -Werror"
+ AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+#if !defined(_ABIO32) || !defined(_MIPS_SIM) || (_MIPS_SIM != _ABIO32)
+#error not o32 ABI
+#endif
+asm (".globl start; start:");
+asm (".globl _start; _start:");
+asm (".globl __start; __start:");
+void __main (void);
+void __main (void) {}
+int main (void);
+]], [[]])],
+ [grub_cv_target_cc_mips_o32_abi="$arg"], [])
+ done
+ ])
+
+ if test x"$grub_cv_target_cc_mips_o32_abi" = xno ; then
+ AC_MSG_ERROR([could not force MIPS o32 ABI])
+ fi
+
+ TARGET_CFLAGS="$TARGET_CFLAGS $grub_cv_target_cc_mips_o32_abi"
+ TARGET_CCASFLAGS="$TARGET_CCASFLAGS $grub_cv_target_cc_mips_o32_abi"
+fi
+
AC_CACHE_CHECK([for options to compile assembly], [grub_cv_cc_target_asm_compile], [
test_program=
case "x$target_cpu-$platform" in
--
1.9.1
_______________________________________________
Grub-devel mailing list
Grub-devel@gnu.org
https://lists.gnu.org/mailman/listinfo/grub-devel
