The 'M' in the designators MQ1 and MQ2 may let the simulator look for a
 MOSFET model. But you want the IRF840 to be handled like a subcircuit (as
 stated in library field #3). Try changing the designators to Q1 and Q2.

 Rolf Molitor
 Ing.-Buero i2e
 Remscheid / Germany

----- Original Message -----
From: "Jeff Stout" <[EMAIL PROTECTED]>
To: "Protel EDA Forum" <[EMAIL PROTECTED]>
Sent: Wednesday, November 05, 2003 4:28 PM
Subject: Re: [PEDA] Simulation woes


> Maybe it's the model for the 1N4148 diode.  Copy the next
> line (the  + TT=4.32N part) to the end of the previous line.  You
> don't need the + of course.
>
> Jeff Stout
>
>
> ----- Original Message -----
> From: "Ian Rozowsky" <[EMAIL PROTECTED]>
> To: "Protel EDA Forum (E-mail)" <[EMAIL PROTECTED]>
> Sent: Wednesday, November 05, 2003 1:19 AM
> Subject: [PEDA] Simulation woes
>
>
> > Hi All
> >
> > I'm currently trying to simulate a MOSFET drive circuit in 99SE. The
> > simulator seems unable to find/recognize the model for the IRF840.
> >
> > I get the following message upon running the simulation:
> >
> > Warning: premature EOF
> > Error on line 7: mq1 netl1_1 lo_gate 0 0 irf840
> > ERROR - unable to find definition of model irf840 - default assumed
> > Error on line 8: mq2 netv1_1 hi_gate netl1_1 netl1_1 irf840
> > ERROR - unable to find definition of model irf840 - default assumed
> >
> > My netlist is as follows:
> >
> > *SPICE Netlist generated by Advanced Sim server on 05-Nov-03 09:12:11
> > *for: Fet Drive.nsx
> >
> > *Schematic Netlist:
> > D1 LO_GATE NetR2_2 1N4148
> > D2 HI_GATE NetR4_2 1N4148
> > L1 NetL1_1 0 100mH
> > MQ1 NetL1_1 LO_GATE 0 0 IRF840
> > MQ2 NetV1_1 HI_GATE NetL1_1 NetL1_1 IRF840
> > R1 LO_DRIVE LO_GATE 120R
> > R2 LO_DRIVE NetR2_2 56R
> > R3 HI_DRIVE HI_GATE 120R
> > R4 HI_DRIVE NetR4_2 56R
> > V1 NetV1_1 0 +310V AC 0 0
> > V2 LO_DRIVE 0 DC 0 PULSE(0 15 0 1u 1u 10mS 20mS 0) AC 1 0
> > V3 HI_DRIVE 0 DC 0 PULSE(0 15 10mS 1u 1u 10mS 20mS 0) AC 1 0
> >
> > .SAVE 0 HI_DRIVE HI_GATE LO_DRIVE LO_GATE NetL1_1 NetR2_2 NetR4_2
NetV1_1
> > .SAVE V1#branch V2#branch V3#branch @V1[z] @V2[z] @V3[z]
> >
> > *PLOT TRAN -1 1 A=HI_DRIVE
> > *PLOT OP -1 1 A=HI_DRIVE
> >
> > *Selected Circuit Analyses:
> > .TRAN 0.0004 0.02 0 0.0004
> > .OP
> >
> > *Models and Subcircuit:
> > .MODEL 1N4148 D (IS=14.2P RS=4.2 N=1.7 BV=75 IBV=5U CJO=1.74P VJ=0.75
> > M=0.333
> > + TT=4.32N)
> >
> > .SUBCKT IRF840   10 20 40 40
> > M1   1  2  3  3  DMOS L=1U W=1U
> > RD  10  1  .402
> > RS  30  3  22.2M
> > RG  20  2  18.7
> > CGS  2  3  1.18N
> > EGD 12  0  2  1  1
> > VFB 14  0  0
> > FFB  2  1  VFB  1
> > CGD 13 14  1.54N
> > R1  13  0  1
> > D1  12 13  DLIM
> > DDG 15 14  DCGD
> > R2  12 15  1
> > D2  15  0  DLIM
> > DSD  3 10  DSUB
> > LS  30 40  7.5N
> > .MODEL DMOS NMOS (LEVEL=3 THETA=60M VMAX=1.04MEG ETA=2M VTO=3 KP=4.33)
> > .MODEL DCGD D (CJO=1.54N VJ=.6 M=.68)
> > .MODEL DSUB D (IS=33.2N N=1.5 RS=.156 BV=500 CJO=817P VJ=.8 M=.42
TT=460N)
> > .MODEL DLIM D (IS=100U)
> > .ENDS IRF840
> >
> > .END
> >
> > The other components (sources, resisitors,diodes) do not generate
errors.
> > Only the IRF840 MOSFET seems to be a problem. Any ideas?
> >
> > TIA
> >
> > Ian Rozowsky
> > R&D Director
> > Centurion Systems (Pty) Ltd.
> > Box 506 Cramerview 2060 South Africa
> > [EMAIL PROTECTED]
> > ||Anti-spam - please remove the ** from the e-mail address before
> sending||
> > http://www.centsys.co.za
> >
> >
>
>



* * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
* To post a message: mailto:[EMAIL PROTECTED]
*
* To leave this list visit:
* http://www.techservinc.com/protelusers/leave.html
*
* Contact the list manager:
* mailto:[EMAIL PROTECTED]
*
* Forum Guidelines Rules:
* http://www.techservinc.com/protelusers/forumrules.html
*
* Browse or Search previous postings:
* http://www.mail-archive.com/[EMAIL PROTECTED]
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

Reply via email to