On 2022/01/02 18:51, Jeremie Courreges-Anglas wrote:
>
> PHP 8.1 introduced support for fibers. The implementation is either
> based on assembly from the Boost project, or a (probably unportable)
> fallback on ucontext_t.
FSVO unportable which is similar to "portable to most OS other than
OpenBSD" ;)
> For riscv64 the fix is easy: simply use the assembly files from boost
> which were not picked up by upstream PHP yet.
>
> The diff below seems to work, a basic runtime test passes. It adds the
> two required files in files/, copied from devel/boost, at the risk of
> them going out of sync with the devel/boost port. The rationale is that
> it should be easy to convince upstream to ship the missing files and
> configure.ac support, which I intend to do.
I'm fine with that. OK sthen@
> Another approach would be to add a BUILD_DEPENDS on devel/boost:patch or
> similar, if that's preferred.
I'd prefer not to do this unless necessary.
> Note that all architectures which aren't supported by Boost.Coroutine
> are at a risk of losing php support. No idea how this should be tackled
> yet.
>
> Thoughts? ok?
Thanks for picking this up.
>
> Index: Makefile
> ===================================================================
> RCS file: /cvs/ports/lang/php/8.1/Makefile,v
> retrieving revision 1.2
> diff -u -p -r1.2 Makefile
> --- Makefile 20 Dec 2021 10:44:01 -0000 1.2
> +++ Makefile 2 Jan 2022 17:27:32 -0000
> @@ -7,4 +7,14 @@ DEBUG_PACKAGES= ${BUILD_PACKAGES}
>
> AUTOCONF_VERSION= 2.71
>
> +post-extract:
> +.for file in jump_riscv64_sysv_elf_gas.S make_riscv64_sysv_elf_gas.S
> + if [ -f "${WRKSRC}/Zend/asm/${file}" ]; then \
> + echo "${WRKSRC}/Zend/asm/${file} already exists, not overwriting"
> >&2; \
> + exit 1; \
> + else \
> + cp "${FILESDIR}/${file}" "${WRKSRC}/Zend/asm/${file}"; \
> + fi
> +.endfor
> +
> .include <bsd.port.mk>
> Index: files/jump_riscv64_sysv_elf_gas.S
> ===================================================================
> RCS file: files/jump_riscv64_sysv_elf_gas.S
> diff -N files/jump_riscv64_sysv_elf_gas.S
> --- /dev/null 1 Jan 1970 00:00:00 -0000
> +++ files/jump_riscv64_sysv_elf_gas.S 2 Jan 2022 17:27:32 -0000
> @@ -0,0 +1,150 @@
> +/*
> + Distributed under the Boost Software License, Version 1.0.
> + (See accompanying file LICENSE_1_0.txt or copy at
> + http://www.boost.org/LICENSE_1_0.txt)
> +*/
> +/*******************************************************
> + * *
> + * ------------------------------------------------- *
> + * | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | *
> + * ------------------------------------------------- *
> + * | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c| *
> + * ------------------------------------------------- *
> + * | fs0 | fs1 | fs2 | fs3 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 8 | 9 | 10 | 11 | 12 | 13 | 14 | 15 | *
> + * ------------------------------------------------- *
> + * | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c| *
> + * ------------------------------------------------- *
> + * | fs4 | fs5 | fs6 | fs7 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 16 | 17 | 18 | 19 | 20 | 21 | 22 | 23 | *
> + * ------------------------------------------------- *
> + * | 0x40| 0x44| 0x48| 0x4c| 0x50| 0x54| 0x58| 0x5c| *
> + * ------------------------------------------------- *
> + * | fs8 | fs9 | fs10 | fs11 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 24 | 25 | 26 | 27 | 28 | 29 | 30 | 31 | *
> + * ------------------------------------------------- *
> + * | 0x60| 0x64| 0x68| 0x6c| 0x70| 0x74| 0x78| 0x7c| *
> + * ------------------------------------------------- *
> + * | s0 | s1 | s2 | s3 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 32 | 33 | 34 | 35 | 36 | 37 | 38 | 39 | *
> + * ------------------------------------------------- *
> + * | 0x80| 0x84| 0x88| 0x8c| 0x90| 0x94| 0x98| 0x9c| *
> + * ------------------------------------------------- *
> + * | s4 | s5 | s6 | s7 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 40 | 41 | 42 | 43 | 44 | 45 | 46 | 47 | *
> + * ------------------------------------------------- *
> + * | 0xa0| 0xa4| 0xa8| 0xac| 0xb0| 0xb4| 0xb8| 0xbc| *
> + * ------------------------------------------------- *
> + * | s8 | s9 | s10 | s11 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 48 | 49 | 50 | 51 | | | | | *
> + * ------------------------------------------------- *
> + * | 0xc0| 0xc4| 0xc8| 0xcc| | | | | *
> + * ------------------------------------------------- *
> + * | ra | pc | | | *
> + * ------------------------------------------------- *
> + * *
> + *******************************************************/
> +
> +.file "jump_riscv64_sysv_elf_gas.S"
> +.text
> +.align 1
> +.global jump_fcontext
> +.type jump_fcontext, %function
> +jump_fcontext:
> + # prepare stack for GP + FPU
> + addi sp, sp, -0xd0
> +
> + # save fs0 - fs11
> + fsd fs0, 0x00(sp)
> + fsd fs1, 0x08(sp)
> + fsd fs2, 0x10(sp)
> + fsd fs3, 0x18(sp)
> + fsd fs4, 0x20(sp)
> + fsd fs5, 0x28(sp)
> + fsd fs6, 0x30(sp)
> + fsd fs7, 0x38(sp)
> + fsd fs8, 0x40(sp)
> + fsd fs9, 0x48(sp)
> + fsd fs10, 0x50(sp)
> + fsd fs11, 0x58(sp)
> +
> + # save s0-s11, ra
> + sd s0, 0x60(sp)
> + sd s1, 0x68(sp)
> + sd s2, 0x70(sp)
> + sd s3, 0x78(sp)
> + sd s4, 0x80(sp)
> + sd s5, 0x88(sp)
> + sd s6, 0x90(sp)
> + sd s7, 0x98(sp)
> + sd s8, 0xa0(sp)
> + sd s9, 0xa8(sp)
> + sd s10, 0xb0(sp)
> + sd s11, 0xb8(sp)
> + sd ra, 0xc0(sp)
> +
> + # save RA as PC
> + sd ra, 0xc8(sp)
> +
> + # store SP (pointing to context-data) in A2
> + mv a2, sp
> +
> + # restore SP (pointing to context-data) from A0
> + mv sp, a0
> +
> + # load fs0 - fs11
> + fld fs0, 0x00(sp)
> + fld fs1, 0x08(sp)
> + fld fs2, 0x10(sp)
> + fld fs3, 0x18(sp)
> + fld fs4, 0x20(sp)
> + fld fs5, 0x28(sp)
> + fld fs6, 0x30(sp)
> + fld fs7, 0x38(sp)
> + fld fs8, 0x40(sp)
> + fld fs9, 0x48(sp)
> + fld fs10, 0x50(sp)
> + fld fs11, 0x58(sp)
> +
> + # load s0-s11,ra
> + ld s0, 0x60(sp)
> + ld s1, 0x68(sp)
> + ld s2, 0x70(sp)
> + ld s3, 0x78(sp)
> + ld s4, 0x80(sp)
> + ld s5, 0x88(sp)
> + ld s6, 0x90(sp)
> + ld s7, 0x98(sp)
> + ld s8, 0xa0(sp)
> + ld s9, 0xa8(sp)
> + ld s10, 0xb0(sp)
> + ld s11, 0xb8(sp)
> + ld ra, 0xc0(sp)
> +
> + # return transfer_t from jump
> + # pass transfer_t as first arg in context function
> + # a0 == FCTX, a1 == DATA
> + mv a0, a2
> +
> + # load pc
> + ld a2, 0xc8(sp)
> +
> + # restore stack from GP + FPU
> + addi sp, sp, 0xd0
> +
> + jr a2
> +.size jump_fcontext,.-jump_fcontext
> +# Mark that we don't need executable stack.
> +.section .note.GNU-stack,"",%progbits
> Index: files/make_riscv64_sysv_elf_gas.S
> ===================================================================
> RCS file: files/make_riscv64_sysv_elf_gas.S
> diff -N files/make_riscv64_sysv_elf_gas.S
> --- /dev/null 1 Jan 1970 00:00:00 -0000
> +++ files/make_riscv64_sysv_elf_gas.S 2 Jan 2022 17:27:32 -0000
> @@ -0,0 +1,91 @@
> +/*
> + Distributed under the Boost Software License, Version 1.0.
> + (See accompanying file LICENSE_1_0.txt or copy at
> + http://www.boost.org/LICENSE_1_0.txt)
> +*/
> +/*******************************************************
> + * *
> + * ------------------------------------------------- *
> + * | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | *
> + * ------------------------------------------------- *
> + * | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c| *
> + * ------------------------------------------------- *
> + * | fs0 | fs1 | fs2 | fs3 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 8 | 9 | 10 | 11 | 12 | 13 | 14 | 15 | *
> + * ------------------------------------------------- *
> + * | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c| *
> + * ------------------------------------------------- *
> + * | fs4 | fs5 | fs6 | fs7 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 16 | 17 | 18 | 19 | 20 | 21 | 22 | 23 | *
> + * ------------------------------------------------- *
> + * | 0x40| 0x44| 0x48| 0x4c| 0x50| 0x54| 0x58| 0x5c| *
> + * ------------------------------------------------- *
> + * | fs8 | fs9 | fs10 | fs11 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 24 | 25 | 26 | 27 | 28 | 29 | 30 | 31 | *
> + * ------------------------------------------------- *
> + * | 0x60| 0x64| 0x68| 0x6c| 0x70| 0x74| 0x78| 0x7c| *
> + * ------------------------------------------------- *
> + * | s0 | s1 | s2 | s3 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 32 | 33 | 34 | 35 | 36 | 37 | 38 | 39 | *
> + * ------------------------------------------------- *
> + * | 0x80| 0x84| 0x88| 0x8c| 0x90| 0x94| 0x98| 0x9c| *
> + * ------------------------------------------------- *
> + * | s4 | s5 | s6 | s7 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 40 | 41 | 42 | 43 | 44 | 45 | 46 | 47 | *
> + * ------------------------------------------------- *
> + * | 0xa0| 0xa4| 0xa8| 0xac| 0xb0| 0xb4| 0xb8| 0xbc| *
> + * ------------------------------------------------- *
> + * | s8 | s9 | s10 | s11 | *
> + * ------------------------------------------------- *
> + * ------------------------------------------------- *
> + * | 48 | 49 | 50 | 51 | | | | | *
> + * ------------------------------------------------- *
> + * | 0xc0| 0xc4| 0xc8| 0xcc| | | | | *
> + * ------------------------------------------------- *
> + * | ra | pc | | | *
> + * ------------------------------------------------- *
> + * *
> + *******************************************************/
> +
> +.file "make_riscv64_sysv_elf_gas.S"
> +.text
> +.align 1
> +.global make_fcontext
> +.type make_fcontext, %function
> +make_fcontext:
> + # shift address in a0 (allocated stack) to lower 16 byte boundary
> + andi a0, a0, ~0xF
> +
> + # reserve space for context-data on context-stack
> + addi a0, a0, -0xd0
> +
> + # third arg of make_fcontext() == address of context-function
> + # store address as a PC to jump in
> + sd a2, 0xc8(a0)
> +
> + # save address of finish as return-address for context-function
> + # will be entered after context-function returns (RA register)
> + lla a4, finish
> + sd a4, 0xc0(a0)
> +
> + ret // return pointer to context-data (a0)
> +
> +finish:
> + # exit code is zero
> + li a0, 0
> + # exit application
> + tail _exit@plt
> +
> +.size make_fcontext,.-make_fcontext
> +# Mark that we don't need executable stack.
> +.section .note.GNU-stack,"",%progbits
> Index: patches/patch-configure_ac
> ===================================================================
> RCS file: /cvs/ports/lang/php/8.1/patches/patch-configure_ac,v
> retrieving revision 1.2
> diff -u -p -r1.2 patch-configure_ac
> --- patches/patch-configure_ac 2 Jan 2022 13:33:40 -0000 1.2
> +++ patches/patch-configure_ac 2 Jan 2022 17:27:32 -0000
> @@ -23,7 +23,23 @@ Index: configure.ac
> if test -z "$PHP_MODULES" && test -z "$PHP_ZEND_EX"; then
> enable_shared=no
> fi
> -@@ -1360,7 +1360,7 @@ EXPANDED_SYSCONFDIR=`eval echo $sysconfdir`
> +@@ -1201,6 +1201,7 @@ AS_CASE([$host_cpu],
> + [arm*], [fiber_cpu="arm32"],
> + [ppc64*|powerpc64*], [fiber_cpu="ppc64"],
> + [ppc*|powerpc*], [fiber_cpu="ppc32"],
> ++ [riscv64*], [fiber_cpu="riscv64"],
> + [s390x*], [fiber_cpu="s390x"],
> + [mips64*], [fiber_cpu="mips64"],
> + [mips*], [fiber_cpu="mips32"],
> +@@ -1220,6 +1221,7 @@ AS_CASE([$fiber_cpu],
> + [arm32], [fiber_asm_file_prefix="arm_aapcs"],
> + [ppc64], [fiber_asm_file_prefix="ppc64_sysv"],
> + [ppc32], [fiber_asm_file_prefix="ppc32_sysv"],
> ++ [riscv64], [fiber_asm_file_prefix="riscv64_sysv"],
> + [s390x], [fiber_asm_file_prefix="s390x_sysv"],
> + [mips64], [fiber_asm_file_prefix="mips64_n64"],
> + [mips32], [fiber_asm_file_prefix="mips32_o32"],
> +@@ -1360,7 +1362,7 @@ EXPANDED_SYSCONFDIR=`eval echo $sysconfdir`
> EXPANDED_DATADIR=$datadir
> EXPANDED_PHP_CONFIG_FILE_PATH=`eval echo "$PHP_CONFIG_FILE_PATH"`
> EXPANDED_PHP_CONFIG_FILE_SCAN_DIR=`eval echo "$PHP_CONFIG_FILE_SCAN_DIR"`
>
>
> --
> jca | PGP : 0x1524E7EE / 5135 92C1 AD36 5293 2BDF DDCC 0DFA 74AE 1524 E7EE
