>From 713 to 209 cycles on Penrynn.
Having a loop counter is a 7 cycle gain.
Unrolling is another 7 cycle gain.
Working in reverse scan is another 6 cycles.
---
libavcodec/x86/sbrdsp.asm | 31 +++++++++++++++++++++++++++++++
libavcodec/x86/sbrdsp_init.c | 2 ++
2 files changed, 33 insertions(+), 0 deletions(-)
diff --git a/libavcodec/x86/sbrdsp.asm b/libavcodec/x86/sbrdsp.asm
index 49dd78c..cfbd6e8 100644
--- a/libavcodec/x86/sbrdsp.asm
+++ b/libavcodec/x86/sbrdsp.asm
@@ -287,3 +287,34 @@ cglobal sbr_qmf_deint_neg, 2,3,4,v,src,vrev
cmp vq, vrevq
jl .loop
REP_RET
+
+; sbr_qmf_deint_bfly(float *v, const float *src0, const float *src1)
+cglobal sbr_qmf_deint_bfly, 3,5,8, v,src0,src1,vrev,c
+ mov cq, 64*4-2*mmsize
+ lea vrevq, [vq + 64*4]
+.loop:
+ mova m0, [src0q+cq]
+ mova m1, [src1q]
+ mova m4, [src0q+cq+mmsize]
+ mova m5, [src1q+mmsize]
+ mova m2, m0
+ mova m3, m1
+ shufps m2, m2, 11011b
+ shufps m3, m3, 11011b
+ mova m6, m4
+ mova m7, m5
+ shufps m6, m6, 11011b
+ shufps m7, m7, 11011b
+ addps m5, m2
+ subps m0, m7
+ addps m1, m6
+ subps m4, m3
+ mova [vrevq], m1
+ mova [vrevq+mmsize], m5
+ mova [vq+cq], m0
+ mova [vq+cq+mmsize], m4
+ add src1q, 2*mmsize
+ add vrevq, 2*mmsize
+ sub cq, 2*mmsize
+ jge .loop
+ REP_RET
diff --git a/libavcodec/x86/sbrdsp_init.c b/libavcodec/x86/sbrdsp_init.c
index 1ac64aa..5e3e131 100644
--- a/libavcodec/x86/sbrdsp_init.c
+++ b/libavcodec/x86/sbrdsp_init.c
@@ -35,6 +35,7 @@ void ff_sbr_neg_odd_64_sse(float *z);
void ff_sbr_qmf_post_shuffle_sse(float W[32][2], const float *z);
void ff_sbr_qmf_pre_shuffle_sse(float *z);
void ff_sbr_qmf_deint_neg_sse(float *v, const float *src);
+void ff_sbr_qmf_deint_bfly_sse(float *v, const float *src0, const float *src1);
void ff_sbrdsp_init_x86(SBRDSPContext *s)
{
@@ -49,5 +50,6 @@ void ff_sbrdsp_init_x86(SBRDSPContext *s)
s->qmf_post_shuffle = ff_sbr_qmf_post_shuffle_sse;
s->qmf_pre_shuffle = ff_sbr_qmf_pre_shuffle_sse;
s->qmf_deint_neg = ff_sbr_qmf_deint_neg_sse;
+ s->qmf_deint_bfly = ff_sbr_qmf_deint_bfly_sse;
}
}
--
1.7.7.msysgit.0
_______________________________________________
libav-devel mailing list
[email protected]
https://lists.libav.org/mailman/listinfo/libav-devel
