---
libavresample/x86/audio_convert.asm | 100 ++++++++++++++++++++++++++++++++
libavresample/x86/audio_convert_init.c | 13 ++++
2 files changed, 113 insertions(+), 0 deletions(-)
diff --git a/libavresample/x86/audio_convert.asm
b/libavresample/x86/audio_convert.asm
index a773183..26bfb9d 100644
--- a/libavresample/x86/audio_convert.asm
+++ b/libavresample/x86/audio_convert.asm
@@ -871,3 +871,103 @@ CONV_S16_TO_FLTP_2CH
INIT_XMM avx
CONV_S16_TO_FLTP_2CH
%endif
+
+;------------------------------------------------------------------------------
+; void ff_conv_s16_to_fltp_6ch(float *const *dst, int16_t *src, int len,
+; int channels);
+;------------------------------------------------------------------------------
+
+%macro CONV_S16_TO_FLTP_6CH 0
+cglobal conv_s16_to_fltp_6ch, 2,8,7, dst, src, dst1, dst2, dst3, dst4, dst5,
len
+%if ARCH_X86_64
+ mov lend, r2d
+%else
+ %define lend dword r2m
+%endif
+ mov dst1q, [dstq+ gprsize]
+ mov dst2q, [dstq+2*gprsize]
+ mov dst3q, [dstq+3*gprsize]
+ mov dst4q, [dstq+4*gprsize]
+ mov dst5q, [dstq+5*gprsize]
+ mov dstq, [dstq ]
+ sub dst1q, dstq
+ sub dst2q, dstq
+ sub dst3q, dstq
+ sub dst4q, dstq
+ sub dst5q, dstq
+ mova m6, [pf_s16_inv_scale]
+ ALIGN 16
+.loop:
+ mova m0, [srcq ] ; m0 = 0, 1, 2, 3, 4, 5, 6, 7
+ mova m1, [srcq+ mmsize] ; m1 = 8, 9, 10, 11, 12, 13, 14, 15
+ mova m2, [srcq+2*mmsize] ; m2 = 16, 17, 18, 19, 20, 21, 22, 23
+ movhlps m3, m1
+ movlhps m3, m2 ; m3 = 12, 13, 14, 15, 16, 17, 18, 19
+ movlhps m1, m1
+ movhlps m1, m0 ; m1 = 4, 5, 6, 7, 8, 9, 10, 11
+ psrldq m1, 4 ; m1 = 6, 7, 8, 9, 10, 11, x, x
+ psrldq m2, 4 ; m2 = 18, 19, 20, 21, 22, 23, x, x
+ punpcklwd m4, m0, m1 ; m4 = 0, 6, 1, 7, 2, 8, 3, 9
+ punpckhwd m0, m1 ; m0 = 4, 10, 5, 11, x, x, x, x
+ punpcklwd m1, m3, m2 ; m1 = 12, 18, 13, 19, 14, 20, 15, 21
+ punpckhwd m3, m2 ; m3 = 16, 22, 17, 23, x, x, x, x
+ punpckldq m2, m4, m1 ; m2 = 0, 6, 12, 18, 1, 7, 13, 19
+ punpckhdq m4, m1 ; m4 = 2, 8, 14, 20, 3, 9, 15, 21
+ punpckldq m0, m3 ; m0 = 4, 10, 16, 22, 5, 11, 17, 23
+ movhlps m3, m2 ; m3 = 1, 7, 13, 19, x, x, x, x
+ movhlps m5, m4 ; m5 = 3, 9, 15, 21, x, x, x, x
+ movhlps m1, m0 ; m1 = 5, 11, 17, 23, x, x, x, x
+%if cpuflag(sse4)
+ pmovsxwd m0, m0
+ pmovsxwd m1, m1
+ pmovsxwd m2, m2
+ pmovsxwd m3, m3
+ pmovsxwd m4, m4
+ pmovsxwd m5, m5
+%else ; sse2
+ punpcklwd m0, m0
+ psrad m0, 16
+ punpcklwd m1, m1
+ psrad m1, 16
+ punpcklwd m2, m2
+ psrad m2, 16
+ punpcklwd m3, m3
+ psrad m3, 16
+ punpcklwd m4, m4
+ psrad m4, 16
+ punpcklwd m5, m5
+ psrad m5, 16
+%endif
+ cvtdq2ps m0, m0
+ cvtdq2ps m1, m1
+ cvtdq2ps m2, m2
+ cvtdq2ps m3, m3
+ cvtdq2ps m4, m4
+ cvtdq2ps m5, m5
+ mulps m0, m6
+ mulps m1, m6
+ mulps m2, m6
+ mulps m3, m6
+ mulps m4, m6
+ mulps m5, m6
+ mova [dstq ], m2
+ mova [dstq+dst1q], m3
+ mova [dstq+dst2q], m4
+ mova [dstq+dst3q], m5
+ mova [dstq+dst4q], m0
+ mova [dstq+dst5q], m1
+ add srcq, mmsize*3
+ add dstq, mmsize
+ sub lend, mmsize/4
+ jg .loop
+ REP_RET
+%endmacro
+
+INIT_XMM sse2
+CONV_S16_TO_FLTP_6CH
+INIT_XMM sse4
+CONV_S16_TO_FLTP_6CH
+%if HAVE_AVX
+INIT_XMM avx
+CONV_S16_TO_FLTP_6CH
+%endif
diff --git a/libavresample/x86/audio_convert_init.c
b/libavresample/x86/audio_convert_init.c
index 3cf8da9..80b4a17 100644
--- a/libavresample/x86/audio_convert_init.c
+++ b/libavresample/x86/audio_convert_init.c
@@ -93,6 +93,13 @@ extern void ff_conv_s16_to_fltp_2ch_sse4(float *const *dst,
int16_t *src,
extern void ff_conv_s16_to_fltp_2ch_avx (float *const *dst, int16_t *src,
int len, int channels);
+extern void ff_conv_s16_to_fltp_6ch_sse2(float *const *dst, int16_t *src,
+ int len, int channels);
+extern void ff_conv_s16_to_fltp_6ch_sse4(float *const *dst, int16_t *src,
+ int len, int channels);
+extern void ff_conv_s16_to_fltp_6ch_avx (float *const *dst, int16_t *src,
+ int len, int channels);
+
av_cold void ff_audio_convert_init_x86(AudioConvert *ac)
{
#if HAVE_YASM
@@ -143,6 +150,8 @@ av_cold void ff_audio_convert_init_x86(AudioConvert *ac)
6, 16, 4, "SSE2",
ff_conv_s16_to_s16p_6ch_sse2);
ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLTP, AV_SAMPLE_FMT_S16,
2, 16, 8, "SSE2",
ff_conv_s16_to_fltp_2ch_sse2);
+ ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLTP, AV_SAMPLE_FMT_S16,
+ 6, 16, 4, "SSE2",
ff_conv_s16_to_fltp_6ch_sse2);
}
if (mm_flags & AV_CPU_FLAG_SSE4 && HAVE_SSE) {
ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLT, AV_SAMPLE_FMT_S16,
@@ -151,6 +160,8 @@ av_cold void ff_audio_convert_init_x86(AudioConvert *ac)
6, 16, 4, "SSE4",
ff_conv_fltp_to_flt_6ch_sse4);
ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLTP, AV_SAMPLE_FMT_S16,
2, 16, 8, "SSE4",
ff_conv_s16_to_fltp_2ch_sse4);
+ ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLTP, AV_SAMPLE_FMT_S16,
+ 6, 16, 4, "SSE4",
ff_conv_s16_to_fltp_6ch_sse4);
}
if (mm_flags & AV_CPU_FLAG_AVX && HAVE_AVX) {
ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLT, AV_SAMPLE_FMT_S32,
@@ -167,6 +178,8 @@ av_cold void ff_audio_convert_init_x86(AudioConvert *ac)
6, 16, 4, "AVX",
ff_conv_s16_to_s16p_6ch_avx);
ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLTP, AV_SAMPLE_FMT_S16,
2, 16, 8, "AVX",
ff_conv_s16_to_fltp_2ch_avx);
+ ff_audio_convert_set_func(ac, AV_SAMPLE_FMT_FLTP, AV_SAMPLE_FMT_S16,
+ 6, 16, 4, "AVX",
ff_conv_s16_to_fltp_6ch_avx);
}
#endif
}
--
1.7.1
_______________________________________________
libav-devel mailing list
[email protected]
https://lists.libav.org/mailman/listinfo/libav-devel
