Johnny Billquist <b...@softjar.se> wrote:
> On 2017-12-13 08:49, Johnny Eriksson wrote:
> > Johnny Billquist <b...@softjar.se> wrote:
> >
> >>> I was disappointed to learn that the RM05 was never supported, either.
> >>
> >> Hmm. Yeah, I can't remember ever seeing 18-bit packs or support on the
> >> RM05.
> >
> > We had several RM05's on kicki back in those days. Things needed:
> >
> > * Include drive geometry etc. in driver tables.
>
> So I assume Tops-10 don't have it in the tables normally. Which drives
> did Tops-10 support officially?
On the RH10/RH20 (KL etc.):
RP04/RP05
RP06
RP07
RM03
On the RH11 (KS):
RP06
RM03
> > * Make sure the controller in the drive (same HW as RM03 if I remember
> > correctly, but sitting in a separate cabinet beside the drive) has
> > the appropriate jumper installed in the backplane to enable 18-bit
> > mode.
>
> I didn't know it was the exact same Massbus adapter for the drive. I
> know that the RM02/RM03 have the adapter in the bottom of the cabinet,
> while the RM05 have it in a separate cabinet (probably because the drive
> itself takes more space in the cabinet).
> And the RM03 is supported by Tops-10 then, I take it.
>
> > * Format the pack in 18-bit mode. We did that with a user-mode program
> > using the write-data-and-headers I/O function. I have the source to
> > that (short) program somewhere.
>
> Hmm. I suspect the code for formatting an RM03 could be used as a
> starting point?
Possibly, if you had the source...
Low-level formatting was done with a stand-alone program (KSFORM) on
the KS10, I don't remember how it was (normally) done on the others.
We (rather JMR) wrote this to to the job for RM05's:
TITLE RM05
SEARCH UUOSYM,MACTEN
SECLEN==201
NUMSEC==^D30
NUMTRK==^D19
NUMCYL==^D822
SEC==1
TRK==2
CYL==3
ADR==4
NUM==5;NUM+1==6
START: RESET
OPEN[ EXP UU.DEL+IO.WHD+.IODMP
SIXBIT "RM05"
XWD 0,0]
JRST[ OUTSTR[ ASCIZ "Please assign the logical name RM05:"]
MONRT.
JRST START]
MOVSI CYL,-NUMCYL
NXTCYL: MOVSI TRK,-NUMTRK
OUTSTR[ ASCIZ "Formatting cylinder "]
MOVEI NUM,(CYL)
IDIVI NUM,^D100
MOVEI NUM,"0"(NUM)
OUTCHR NUM
MOVE NUM,NUM+1
IDIVI NUM,^D10
MOVEI NUM,"0"(NUM)
OUTCHR NUM
MOVEI NUM,"0"(NUM+1)
OUTCHR NUM
NXTTRK: SETZM BUFFER
MOVE[ XWD BUFFER,BUFFER+1]
BLT BUFEND
MOVSI SEC,-NUMSEC
MOVEI ADR,BUFFER
NXTSEC: MOVSI 140000
MOVEM (ADR)
DPB CYL,[POINT 10,(ADR),17]
DPB TRK,[POINT 5,(ADR),27]
DPB SEC,[POINT 5,(ADR),35]
ADDI ADR,SECLEN
AOBJN SEC,NXTSEC
MOVEI ADR,(CYL)
IMULI ADR,NUMTRK
ADDI ADR,(TRK)
IMULI ADR,NUMSEC
TXO ADR,SU.SOT
SUSET. ADR,
HALT
OUT[ IOWD BUFEND+1-BUFFER,BUFFER
EXP 0]
SKIPA
HALT
AOBJN TRK,NXTTRK
OUTCHR[ EXP .CHCRT]
AOBJN CYL,NXTCYL
MONRT.
JRST START
BUFFER: BLOCK SECLEN*NUMSEC
BUFEND==.-1
END START
> > --Johnny (the other one)
>
> Hah! I should have know who to ask about such a topic... ;-)
You are welcome.
> Johnny
--Johnny
_______________________________________________
Simh mailing list
Simh@trailing-edge.com
http://mailman.trailing-edge.com/mailman/listinfo/simh
