On Mon, 2005-08-15 at 10:18 -0500, Ronald G wells wrote:
> Is there a method to sound BEEP depending on MSG being displayed on a
> console...running z/os 1.4 currently...
You can issue the message with e.g. WTO ... DESC=2. Here is an MPF exit
than you can refer to in your MPFLSTxx member that will change the
descriptor code for messages of your choice.
Modify the following example for inclusion in SYS1.PARMLIB(MPFLSTxx):
$HASP310,SUP(NO),USEREXIT(MPFHIGH) HILIGHT END OF MEM MSG
Assemble and linkedit the following into your MPF exits load library:
MPFHIGH TITLE '- MPF EXIT FOR MESSAGE HIGHLIGHTING'
PRINT ON,GEN,DATA
*
* THE PURPOSE OF THIS EXIT IS TO CHANGE THE DESCRIPTOR CODE
* TO "IMMEDIATE ACTION REQUIRED" (CODE 2) FOR MESSAGES THAT
* THIS INSTALLATION CONSIDERS IMPORTANT.
*
SPACE ,
R0 EQU 0
R1 EQU 1
R2 EQU 2
R3 EQU 3
R4 EQU 4
R5 EQU 5
R6 EQU 6
R7 EQU 7
R8 EQU 8
R9 EQU 9
R10 EQU 10
R11 EQU 11
R12 EQU 12
R13 EQU 13
R14 EQU 14
R15 EQU 15
MPFHIGH CSECT
MPFHIGH AMODE 31
MPFHIGH RMODE ANY
SAVE (14,12),,MPFHIGH-&SYSDATE-&SYSTIME
LR R12,R15 R12 IS PROGRAM BASE
USING MPFHIGH,R12 "
L R2,0(,R1) POINT TO CTXT
USING CTXT,R2 "
L R3,CTXTTXPJ POINT TO MESSAGE ATTRIBUTES
USING CTXTATTR,R3 "
L R11,CTXTDCP POINT TO DESCRIPTOR CODES
USING CTXTDESC,R11 "
L R10,CTXTFCNP POINT TO RETURN FLAGS
USING CTXTPRFL,R10 "
LA R4,CTXTTMSG POINT TO TEXT AREA
HILIGHT MVI CTXTDC1,CTXTDC02 DESC=2 CRITICAL ACTION REQUIRED
OI CTXTRFB1,CTXTRCDC CHANGE DESCRIPTOR CODES
EXIT RETURN (14,12)
SPACE ,
LTORG ,
TITLE ' - DSECTS'
PRINT NOGEN
IEZVX100 , CTXT PARAMETER DSECTS
END MPFHIGH
--
David Andrews
A. Duda and Sons, Inc.
[EMAIL PROTECTED]
----------------------------------------------------------------------
For IBM-MAIN subscribe / signoff / archive access instructions,
send email to [EMAIL PROTECTED] with the message: GET IBM-MAIN INFO
Search the archives at http://bama.ua.edu/archives/ibm-main.html
