Jörg Becker schrieb:
> Hallo.....
>
> Welche Möglichkeiten gibt es Falz- und Lochmarkierungen auf der ersten
> Seite eines Dokumentes einzufügen? Gibt es eine Erweiterung oder
> Zusatzprogramm?
>
Hey Jörg,
ich hab dafür mal ein kleines Makro geschrieben, schick ich dir mit.
Eventuell musst du es auf deine Bedürfnisse anpassen ;-)
****************************
Sub FalzMarkenSetzen
dim aNamen() as string
aNamen = array("Falzmarke1", "Falzmarke2", "Lochermarke")
oDoc = thisComponent
dim oFalz1 as object, oFalz2 as object
REM zunächst evt. Objekte entfernen:
oGrafiken = oDoc.Drawpage
For i = 0 to oGrafiken.count-1
oGrafik = oGrafiken.getByIndex(i)
For j = 0 to uBound(aNamen)
if oGrafik.Name = aNamen(j) then oGrafiken.remove(oGrafik)
next
next
REM Größe der Falzmarken
dim oFalzSize as new com.sun.star.awt.Size
oFalzSize.Width = 400 '4 mm lang
oFalzSize.Height = 0
REM Größe der Lochermarke
dim oLocherSize as new com.sun.star.awt.Size
oLocherSize.Width = 500 '5 mm lang
oLocherSize.Height = 0
REM erste Falzmarke
oFalz1 = oDoc.createInstance("com.sun.star.drawing.LineShape")
dim oPos1 as new com.sun.star.awt.Point
oPos1.X = 300 '3 mm Randabstand
oPos1.Y = 10000 '10 ca, von oben
with oFalz1
.name = "Falzmarke1"
.lineColor = RGB(0, 0, 0)
.lineWidth = 1
.position = oPos1
.Size = oFalzSize
.AnchorType = com.sun.star.text.TextContentAnchorType.AT_PAGE
.MoveProtect = true
end with
oDoc.Drawpage.add(oFalz1)
REM zweite Falzmarke
oFalz2 = oDoc.createInstance("com.sun.star.drawing.LineShape")
dim oPos2 as new com.sun.star.awt.Point
oPos2.X = 300 '3 mm Randabstand
oPos2.Y = 19800 '19,8 cm von oben
with oFalz2
.name = "Falzmarke2"
.lineColor = RGB(0, 0, 0)
.lineWidth = 1
.position = oPos2
.Size = oFalzSize
.AnchorType = com.sun.star.text.TextContentAnchorType.AT_PAGE
.MoveProtect = true
end with
oDoc.Drawpage.add(oFalz2)
REM Lochermarke
oAbheft = oDoc.createInstance("com.sun.star.drawing.LineShape")
dim oPos3 as new com.sun.star.awt.Point
oPos3.X = 300 '3 mm Randabstand
oPos3.Y = 14800 '14,8 cm von oben
with oAbheft
.name = "Lochermarke"
.lineColor = RGB(0, 0, 0)
.lineWidth = 1
.position = oPos3
.Size = oLocherSize
.AnchorType = com.sun.star.text.TextContentAnchorType.AT_PAGE
.MoveProtect = true
end with
oDoc.Drawpage.add(oAbheft)
End Sub
**************************
viele Grüße
Thomas
--
## Marketing deutschsprachiges Projekt
## http://de.openoffice.org - www.openoffice.org
## Vorstand OpenOffice.org Deutschland e.V.
## Mitglieder willkommen: www.OOoDeV.org
---------------------------------------------------------------------
To unsubscribe, e-mail: [EMAIL PROTECTED]
For additional commands, e-mail: [EMAIL PROTECTED]
