RE: small-caps

[Pascal Sancho]

Hi,

No, font-variant property is not supported by FOP 0.20.5 (compliance page 
should say "no" for that).

If you want such feature, you should make it in the XSLT stage.

You can include the following snippet in your XSLT.
(This is designed to work with XALAN + Javascript, see [1] for further 
information). 

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
  xmlns:fo="http://www.w3.org/1999/XSL/Format";
  xmlns:xalan="http://xml.apache.org/xalan";
  xmlns:yours="http://www.yourscript.net/script/";>

  <xsl:template name="smallCaps">
    <xsl:param name="text"/>
    <fo:wrapper font-size="75%">
      <xsl:if test="string-length($text) &gt; 0">
        <xsl:call-template name="recursiveSmallCaps">
          <xsl:with-param name="text" select="$text"/>
        </xsl:call-template>
      </xsl:if>
    </fo:wrapper>
  </xsl:template>

  <xsl:template name="recursiveSmallCaps">
    <xsl:param name="text"/>
    <xsl:variable name="char" select="substring($text,1,1)"/>
    <xsl:variable name="upperCase" select="yours:upperCase($char)"/>
    <xsl:choose>
      <xsl:when test="$char=$upperCase">
        <fo:wrapper font-size="{100 div 0.75}%">
          <xsl:value-of select="$upperCase"/>
        </fo:wrapper>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$upperCase"/>
      </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="string-length($text) &gt; 1">
      <xsl:call-template name="recursiveSmallCaps">
        <xsl:with-param name="text" select="substring($text,2)"/>
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

  <xalan:component prefix="yours" elements="" functions="upperCase">
    <xalan:script lang="javascript">
<![CDATA[
function upperCase(string) {
    return string.toUpperCase();
}
]]>
    </xalan:script>
  </xalan:component>

</xsl:stylesheet>

HTH,

[1] http://xml.apache.org/xalan-j/extensions.html

Pascal

> -----Message d'origine-----
> De : Nicolas Vahlas [mailto:[EMAIL PROTECTED] 
> Envoyé : lundi 2 juillet 2007 13:23
> À : fop-users@xmlgraphics.apache.org
> Objet : small-caps
> 
> Hi,
> 
> I have noticed that the latest releases of fop do not support 
> small-caps anymore.
> In the compliance table I can see it was supported in the 
> 0.20.5, but not anymore in the 0.93 and the trunk.
> I need to produce a PDF file with small caps in them and I 
> would not like to use the older version of FOP.
> Is there a way I can do it ?
> 
> Thanks for helping.
> Nicolas