The following patches fix two rather nasty issues with configury, and
one missing bit of GCS update. All changes should be backwards
compatible (in the sense that they will work with older Autoconf
versions), the first two are necessary for correct functioning with
Autoconf-2.59 already, but the first will really bite you when you
eventually use 2.60, as it will cause a configure script with syntax
errors. The third is to support the directory names change mandated by
a GNU Coding Standards change (this change was actually found by a
warning measure Autoconf applies to configure scripts during the move).
The patches are against the trunk, but I guess similar ones apply to
whatever OpenMPI branch runs danger of being bootstrapped with 2.60
eventually.
Cheers,
Ralf
* config/ompi_config_asm.m4 (OMPI_CHECK_POWERPC_REG): Fix M4
quoting.
* ompi/mca/io/romio/romio/configure.in: Fix some more M4
quoting.
* config/ompi_config_subdir.m4 (OMPI_CONFIG_SUBDIR):
More consistent quoting, a la CVS Autoconf.
* config/ompi_config_subdir_args.m4 (OMPI_CONFIG_SUBDIR_ARGS):
The (undocumented!) Autoconf variable $ac_configure_args needs
to be evaluated, to account for the quoting done.
* ompi/mca/io/romio/romio/util/romioinstall.in: Set datarootdir,
necessary for Autoconf-2.60 which will define some variables
based upon this value (e.g., datadir, docdir).
Index: config/ompi_config_asm.m4
===================================================================
--- config/ompi_config_asm.m4 (revision 10115)
+++ config/ompi_config_asm.m4 (working copy)
@@ -424,10 +424,10 @@
OMPI_TRY_ASSEMBLE([$ompi_cv_asm_text
addi 1,1,0],
[ompi_cv_asm_powerpc_r_reg=0],
- OMPI_TRY_ASSEMBLE([$ompi_cv_asm_text
+ [OMPI_TRY_ASSEMBLE([$ompi_cv_asm_text
addi r1,r1,0],
[ompi_cv_asm_powerpc_r_reg=1],
- AC_MSG_ERROR([Can not determine how to use PPC registers])))
+ [AC_MSG_ERROR([Can not determine how to use PPC registers])])])
if test "$ompi_cv_asm_powerpc_r_reg" = "1" ; then
AC_MSG_RESULT([yes])
else
Index: config/ompi_config_subdir.m4
===================================================================
--- config/ompi_config_subdir.m4 (revision 10115)
+++ config/ompi_config_subdir.m4 (working copy)
@@ -131,8 +131,8 @@
export LDFLAGS LIBS
sub_configure="$SHELL '$subdir_srcdir/configure'"
AC_MSG_NOTICE([running $sub_configure $subdir_args
--cache-file=$subdir_cache_file --srcdir=$subdir_srcdir])
- eval $sub_configure $subdir_args \
- --cache-file=$subdir_cache_file --srcdir=$subdir_srcdir
+ eval "$sub_configure $subdir_args \
+ --cache-file=\"\$subdir_cache_file\" --srcdir=\"$subdir_srcdir\""
if test "$?" = "0"; then
eval $subdir_success
AC_MSG_NOTICE([$sub_configure succeeded for $subdir_dir])
Index: config/ompi_config_subdir_args.m4
===================================================================
--- config/ompi_config_subdir_args.m4 (revision 10115)
+++ config/ompi_config_subdir_args.m4 (working copy)
@@ -33,7 +33,10 @@
subdirs_args=
subdirs_skip=no
-for subdirs_arg in $ac_configure_args; do
+eval "set x $ac_configure_args"
+shift
+for subdirs_arg
+do
if test "$subdirs_skip" = "yes"; then
subdirs_skip=no
else
@@ -51,7 +54,10 @@
-srcdir=* | --srcdir=*)
;;
*)
- subdirs_args="$subdirs_args $subdirs_arg"
+ case $subdir_arg in
+ *\'*) subdir_arg=`echo "$subdir_arg | sed "s/'/'\\\\\\\\''/g"` ;;
+ esac
+ subdirs_args="$subdirs_args '$subdirs_arg'"
;;
esac
fi
@@ -61,8 +67,8 @@
# Assign the output
#
-subdirs_str="$1="'"'"$subdirs_args"'"'
-eval $subdirs_str
+subdirs_str=$1=\"$subdirs_args\"
+eval "$subdirs_str"
#
# Clean up
Index: ompi/mca/io/romio/romio/configure.in
===================================================================
--- ompi/mca/io/romio/romio/configure.in (revision 10118)
+++ ompi/mca/io/romio/romio/configure.in (working copy)
@@ -1475,7 +1475,7 @@
#
AC_CHECK_HEADERS(sys/stat.h sys/types.h unistd.h)
AC_CHECK_FUNCS(stat,
- AC_DEFINE(HAVE_STAT, 1, Define if stat function is present)
+ [AC_DEFINE(HAVE_STAT, 1, Define if stat function is present)
AC_MSG_CHECKING([for st_fstype member of stat structure])
AC_TRY_COMPILE([
#ifdef HAVE_SYS_TYPES_H
@@ -1496,14 +1496,14 @@
AC_DEFINE(ROMIO_HAVE_STRUCT_STAT_WITH_ST_FSTYPE, 1, Define if struct
stat has a st_fstype member),
AC_MSG_RESULT(no)
)
-)
+])
#
# Check for statvfs and f_basetype field (Solaris, Irix, AIX, etc.)
#
AC_CHECK_HEADERS(sys/types.h sys/statvfs.h sys/vfs.h)
AC_CHECK_FUNCS(statvfs,
- AC_DEFINE(HAVE_STATVFS, 1, Define if statvfs function is present)
+ [AC_DEFINE(HAVE_STATVFS, 1, Define if statvfs function is present)
AC_MSG_CHECKING([for f_basetype member of statvfs structure])
AC_TRY_COMPILE([
#ifdef HAVE_SYS_TYPES_H
@@ -1524,7 +1524,7 @@
AC_DEFINE(ROMIO_HAVE_STRUCT_STATVFS_WITH_F_BASETYPE, 1, defined if
struct statvfs has a f_basetype member),
AC_MSG_RESULT(no)
)
-)
+])
#
# Check for large file support. Make sure that we can use the off64_t
Index: ompi/mca/io/romio/romio/util/romioinstall.in
===================================================================
--- ompi/mca/io/romio/romio/util/romioinstall.in (revision 10118)
+++ ompi/mca/io/romio/romio/util/romioinstall.in (working copy)
@@ -28,6 +28,7 @@
#sysconfdir=@sysconfdir@
libdir=@libdir@
#sharedlib_dir=@sharedlib_dir@
+datarootdir=@datarootdir@
mandir=@mandir@
htmldir=@htmldir@
#datadir=@datadir@
