Sylwester Prozowski wrote:
Hello,
i installed ccid, pcsc-lite, libmusclecard and want to install
muscle framework.
the problem is that make does not see the *.h files for example
musclecard.h. I changed Makefile adding the inc line pointing to the
*.h directory. I tried to compile it with .h file in this same
directory but it simply does not see it.
Im doing it all as a root so i have rigths to acces the files and
the files are there. Any ideas?
The card reader naturally works with pcsc-lite
You have done
(./reconf --force)
./configure
make
What do you mean with "Framework"? Do you mean the MCardPlugin? I think
yes, because you said, you have already installed ccid, pcsc-lite and
libmusclecard.
Try this
Maybe you can try the configure.in file appended, it is more verbose and
complains if some thing is not there. Place it in the MCardPlugin dir.
You must run ./reconf --force and a ne configure file will be created.
Then again configure (with the necessary options) Read also this excerp:
Details:
For compiling the plug-in and executing
installBundle you must have pkg-config installed.
pkg-config libmusclecard --variable=muscledropdir
will tell you where the bundle directory is placed.
Usually pkg-config looks in the /usr/local/lib/pkgconfig directory.
There should placed a file libmusclecard.pc containing information
about the required libraries, header files and other information.
If pkgconfig fails and your pkgconfig directory is at a
different location you have to set the environment variable
PKG_CONFIG_PATH. E.g. the Debian path for pkgconfig is /usr/lib/pkgconfig.
This bundle directory will contain everything about your plug-in. The
bundle
looks like the following:
mscMuscleCard.bundle.bundle/Contents
Info.plist - XML file of attributes like ATR,
Name
[Linux]/mscMuscleCard.bundle - Shared Library
If your token is unrecognized, try to use the bundleTool contained with the
MuscleCard package. Remove all cards from any reader and make sure the PC/SC
daemon is running.
bundleTool
bundleTool will edit the configuration information for your driver
and add support for the card which you will place into the reader.
You must be privileged to do this as it will access the bundle directory.
Karsten
_______________________________________________
Muscle mailing list
[email protected]
http://lists.drizzle.com/mailman/listinfo/muscle
dnl Process this file with autoconf to produce a configure script.
# Require autoconf 2.53
AC_PREREQ(2.53)
AC_INIT(MuscleCard Applet Plug-In, 2.0.0,,MCardPlugin)
AC_COPYRIGHT(COPYING)
AM_INIT_AUTOMAKE
AM_CONFIG_HEADER(config.h)
AC_CONFIG_SRCDIR(src/musclecardApplet.c)
AC_CANONICAL_HOST
AM_MAINTAINER_MODE
dnl Select OS specific versions of source files.
case "${build_os}" in
linux-gnu) arch=linux ;;
*bsd*) arch=bsd ;;
*darwin*) arch=darwin ;;
*solaris*) arch=solaris ;;
*hpux*) arch=hpux ;;
*osf*) arch=tru64 ;;
*cygwin*) arch=cygwin ;;
*) AC_MSG_ERROR([Operating system ${build_os} not supported]) ;;
esac
AM_CONDITIONAL(MSC_ARCH_LINUX, test x$arch = xlinux)
AM_CONDITIONAL(MSC_ARCH_BSD, test x$arch = xbsd)
AM_CONDITIONAL(MSC_ARCH_OSX, test x$arch = xdarwin)
AM_CONDITIONAL(MSC_ARCH_SOLARIS, test x$arch = xsolaris)
AM_CONDITIONAL(MSC_ARCH_HPUX, test x$arch = xhpux)
AM_CONDITIONAL(MSC_ARCH_TRU64, test x$arch = xtru64)
AM_CONDITIONAL(MSC_ARCH_CYGWIN, test x$arch = xcygwin)
if test x$arch = xlinux ; then
AC_DEFINE(MSC_TARGET_LINUX, 1, [Linux])
fi
if test x$arch = xbsd ; then
AC_DEFINE(MSC_TARGET_BSD, 1, [BSD])
fi
if test x$arch = xdarwin ; then
AC_DEFINE(MSC_TARGET_OSX, 1, [OSX])
fi
if test x$arch = xsolaris ; then
AC_DEFINE(MSC_TARGET_SOLARIS, 1, [Solaris])
fi
if test x$arch = xhpux ; then
AC_DEFINE(MSC_TARGET_HPUX, 1, [HP-UX])
fi
if test x$arch = xtru64 ; then
AC_DEFINE(MSC_TARGET_TRU64, 1, [TRU64])
fi
if test x$arch = xcygwin ; then
AC_DEFINE(MSC_TARGET_CYGWIN, 1, [Cygwin])
fi
dnl Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AC_PROG_MAKE_SET
dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADER(stdarg.h, [],
[AC_MSG_ERROR([stdarg.h not found.])])
dnl Check for pcsclite
PKG_CHECK_MODULES(PCSCLITE, libpcsclite >= 1.2.9-beta7, [],
[ if test -f /usr/local/lib/pkgconfig/libpcsclite.pc ; then
AC_MSG_ERROR([install pkg-config or set PKG_CONFIG_PATH to
pkgconfig directory])
else
AC_MSG_WARN([install pcsc-lite 1.2.9-beta7 or later])
fi
])
AC_CHECK_LIB(pcsclite, SCardEstablishContext, [],
[AC_MSG_ERROR([SCardEstablishContext() not found, install pcsc-lite
1.2.9-beta7 or later])])
CFLAGS="$CFLAGS $PCSCLITE_CFLAGS"
AC_CHECK_HEADER(winscard.h, [],
[AC_MSG_ERROR([winscard.h not found, install pcsc-lite 1.2.9-beta7 or
later, or use CFLAGS=... ./configure])],
[ #include <winscard.h> ])
dnl look for MuscleCard
PKG_CHECK_MODULES(MUSCLECARD, libmusclecard, [],
[AC_MSG_ERROR([libmusclecard not found, install libmusclecard 1.2.9-beta7 or
later])])
dnl Special check for pthread support.
AC_ARG_ENABLE(callback,
[ --enable-callback pcscd runs as a true daemon.],
[case "${enableval}" in
yes) callback=true ;;
no) callback=false ;;
*) AC_MSG_ERROR([bad value ${enableval} for --enable-callback]) ;;
esac], [callback=false])
if test x${callback} = xtrue ; then
AC_DEFINE(MSC_ENABLE_CALLBACK, 1, [status callbacks are enabled])
fi
AM_CONDITIONAL(MSC_WITH_CALLBACK, test x$callback = xtrue)
if test x${callback} = xtrue ; then
AC_MSG_RESULT([callbacks requested : checking thread support])
if test x$arch != xtru64 ; then
ACX_PTHREAD(
[
AC_DEFINE(HAVE_PTHREAD,1,
[Define if you have POSIX threads libraries and header files.])
], [
AC_MSG_ERROR([POSIX thread support required])
])
else
PTHREAD_CC="$CC -pthread"
fi
else
PTHREAD_CC="$CC"
fi
LIBS="$PTHREAD_LIBS $LIBS"
CFLAGS="$CFLAGS -fno-common $PTHREAD_CFLAGS -I/usr/local/include -Wall"
CC="$PTHREAD_CC"
dnl Checks for typedefs, structures, and compiler characteristics.
dnl Checks for library functions.
AC_FUNC_VPRINTF
AC_FUNC_MALLOC
AC_CHECK_FUNCS(strdup snprintf localtime getenv vsyslog, [],
[AC_MSG_ERROR([Necessary function is not supported.])])
dnl Add libtool support.
AM_PROG_LIBTOOL
dnl Automatically update the libtool script if it becomes out-of-date.
AC_SUBST(LIBTOOL_DEPS)
AC_SUBST(ac_aux_dir)
AC_ARG_ENABLE(debug,
[ --enable-debug enable debug messages from MuscleCard Plug-In.],
[ case "${enableval}" in
yes)
debug=true ;;
no)
debug=false ;;
*) AC_MSG_ERROR([bad value ${enableval} for --enable-debug]) ;;
esac], [debug=false])
if test x${debug} = xtrue ; then
AC_DEFINE(MSC_DEBUG, 1, [enable full MSC debug messaging.])
fi
AC_MSG_RESULT([system target type : $arch])
AC_MSG_RESULT([enable status callback : $callback])
AC_MSG_RESULT([enable mcard debug : $debug])
AC_OUTPUT(Makefile aclocal/Makefile src/Makefile)
_______________________________________________
Muscle mailing list
[email protected]
http://lists.drizzle.com/mailman/listinfo/muscle
