FYI: SYSEVENT REQFASD on z/OS 1.12 needs a larger work area

[David Alcock]

I see that SYSEVENT REQFASD needs a larger work area in z/OS 1.12 than in 
previous releases.  If you have an existing program assembled with IRARASD 
before z/OS 1.12 maclib and using the recommended RQFASDWA equate to set the 
work area length, you'll be using an area smaller than what z/OS 1.12 needs and 
may get data overlay or S0C4.   Assemble the sample program below with maclib 
prior to z/OS 1.12 and comment out the My_Slack field to see it ABEND on 1.12.  
Existing programs are at risk, those assembled with z/OS 1.12 maclib should be 
fine.  I would guess SYSEVENT REQASD would have the same problem.

ZREQFASD CSECT , *** Show SYSEVENT REQFASD z/OS 1.12 problem ***
ZREQFASD AMODE 31
ZREQFASD RMODE ANY
         LR    R12,R15
         USING ZREQFASD,R12
         BAKR  R14,0
         STORAGE OBTAIN,LENGTH=MyAreaL,BNDRY=PAGE,LOC=BELOW
         LR    R11,R1
         USING MyArea,R11
*
         la    r1,My_Rasd             Locate RASD area
         mvc   RASDACRO-RASD(4,R1),=C'RASD'
         la    r0,RASDSIZE
         sth   r0,RASDLEN-RASD(R1)
         L     r15,PSAAOLD-PSA(0,0)   Locate ASCB
         LH    R4,ASCBASID-ASCB(R15)
         la    r13,My_SDWA            Locate work area
         SYSEVENT REQFASD,ASID=(4)    Get WLM info
*
         TPUT  My_Rasd+(RASDSCL-RASD),L'RASDSCL
         TPUT  My_Rasd+(RASDWKLD-RASD),L'RASDWKLD
         STORAGE RELEASE,LENGTH=MyAreaL,Addr=(11)
         PR    ,
         LTORG ,
MyArea   DSECT ,
My_Rasd  ds    xl(RASDSIZE)           REQFASD parameter list
         ORG   (MyArea+4096)-RQFASDWA Position near end of page
My_SDWA  ds    xl(RQFASDWA)           REQFASD work area
My_Slack DS    XL174                  Comment to get S0C4
MyAreaL  EQU   *-MyArea
*
         IRARASD TITLE=NO             SYSEVENT REQFASD
         Print NOGEN
         YREGS ,
         IHAPSA ,
         CVT   DSECT=YES,LIST=NO
         IHAASCB ,
         END   ,