>From 312 to 68 cycles on Arrandale and Win64.
Sandybridge: 47 cycles.
Having a loop counter is a 7 cycle gain.
Unrolling is another 7 cycle gain.
Working in reverse scan is another 6 cycles.
---
libavcodec/x86/sbrdsp.asm | 28 ++++++++++++++++++++++++++++
libavcodec/x86/sbrdsp_init.c | 2 ++
2 files changed, 30 insertions(+)
diff --git a/libavcodec/x86/sbrdsp.asm b/libavcodec/x86/sbrdsp.asm
index 62df005..aeeac47 100644
--- a/libavcodec/x86/sbrdsp.asm
+++ b/libavcodec/x86/sbrdsp.asm
@@ -295,3 +295,31 @@ cglobal sbr_qmf_deint_neg, 2,3,3,v,src,vrev
cmp vq, vrevq
jl .loop
REP_RET
+
+INIT_XMM sse2
+; sbr_qmf_deint_bfly(float *v, const float *src0, const float *src1)
+cglobal sbr_qmf_deint_bfly, 3,5,8, v,src0,src1,vrev,c
+ mov cq, 64*4-2*mmsize
+ lea vrevq, [vq + 64*4]
+.loop:
+ mova m0, [src0q+cq]
+ mova m1, [src1q]
+ mova m2, [src0q+cq+mmsize]
+ mova m3, [src1q+mmsize]
+ pshufd m4, m0, q0123
+ pshufd m5, m1, q0123
+ pshufd m6, m2, q0123
+ pshufd m7, m3, q0123
+ addps m3, m4
+ subps m0, m7
+ addps m1, m6
+ subps m2, m5
+ mova [vrevq], m1
+ mova [vrevq+mmsize], m3
+ mova [vq+cq], m0
+ mova [vq+cq+mmsize], m2
+ add src1q, 2*mmsize
+ add vrevq, 2*mmsize
+ sub cq, 2*mmsize
+ jge .loop
+ REP_RET
diff --git a/libavcodec/x86/sbrdsp_init.c b/libavcodec/x86/sbrdsp_init.c
index 82aeaa5..f6154e1 100644
--- a/libavcodec/x86/sbrdsp_init.c
+++ b/libavcodec/x86/sbrdsp_init.c
@@ -36,6 +36,7 @@ void ff_sbr_neg_odd_64_sse(float *z);
void ff_sbr_qmf_post_shuffle_sse(float W[32][2], const float *z);
void ff_sbr_qmf_pre_shuffle_sse2(float *z);
void ff_sbr_qmf_deint_neg_sse(float *v, const float *src);
+void ff_sbr_qmf_deint_bfly_sse2(float *v, const float *src0, const float
*src1);
av_cold void ff_sbrdsp_init_x86(SBRDSPContext *s)
{
@@ -53,5 +54,6 @@ av_cold void ff_sbrdsp_init_x86(SBRDSPContext *s)
if (EXTERNAL_SSE2(mm_flags)) {
s->qmf_pre_shuffle = ff_sbr_qmf_pre_shuffle_sse2;
+ s->qmf_deint_bfly = ff_sbr_qmf_deint_bfly_sse2;
}
}
--
1.8.0.msysgit.0
_______________________________________________
libav-devel mailing list
[email protected]
https://lists.libav.org/mailman/listinfo/libav-devel
