On Fr, 06 Apr 2018, Bram Moolenaar wrote:

> It might be good to check if xxd was actually built. The normal "make"
> command should, but some people might use their own way of building.
> A missing "xxd" executable should not make the test fail.

Yeah, initially, I wanted to make the test depend on src/xxd/xxd 

But I couldn't figure out how to make it depend on a rule from a 
different Makefile, so I left it as is. So here is an update that simply 
checks if $XXD is executable.

Best,
Christian
-- 
Die größten Ereignisse, das sind nicht unsere lautesten, sondern
unsere stillsten Stunden.
                -- Friedrich Wilhelm Nietzsche

-- 
-- 
You received this message from the "vim_dev" maillist.
Do not top-post! Type your reply below the text you are replying to.
For more information, visit http://www.vim.org/maillist.php

--- 
You received this message because you are subscribed to the Google Groups 
"vim_dev" group.
To unsubscribe from this group and stop receiving emails from it, send an email 
to vim_dev+unsubscr...@googlegroups.com.
For more options, visit https://groups.google.com/d/optout.
From a5cda5454aa8cd297249f75dcb880e8882dba53e Mon Sep 17 00:00:00 2001
From: Christian Brabandt <c...@256bit.org>
Date: Thu, 5 Apr 2018 23:26:03 +0200
Subject: [PATCH] Add a test for xxd

---
 src/testdir/Make_all.mak |  1 +
 src/testdir/Makefile     |  4 ++
 src/testdir/test_xxd.vim | 95 ++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 100 insertions(+)
 create mode 100644 src/testdir/test_xxd.vim

diff --git a/src/testdir/Make_all.mak b/src/testdir/Make_all.mak
index 159bf1ece..b4e4bc328 100644
--- a/src/testdir/Make_all.mak
+++ b/src/testdir/Make_all.mak
@@ -187,6 +187,7 @@ NEW_TESTS = test_arabic.res \
 	    test_windows_home.res \
 	    test_wordcount.res \
 	    test_writefile.res \
+	    test_xxd.res \
 	    test_alot_latin.res \
 	    test_alot_utf8.res \
 	    test_alot.res
diff --git a/src/testdir/Makefile b/src/testdir/Makefile
index 2ff72c230..fe36a4e05 100644
--- a/src/testdir/Makefile
+++ b/src/testdir/Makefile
@@ -4,6 +4,7 @@
 
 # Use console or GUI.
 VIMPROG = ../vim
+XXDPROG = ../xxd/xxd
 # VIMPROG = ../gvim
 
 SCRIPTSOURCE = ../../runtime
@@ -145,3 +146,6 @@ test_gui_init.res: test_gui_init.vim
 
 opt_test.vim: ../option.c gen_opt_test.vim
 	$(VIMPROG) -u NONE -S gen_opt_test.vim --noplugin --not-a-term ../option.c
+
+test_xxd.res:
+	XXD=$(XXDPROG); export XXD; $(RUN_VIMTEST) $(NO_INITS) -S runtest.vim test_xxd.vim
diff --git a/src/testdir/test_xxd.vim b/src/testdir/test_xxd.vim
new file mode 100644
index 000000000..c0ed06ae8
--- /dev/null
+++ b/src/testdir/test_xxd.vim
@@ -0,0 +1,95 @@
+" Test for the xxd command
+func! PrepareBuffer(command)
+  %d
+  call append(0, a:command)
+  $d
+  w Xfile
+endfunc
+
+func! s:Mess(counter)
+  return printf("Failed xxd test %d:", a:counter)
+endfunc
+
+func! Test_xxd()
+  if empty($XXD) || !executable($XXD)
+    return
+  endif
+  new
+  let s:test=0
+  call PrepareBuffer(range(1,30))
+  " Test 1: simple, filter the result through xxd
+  let s:test+=1
+  let msg=printf("Failed xxd test %d:", s:test)
+  %!$XXD %
+  let expected=[
+        \ '00000000: 310a 320a 330a 340a 350a 360a 370a 380a  1.2.3.4.5.6.7.8.',
+        \ '00000010: 390a 3130 0a31 310a 3132 0a31 330a 3134  9.10.11.12.13.14',
+        \ '00000020: 0a31 350a 3136 0a31 370a 3138 0a31 390a  .15.16.17.18.19.',
+        \ '00000030: 3230 0a32 310a 3232 0a32 330a 3234 0a32  20.21.22.23.24.2',
+        \ '00000040: 350a 3236 0a32 370a 3238 0a32 390a 3330  5.26.27.28.29.30',
+        \ '00000050: 0a                                       .']
+  call assert_equal(expected, getline(1,'$'), msg)
+  " Test 2: reverse the result
+  let s:test+=1
+  %!$XXD -r
+  call assert_equal(map(range(1,30), {v,c -> string(c)}), getline(1,'$'), s:Mess(s:test))
+
+  " Test 3: Skip the first 30 bytes
+  let s:test+=1
+  %!$XXD -s 0x30 %
+  call assert_equal(expected[3:], getline(1,'$'), s:Mess(s:test))
+
+  " Test 4: Skip the first 30 bytes
+  let s:test+=1
+  %!$XXD -s -0x31 %
+  call assert_equal(expected[2:], getline(1,'$'), s:Mess(s:test))
+
+  " Test 5: Print 120 bytes as continuous hexdump with 20 octets per line
+  let s:test+=1
+  %d
+  0r! $XXD -l 120 -ps -c 20 ../../runtime/doc/xxd.1
+  $d
+  let expected=[
+      \ '2e54482058584420312022417567757374203139',
+      \ '39362220224d616e75616c207061676520666f72',
+      \ '20787864220a2e5c220a2e5c222032317374204d',
+      \ '617920313939360a2e5c22204d616e2070616765',
+      \ '20617574686f723a0a2e5c2220202020546f6e79',
+      \ '204e7567656e74203c746f6e79407363746e7567']
+  call assert_equal(expected, getline(1,'$'), s:Mess(s:test))
+  " Test 6: Print the date from xxd.1
+  let s:test+=1
+  %d
+  0r! $XXD -s 0x36 -l 13 -c 13 ../../runtime/doc/xxd.1
+  $d
+  call assert_equal('00000036: 3231 7374 204d 6179 2031 3939 36  21st May 1996', getline(1), s:Mess(s:test))
+  " Test 7: Print C include
+  let s:test+=1
+  call writefile(['TESTabcd09'], 'Xfile')
+  %d
+  0r! $XXD -i Xfile
+  $d
+  let expected=['unsigned char Xfile[] = {',
+        \ '  0x54, 0x45, 0x53, 0x54, 0x61, 0x62, 0x63, 0x64, 0x30, 0x39, 0x0a', '};',
+        \ 'unsigned int Xfile_len = 11;']
+  call assert_equal(expected, getline(1,'$'), s:Mess(s:test))
+  " Test 8: Print C include capitalized
+  let s:test+=1
+  call writefile(['TESTabcd09'], 'Xfile')
+  %d
+  0r! $XXD -i -C Xfile
+  $d
+  let expected=['unsigned char XFILE[] = {',
+        \ '  0x54, 0x45, 0x53, 0x54, 0x61, 0x62, 0x63, 0x64, 0x30, 0x39, 0x0a', '};',
+        \ 'unsigned int XFILE_LEN = 11;']
+  call assert_equal(expected, getline(1,'$'), s:Mess(s:test))
+  " Test 9: Create a  file with containing a single 'A'
+  let s:test+=1
+  call delete('Xfile')
+  call system('echo "010000: 41"|'.$XXD.' -r -s -0x10000 > Xfile')
+  call PrepareBuffer(readfile('Xfile')[0])
+  call assert_equal('A', getline(1), s:Mess(s:test))
+  call delete('Xfile')
+  %d
+  bw!
+endfunc
-- 
2.16.1

Raspunde prin e-mail lui