>> John McKown >I second what John says. If you have more details / symptoms >to give us more detailed clues, we can help you better. But >I would first make sure you are using BASSM / BSM instead of >BASSR / BE to call your subroutine and return. >-- > >Kind regards, > >-Steve Comstock
Here's a sample for one way to do it. Depending on your code, there may be
savearea considerations to deal with for your 31 bit program. This sample
provides a 72 byte save area.
Todd
TEST64 CSECT
TEST64 AMODE 64
TEST64 RMODE ANY
BAKR R14,0 SAVE GPRS AND ARS IN LINKAGE STACK
SAM64
CNOP 0,4
BRAS R12,*+8 POINT R12 TO THE ACON FOR THE MODULE
DC A(TEST64)
L R12,0(,R12) NOW, WE HAVE ADDRESSABILITY
USING TEST64,R12
WTO '64: CURRENTLY IN 64.',DESC=(6),ROUTCDE=(11),MF=I
LA R14,CALL31 SUBROUTINE TO CALL
BAKR 0,R14 CALL SUBROUTINE
WTO '64: BACK IN 64.',DESC=(6),ROUTCDE=(11),MF=I
LA R15,0 RC = 0
PR , PROGRAM RETURN TO OS
*
CALL31 DS 0H
SAM31
LA R13,SAVEAREA
CALL TEST31
PR RETURNS TO THE WTO BACK IN 64...
*
SAVEAREA DS 18F
*
TEST31 CSECT
TEST31 AMODE 31
TEST31 RMODE ANY
STM R14,R12,12(R13)
LR R12,R15
USING TEST31,R12
WTO '31: CURRENTLY IN 31.',DESC=(6),ROUTCDE=(11),MF=I
LM R14,R12,12(R13)
XR R15,R15
BR R14
YREGS
END
No virus found in this outgoing message.
Checked by AVG Free Edition.
Version: 7.5.484 / Virus Database: 269.12.2 - Release Date: 8/22/2007 12:00
AM
----------------------------------------------------------------------
For IBM-MAIN subscribe / signoff / archive access instructions,
send email to [EMAIL PROTECTED] with the message: GET IBM-MAIN INFO
Search the archives at http://bama.ua.edu/archives/ibm-main.html
