On 13/09/09 21:50, Patrick Gen-Paul wrote:
>
> I found the TabLineSet.vim plugin that advertises a number of
> functionalities that I was looking for, such as display the tab page
> number, or show only the focused file's basefile instead of the full
> path, but all I get is a blank line on line one, followed by a white
> line across the entire screen.
>
> I switched color schemes, tried with the vim -u flag, logged in as a
> different user.. no joy.
>
> When I issue :call commands pointing to TabLineSet_verbose_rotate(), it
> displays the "Tabline options" that it sets, but the corresponding
> labels are invisible.
>
> Is anyone successfully using this plugin in non-gui vim?
>
> Thanks,
>
> Gen-Paul.
I'm not using that plugin, but I'm using a text-style tabline in both
Console Vim and gvim.
One example of how to set it can be found under ":help setting-tabline".
What I use is slightly different, as follows (uncomment the maps at the
bottom if you like them):
if exists("+guioptions")
set go-=a go-=e go+=tc
" remove a no autoselect to * register
" remove e always use text-style tabs
" add t include tearoff menu items if possible
" add c avoid popup dialogs for small choices
endif
" define our text-style tabline
" this is adapted (with some enhancements) from the example
" at :help setting-tabline
if exists("+showtabline")
function MyTabLine()
let s = ''
let t = tabpagenr()
let i = 1
while i <= tabpagenr('$')
let buflist = tabpagebuflist(i)
let winnr = tabpagewinnr(i)
let s .= '%' . i . 'T'
let s .= (i == t ? '%1*' : '%2*')
let s .= ' '
let s .= i . ':'
let s .= winnr . '/' . tabpagewinnr(i,'$')
let s .= ' %*'
let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
let file = bufname(buflist[winnr - 1])
let file = fnamemodify(file, ':p:t')
if file == ''
let file = '[No Name]'
endif
let s .= file
let i = i + 1
endwhile
let s .= '%T%#TabLineFill#%='
let s .= (tabpagenr('$') > 1 ? '%999XX' : 'X')
return s
endfunction
set stal=2
set tabline=%!MyTabLine()
" map <F10> :tabnext<CR>
" map! <F10> <C-O>:tabnext<CR>
" map <S-F10> :tabprev<CR>
" map! <S-F10> <C-O>:tabprev<CR>
endif
--~--~---------~--~----~------------~-------~--~----~
You received this message from the "vim_use" maillist.
For more information, visit http://www.vim.org/maillist.php
-~----------~----~----~----~------~----~------~--~---
