I have had to fight this kind of thing in the past.
1) Get a SA dump
2) IPCS and do a VERBX RSMDATA
3) Validate that only pages in that range are 31-bit restricted.
- At one point I had a system with 90% of the 24-bit frames occupied by
pages that could have gone into 64-bit frames
4) Here is part of a program that will list how much each address space has
fixed and where that you can run in real time.
First a macro it uses
MACRO
&NAME DISPLAY &VALUE,&PRINT
&T SETC T'&VALUE
AIF ('&T' EQ 'H').USEH
AIF ('&T' EQ 'D').USED
LGF R15,&VALUE GET VALUE TO DISPLAY
AGO .NEXT
.USEH ANOP ,
LGH R15,&VALUE GET VALUE TO DISPLAY
AGO .NEXT
.USED ANOP ,
LG R15,&VALUE GET VALUE TO DISPLAY
.NEXT ANOP ,
MVC WORK20,=XL20'402020206B2020206B2020206B2020206B202120'
CVD R15,WORKD COVERT TO DECIMAL
ED WORK20,WORKD
MVC &PRINT,WORK20+20-L'&PRINT MOVE TO PRINT LINE
MEND
The code has a couple of trigger points so you don't list every address space.
***********************************************************************
* *
* FOR EACH ASID *
* IF(RAXTOTFX GT TOTALFX OR *
* RAXBELFX GT BELOWFX OR *
* RAXFMCT GT WKFRAMES) *
* SET JOBNAME OR ASID *
* DISPLAY RAXTOTFX *
* DISPLAY RAXBELFX *
* DISPLAY RAXABVFX *
* DISPLAY RAXFMCT *
* CALL PRINT *
* EIF *
* EFOR *
* *
***********************************************************************
L R5,ASVTMAXU GET NUMBER OF ADDRESS SPACES
LA R4,ASVTENTY POINT AT FIRST ASID POINTER
SNFR0300 DS 0H
TM 0(R4),X'80' IS IT NOT USED?
JO SNFR0700 YES, SKIP IT
L R3,0(0,R4) GET ASCB ADDRESS
USING ASCB,R3
L R2,ASCBRSME GET RAX ADDRESS
USING RAX,R2
CLC RAXTOTFX,TOTALFF IS TOTAL HIGH?
JNL SNFR0400 YES, NEED A DETAIL LINE
CLC RAXBELFX,BELOWFF IS BELOW HIGH?
JNL SNFR0400 YES, NEED A DETAIL LINE
CLC RAXFMCT,WKFRAMES IS TOTAL FRAME COUNT HIGH
JL SNFR0700 NO, NEXT ASCB
SNFR0400 DS 0H
MVC PRINTLIN,BLANK1 START WITH BLANK LINE
MVC LINETIME,=CL11'JN= '
ICM R15,15,ASCBJBNI GET JOBNAME ADDRESS
JNZ SNFR0500
ICM R15,15,ASCBJBNS GET JOBNAME ADDRESS
JNZ SNFR0500
MVC LINETIME,=CL11'ASID= ' USE ASID
LA R2,ASCBASID POINT AT FIRST BYTE
LHI R0,2 ONLY 2 BYTES
LA R1,LINEMM+2 POINT WHERE IT GOES
HEX2CHAR DS 0H
ICM R15,8,0(R2) GET A BYTE
SLR R14,R14 CLEAR IT
SLDL R14,4 GET HIGH NIBBLE
IC R14,TABLE(R14) GET PRINTABLE
STC R14,0(0,R1) STORE IN DESTINATION
LA R1,1(0,R1) POINT TO NEXT DEST
SLR R14,R14 ZERO IT AGAIN
SLDL R14,4 GET LOW NIBBLE
IC R14,TABLE(R14) GET PRINTABLE
STC R14,0(0,R1) STORE IN DESTINATION
LA R1,1(0,R1) POINT TO NEXT DEST
LA R2,1(0,R2) POINT TO NEXT SOURCE
BCT R0,HEX2CHAR DO IT AGAIN IF NEEDED
J SNFR0600
TABLE DC CL16'0123456789ABCDEF' CONVERSION TABLE
SNFR0500 DS 0H
MVC JOBNAME,0(R15) MOVE IN JOBNAME
SNFR0600 DS 0H
DISPLAY RAXTOTFX,TOTFX
DISPLAY RAXBELFX,BELFX
DISPLAY RAXFMCT,WKFRAME
DISPLAY RAXABVFX,ABVFX
L R15,RAXTOTFX
S R15,RAXBELFX
S R15,RAXABVFX
ST R15,WORKF
DISPLAY WORKF,ABRFX
$CALL PRINT
SNFR0700 DS 0H
AHI R4,4 BUMP TO NEXT ASID
JCT R5,SNFR0300 LOOP IF WE NEED TO
DROP R2,R3
SNFR0800 DS 0H
Chris Blaicher
Technical Architect
Mainframe Development
P: 201-930-8234 | M: 512-627-3803
E: [email protected]
Syncsort Incorporated
2 Blue Hill Plaza #1563
Pearl River, NY 10965
www.syncsort.com
Data quality leader Trillium Software is now a part of Syncsort.
-----Original Message-----
From: IBM Mainframe Discussion List [mailto:[email protected]] On Behalf
Of Edgington, Jerry
Sent: Tuesday, April 24, 2018 7:24 AM
To: [email protected]
Subject: IRA400E RC=04
To all,
We had a problem, yesterday with shortage of pageable central storage frames,
pageable frames between 16 megabytes and 2 gigabytes shortage.
In IEASYS;
RSU=0,
In IEAOPT;
CPENABLE=(10,30),
ERV=50000,
HIPERDISPATCH=YES,
PROJECTCPU=YES,
INITIMP=E
We are running a Monoplex with CICS, no DB2, on z/OS v2.2. Any advice on what
to change to prevent this issue from happening again.
Thanks,
Jerry Edgington
----------------------------------------------------------------------
For IBM-MAIN subscribe / signoff / archive access instructions, send email to
[email protected] with the message: INFO IBM-MAIN
________________________________
ATTENTION: -----
The information contained in this message (including any files transmitted with
this message) may contain proprietary, trade secret or other confidential
and/or legally privileged information. Any pricing information contained in
this message or in any files transmitted with this message is always
confidential and cannot be shared with any third parties without prior written
approval from Syncsort. This message is intended to be read only by the
individual or entity to whom it is addressed or by their designee. If the
reader of this message is not the intended recipient, you are on notice that
any use, disclosure, copying or distribution of this message, in any form, is
strictly prohibited. If you have received this message in error, please
immediately notify the sender and/or Syncsort and destroy all copies of this
message in your possession, custody or control.
----------------------------------------------------------------------
For IBM-MAIN subscribe / signoff / archive access instructions,
send email to [email protected] with the message: INFO IBM-MAIN
