[fpc-pascal] I think I must be the first person to ever use tmemds for anything serious...

[David Mears]

I think I've just found my 3rd bug in the unit.

for me, it always says true when booleans are returned with .asBoolean,
and as empty strings when returned with .asString with the latest svn
compiler, is this also true of the release compiler?


{
    This file is part of the Free Component Library (FCL)
    Copyright (c) 1999-2000 by the Free Pascal development team

    See the file COPYING.FPC, included in this distribution,
    for details about the copyright.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

 **********************************************************************}
{$mode objfpc}
{$h+}

program testpop;

uses db,memds,classes,sysutils;

Procedure DoTest;

var
  I,ACount : integer;
  D   : TDateTime;

begin
  with TMemDataset.Create(Nil) do
    Try
      With FieldDefs do
        begin
        Clear;
        Add('Boolean', ftBoolean, 0, False);
        Add('Integer', ftInteger, 0, False);
        Add('SmallInt', ftSmallInt, 0, False);
        Add('Float', ftFloat, 0, False);
        Add('String', ftString, 30, False);
        Add('Time', ftTime, 0, False);
        Add('Date', ftDate, 0, False);
        end;
      CreateTable;
      Open;
      D:=now;
      ACount:=1000;
      for I:=1 to ACount do
        begin
        Append;
        FieldByName('Boolean').AsBoolean:=i mod 2 = 1;
        FieldByName('Integer').AsInteger:=I;
        FieldByName('SmallInt').AsInteger:=I;
        FieldByName('Float').AsFloat:=I/10;
        FieldByName('String').AsString:='Test-Data '+IntToStr(I);
        FieldByName('Time').AsDateTime:=D;
        FieldByName('Date').AsDateTime:=D;
        Post;
        end;
      First;
      ACount:=0;
      While Not EOF do
        begin
        Inc(ACount);
        Writeln('Record ',ACount,' : ');
        Writeln('------------------------');
        For I:=0 to Fields.Count-1 do
          case fields[i].DataType of
          ftBoolean:
          begin
            writeln('should say "TRUE" and "FALSE" alternately');
            if fields[i].asboolean then Writeln(Fields[I].FieldName,' : TRUE') 
else Writeln(Fields[I].FieldName,' : FALSE');
            Writeln(Fields[i].FieldName,' :',fields[i].asString);
          end;
          ftInteger:Writeln(Fields[I].FieldName,' : ',Fields[I].AsInteger);
          ftSmallInt:Writeln(Fields[i].FieldName,' : ',Fields[i].AsInteger);
          ftFloat:Writeln(Fields[i].FieldName,' : ',Fields[i].AsFloat); //CRASH
          ftString:Writeln(Fields[i].FieldName,' : ',Fields[i].AsString);
          ftTime:Writeln(Fields[i].FieldName,' : ',Fields[i].AsDateTime);
          ftDate:Writeln(Fields[i].FieldName,' : ',Fields[i].AsDateTime);
          end;
        Writeln;
        Next;
        end;
      Writeln('Total data size : ',DataSize);
      If (ParamCount>0) then
        FileName:=ParamStr(1);
      Close;
  finally
    Free;
  end;
end;

begin
  DoTest;
end.

_______________________________________________
fpc-pascal maillist  -  fpc-pascal@lists.freepascal.org
http://lists.freepascal.org/mailman/listinfo/fpc-pascal