[Ph4nt0m] Re: 怎么样 解开 这样的网站打包文 件

Tue, 26 Aug 2008 18:58:33 -0700 

 以下代码保存VBS格式 和MDB放一个目录
Dim rs, ws, fso, conn, stream, connStr, theFolder
Set rs = CreateObject("ADODB.RecordSet")
Set stream = CreateObject("ADODB.Stream")
Set conn = CreateObject("ADODB.Connection")
Set fso = CreateObject("Scripting.FileSystemObject")
connStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=Packet.mdb;"

conn.Open connStr
rs.Open "FileData", conn, 1, 1
stream.Open
stream.Type = 1

On Error Resume Next

Do Until rs.Eof
    str = rs("P")
    If Left(str, 1) = "\" Then str = Mid(str, 2)
    theFolder = Left(str, InStrRev(str, "\"))
    If fso.FolderExists(theFolder) = False Then
        createFolder(theFolder)
    End If
    stream.SetEos()
    stream.Write rs("fileContent")
    stream.SaveToFile str, 2
    rs.MoveNext
Loop

rs.Close
conn.Close
stream.Close
Set ws = Nothing
Set rs = Nothing
Set stream = Nothing
Set conn = Nothing

Wscript.Echo "所有文件释放完毕!"

Sub createFolder(thePath)
    Dim i
    i = Instr(thePath, "\")
    Do While i > 0
        If fso.FolderExists(Left(thePath, i)) = False Then
            fso.CreateFolder(Left(thePath, i - 1))
        End If
        If InStr(Mid(thePath, i + 1), "\") Then
            i = i + Instr(Mid(thePath, i + 1), "\")
         Else
            i = 0
        End If
    Loop
End Sub
 
 

在2008-08-26，Saint <[EMAIL PROTECTED]> 写道：

我朋友的遭到了攻击，被删除了很多东西，整站还被打包下载了，在网站根目录下留下了一个crab.mdb 
这样的网站打包文件，crab.mdb是我朋友的整个网站的打包文件，

我搜索crab.mdb发现应该是 http://www.winshell.cn/read.php?862 是这个ASP 
WEBSHELL打包的，但这个WEBSHELL没有解包的功能，作者说要500元才给解包。郁闷……
-- 
=== SST：saint security team ===




--~--~---------~--~----~------------~-------~--~----~
 要向邮件组发送邮件，请发到 [email protected]
 要退订此邮件，请发邮件至 [EMAIL PROTECTED]
-~----------~----~----~----~------~----~------~--~---

回复